APS_COM_CS_D2_CDOC_GEN

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Com. Sys. change docs (general changes)'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #M,
  dataClass: #MIXED
}

define view entity APS_COM_CS_D2_CDOC_GEN
  as select from    APS_COM_CHG_DOC_BASE as changeDocs
    left outer join aps_cs_d_root        as ComSys         on changeDocs.CDocKey = cast(
      bintohex(
        ComSys.db_key
      )                                  as abap.char(
                                         90
                                       )
    )

    left outer join t100                 as _Text_Old_Hash on  _Text_Old_Hash.sprsl = $session.system_language
                                                           and _Text_Old_Hash.arbgb = 'CM_APS_CS_CDS'
                                                           and _Text_Old_Hash.msgnr = '000'

    left outer join t100                 as _Text_New_Hash on  _Text_New_Hash.sprsl = $session.system_language
                                                           and _Text_New_Hash.arbgb = 'CM_APS_CS_CDS'
                                                           and _Text_New_Hash.msgnr = '001'
{
  key ComSys.db_key              as ComSysKey,
  key changeDocs.CDocClass       as CDocClass,
  key changeDocs.CDocKey         as CDocKey,
  key changeDocs.CDoc            as CDoc,
  key changeDocs.DBTable         as ChangeCategory,
  key changeDocs.DBTableKey      as DBTableKey,
  key changeDocs.FieldName       as FieldName,
  key changeDocs.Action          as Action,

      changeDocs.DBTableText     as ChangeCategoryText,
      changeDocs.ActionTxt       as ActionTxt,
      changeDocs.CreatedByUser   as ChangedByUser,
      changeDocs.CreatedByUsrTxt as ChangedByUserTxt,
      changeDocs.CreationDate    as ChangedDate,
      changeDocs.CreationTime    as ChangedTime,
      changeDocs.ChangedAt       as ChangedAt,
      changeDocs.Attribute       as Attribute,
      changeDocs.AttributeText   as AttributeText,
      changeDocs.NewValue        as NewValue,
      changeDocs.OldValue        as OldValue,

      ComSys.commsyst            as ComSyst,
      ComSys.commsystname        as ComSysName,
      ComSys.commsysttype        as ComSysType,

      case $projection.Attribute
        when 'APS_CS_OUTBOUND_PWD_REF' then _Text_Old_Hash.text
        else $projection.OldValue
      end                        as OldValueText,

      case $projection.Attribute
        when 'APS_CS_OUTBOUND_PWD_REF' then _Text_New_Hash.text
        else $projection.NewValue
      end                        as NewValueText

}
where
  changeDocs.CDocClass = 'APS_COM_CS'