ACE_ACDOCA_MIG_ACRTYPE_RULE

@AbapCatalog.sqlViewName: 'ACEV_TYPE_RULE'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass:  #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #X
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Get original source from ACDOCA'
@AbapCatalog.preserveKey:true

define view ACE_ACDOCA_MIG_ACRTYPE_RULE
  as select from    ACE_ACDOCA_MIG_ACCR as acdoca
    left outer join acesobj        on  acdoca.acrobjtype = acesobj.comp
                                   and acdoca.acrlogsys  = acesobj.logsys //should always be empty in migration

                                   and acdoca.rbukrs     = acesobj.bukrs
                                   and acdoca.acrobj_id  = acesobj.ref_key
                                   and acdoca.acrsobj_id = acesobj.ref_subkey
    left outer join ACE_ITEMTYPEL_DISTINCT as tace_itemtypel 
                                   on  acdoca.acrobjtype        = tace_itemtypel.comp
                                   and acdoca.rbukrs            = tace_itemtypel.bukrs
                                   and acdoca.acritmtype        = tace_itemtypel.itemtype
    left outer join tace_combination as tace_combination
                                   on  acdoca.acrobjtype        = tace_combination.comp
                                   and acdoca.rbukrs            = tace_combination.bukrs 
{
  key acdoca.acrobjtype,
  key acdoca.gjahr,
  key acdoca.rbukrs,
  key acesobj.objid,
  key acesobj.subid,
  key tace_itemtypel.acrtype,
  key tace_combination.accrule,
  acdoca.rldnr,
  acdoca.acritmtype,
  concat(tace_itemtypel.acrtype,concat('_', tace_combination.accrule) ) as concat_itemtype,
  acdoca.acrobj_id,
  acdoca.acrsobj_id,
  tace_itemtypel.is_itemtype_concat,
  acdoca.pre_gjahr,
  acdoca.slalittype,
  acdoca.valtbp,
  acdoca.currency,
  acdoca.transtype,
  acdoca.effdate,
  acdoca.podate,
  acdoca.poper,
  acdoca.poyear,
  acdoca.awtyp,
  acdoca.awkey,
  acdoca.awsys,
  acdoca.timestamp,
  acdoca.mig_source
}