R_WORKPERMITAPPROVALTP

CDS View

Approval root entity

R_WORKPERMITAPPROVALTP is a CDS View in S/4HANA. Approval root entity. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
A_WorkPermitApproval view_entity projection CONSUMPTION Work Permit Approval
C_WorkPermitApprovalTP view_entity projection CONSUMPTION Approvals for permit type 
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Approval root entity'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.resultSet.sizeCategory: #XS
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL
define view entity R_WorkPermitApprovalTP
  as select from I_WorkPermitApproval
  association        to parent R_WorkPermitTP       as _WorkPermit on  $projection.WorkPermit = _WorkPermit.WorkPermit
  association [0..1] to I_TextObjectPlainLongText   as _LongText   on  $projection.TextObjectKey    = _LongText.TextObjectKey
                                                                   and _LongText.TextObjectCategory = 'APPROVAL'
                                                                   and _LongText.TextObjectType     = 'LTXT'
                                                                   and _LongText.Language           = $session.system_language
  association [0..1] to I_MasterDataDomainValueText as _DomainText on  $projection.WorkPermitApprovalStatus = _DomainText.DomainValue
                                                                   and _DomainText.Name                     = 'PTWDWORKPERMITAPPROVALSTATUS'
                                                                   and _DomainText.Language                 = $session.system_language
   -- Extensions, do not expose as association:
  association [0..1] to E_WorkPermitApproval        as _WorkPermitApprovalExtension   on  _WorkPermitApprovalExtension.WorkPermitInternalID = $projection.WorkPermitInternalID
                                                                                      and _WorkPermitApprovalExtension.NumberOfWrkPermitApprovals  = $projection.NumberOfWrkPermitApprovals

{
  key WorkPermitInternalID,
  key NumberOfWrkPermitApprovals,
      WorkPermitApproval,
      WorkPermit,
      WorkPermitHasLongText,
      CreationDate,
      CreatedByUser,
      LastChangedDate,
      LastChangedByUser,
      WorkPermitApprovalComment,
      WorkPermitApprovalDescription,
      WorkPermitApprovalStatus,
//      cast (case

//      when ( WorkPermitApprovalStatus =  'A' )

//       then 'X'

//       else '' end as  xfeld )              as IsEditable,

      _ApprovalDetails.WrkPmtApprovalIsMandatory,
      _ApprovalDetails.WrkPmtApprovalHierarchyLevel,
      _ApprovalDetails.WrkPmtApprvlMandText,
      TextObjectKey,
      _LongText.PlainLongText,
      case
      when ( WorkPermitApprovalStatus =  'R'  )  then cast( '1' as eam_criticality )
      when ( WorkPermitApprovalStatus =  'A'  )  then cast( '3' as eam_criticality )
      else cast('1' as eam_criticality) end as WrkPmtSftyRqmtCriticalityCode,
      MaintenancePlanningPlant,
      WorkPermitType,
      //association

      _WorkPermit,
      _DomainText,
      _LongText
}
where
  WrkPmtMgmtObjSubType = 'P'

Learn More