R_WORKCENTERCAPACITYTP

CDS View

Work Center Capacity

R_WORKCENTERCAPACITYTP is a CDS View in S/4HANA. Work Center Capacity. 5 CDS views read from this table.

Used by 5 CDS view(s)

CDS Views using this table (5)

ViewTypeJoinVDMDescription
A_WorkCenterCapacity_2 view_entity projection CONSUMPTION Work Center Capacity
I_WorkCenterCapacityTP view_entity projection TRANSACTIONAL Interface for the BO WorkCenter Capacity - TP
R_WorkCenterCapacityIntervalTP view_entity inner TRANSACTIONAL Capacity Interval
R_WorkCenterCapacityShiftTP view_entity inner TRANSACTIONAL Capacity Shift
R_WorkCenterCapacityTextTP view_entity inner TRANSACTIONAL Work Center Capacity Text 
//@AbapCatalog.sqlViewName: 'RWRKCTRCAPTP'

//@AbapCatalog.compiler.compareFilter: true

//@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Work Center Capacity'
//@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel.usageType: { serviceQuality: #C, sizeCategory: #M, dataClass: #MASTER }
@VDM: { viewType: #TRANSACTIONAL, lifecycle.contract.type: #SAP_INTERNAL_API }
define view entity R_WorkCenterCapacityTP
  as select from I_WorkCenterCapacity_2
  -- to Capacity Interval
  composition [1..*] of R_WorkCenterCapacityIntervalTP as _Interval

  --to Capacity Text
  composition [1..*] of R_WorkCenterCapacityTextTP     as _CapDescription

  association to parent R_WorkCenterTP                 as _Header on  $projection.WorkCenterTypeCode   = _Header.WorkCenterTypeCode
                                                                  and $projection.WorkCenterInternalID = _Header.WorkCenterInternalID

{
  key WorkCenterInternalID,
  key WorkCenterTypeCode,
  key CapacityCategoryAllocation,
  key CapacityInternalID,

      // Capacity Alloc Attributes

      LastChangeDate,
      LastChangedByUser,
      WorkCenter,
      WorkCenterCategoryCode,
      SetupCapRequirementFormula,
      ProcgCapRequirementFormula,
      TeardownCapRequirementFormula,
      OtherCapRequirementFormula,
      ValidityStartDate,
      ValidityEndDate,
      WorkCenterLastChangeDateTime,

      // Capacity Attributes

      Capacity,
      CapacityCategoryCode,
      CapacityActiveVersion,
      CapacityIsFinite,
      CapacityIsPooled,
      CapacityHasIndivCapacities,
      CapacityIsExcldFrmLongTermPlng,
      CapacityNumberOfCapacities,
      CapacityResponsiblePlanner,
      CapacityPlanUtilizationPercent,
      CapacityBreakDuration,

      // Assignments

      Plant,
      FactoryCalendar,
      AuthorizationGroup,
      ShiftGroup,

      // Times

      @Semantics.durationInSeconds:true
      CapacityStartTimeID,
      @Semantics.durationInSeconds:true
      CapacityEndTimeID,

      CapIsUsedInMultiOperations,
      ReferencedCapacityInternalID,
      CapOverloadThresholdInPercent,

      // Unit of Measures

      //      @Semantics.unitOfMeasure: true

      CapacityQuantityUnit,
      //      @Semantics.unitOfMeasure: true

      CapacityBaseQtyUnit,

      CapacityLastChangeDateTime,

      /*Associations*/
      @Consumption.hidden: true
      _Header,
      _Interval,
      _CapDescription
}
where
      CapacityIsPooled is initial
  and Capacity         is initial

Learn More