R_VASDETERMINATIONTP

CDS View

VAS Determination - TP

R_VASDETERMINATIONTP is a CDS View in S/4HANA. VAS Determination - TP. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
C_VASDetermination view_entity projection CONSUMPTION VAS Determination Details
I_VASDeterminationTP view_entity projection TRANSACTIONAL Interface VAS Determination - TP 
 @AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: [ '_NoteBasic' ]
@EndUserText.label: 'VAS Determination - TP'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #S, 
  dataClass: #MIXED
}
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API  
@ObjectModel.sapObjectNodeType.name: 'VASDetail'
define view entity R_VASDeterminationTP
  as select from I_VASDetermination
  association to parent R_VASCharacteristicValueTP as _VASCharcVal on $projection.VASCharacteristicValueUUID = _VASCharcVal.VASCharacteristicValueUUID
 // composition [0..*] of R_VASDeterminationTextTP as _VASDetnText 

  composition [0..*] of R_VASInstructionTP as _VASDetnText 
  association [1..1] to R_VASCombinationTP as _VASCombn on $projection.VASCombinationUUID = _VASCombn.VASCombinationUUID
  association [0..*] to I_ProductDescription as _ProductDescription on $projection.Product = _ProductDescription.Product
  association [0..*] to I_VASServiceText as _VASServiceText on $projection.VASService = _VASServiceText.VASService
  association [0..*] to I_VASServiceTypeText as _VASServiceTypeText on $projection.ValueAddedSubServiceType = _VASServiceTypeText.ValueAddedSubServiceType
                                                                    and  $projection.VASService = _VASServiceTypeText.VASService
  association [0..*] to I_VASChargeCodeText as _VASChargeCodeText on $projection.VASChargeCode = _VASChargeCodeText.VASChargeCode 
{
  key VASDeterminationUUID,
      VASCharacteristicValueUUID,
      VASCombinationUUID,
      
      VASService,
      
      ValueAddedSubServiceType,
      
      Product,
      RequirementRelevant,
      VASQuantityRoundingIsDown,
      VASIncrement,
      VASChargeCode,
      @Semantics.text:true 
      _ProductDescription[1: Language = $session.system_language ].ProductDescription as ProductDescription,
      @Semantics.text:true 
      _VASServiceText[1: Language = $session.system_language ].VASServiceText as VASServiceText ,
      @Semantics.text:true 
      _VASServiceTypeText[1: Language = $session.system_language ].VASServiceTypeText as VASServiceTypeText,
      @Semantics.text:true 
      _VASChargeCodeText[1: Language = $session.system_language ].VASChargeCodeText as VASChargeCodeText,

      //  admin fields

      CreatedByUser,
      CreatedOnDateTime,
      LastChangedByUser,
      LastChangeDateTime,
   

      //  association

//      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT,#TO_COMPOSITION_PARENT]

      _VASDetnText,
//      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT,#TO_COMPOSITION_PARENT]

      _VASCharcVal,
      _VASCombn,
      _ProductDescription,
      _VASServiceText,
      _VASServiceTypeText,
      _VASChargeCodeText
      
}

Learn More