R_UNIVERSALALLOCATIONCYCLE

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Allocation Cycle'
@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel.usageType: {
    dataClass: #MASTER,
    serviceQuality: #C ,
    sizeCategory: #M  }
@AccessControl.privilegedAssociations: [ '_CreatedByUser' ]
define view entity R_UniversalAllocationCycle
  as select from I_UniversalAllocationCycle

  association [0..*] to I_AllocationPostingTypeText    as _AllocationPostingTypeText on  _AllocationPostingTypeText.AllocationPostingType = $projection.AllocationPostingType
  association [1]    to I_UnivAllocCycleCalculation    as _CycleCalc                 on  _CycleCalc.AllocationCycle          = $projection.AllocationCycle
                                                                                     and _CycleCalc.AllocationType           = $projection.AllocationType
                                                                                     and _CycleCalc.AllocationCycleStartDate = $projection.AllocationCycleStartDate
  association [1]    to I_CycleRunGroup                as _CycleRunGroup             on  $projection.AllocationType              = _CycleRunGroup.AllocationType
                                                                                     and $projection.Ledger                      = _CycleRunGroup.Ledger
                                                                                     and $projection.AllocationPostingType       = _CycleRunGroup.AllocationPostingType
                                                                                     and $projection.AllocationActualPlanVariant = _CycleRunGroup.AllocationActualPlanVariant
                                                                                     and $projection.AllocationCycleRunGroup     = _CycleRunGroup.AllocationCycleRunGroup
  association [0..1] to I_AllocationContextType        as _Context                   on  $projection.AllocationType = _Context.AllocationType
  association [0..*] to I_LedgerText                   as _LedgerText                on  $projection.Ledger = _LedgerText.Ledger
  association [1..1] to I_UserContactCard              as _CreatedByUser             on  $projection.CreatedByUser = _CreatedByUser.ContactCardID
  association [1..1] to I_UserContactCard              as _ChangedByUser             on  $projection.LastChangedByUser = _ChangedByUser.ContactCardID
  association [1..1] to I_UserContactCard              as _LastExecByUser            on  $projection.AllocationLastExecutedByUser = _LastExecByUser.ContactCardID
  association [1..1] to I_AllocationStatus             as _AllocationStatus          on  $projection.AllocationStatus = _AllocationStatus.AllocationStatus
  association [1..1] to I_AllocActualPlanVariant       as _ActualPlanVariant         on  $projection.AllocationActualPlanVariant = _ActualPlanVariant.AllocationActualPlanVariant
  association [1..1] to I_UniversalAllocationCycleNote as _CycleNote                 on  $projection.AllocationCycle          = _CycleNote.AllocationCycle
                                                                                     and $projection.AllocationType           = _CycleNote.AllocationType
                                                                                     and $projection.AllocationCycleStartDate = _CycleNote.AllocationCycleStartDate
  association [0..1] to I_CompanyCode                  as _CompanyCode               on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_ControllingArea              as _ControllingArea           on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [0..1] to I_UnivAllocTopDwnDistrTemplate as _Template               on  $projection.AllocationType           = _Template.AllocationType
                                                                                         and $projection.AllocationCycle          = _Template.AllocationCycle
                                                                                         and $projection.AllocationCycleStartDate = _Template.AllocationCycleStartDate
  association [0..1] to I_UnivAllocTopDwnDistrTmplHdr as _TemplateHeader         on  _TemplateHeader.AllocationType      = $projection.AllocationType
                                                                                      and _TemplateHeader.TopDwnDistrTmplName = $projection.topdwndistrtmplname
{
  key cast( AllocationType as fco_ua_type preserving type )                                   as AllocationType,
  key AllocationCycle,
  key cast( AllocationCycleStartDate as fco_alloc_valid_from preserving type )                as AllocationCycleStartDate,
      //$session.user_timezone                                                                  as AllocationCycleTimeZone,

      AllocationCycleName                                                                     as AllocationCycleName, 
      Ledger,
      cast( CompanyCode as fis_bukrs preserving type )                                        as CompanyCode,
      cast( AllocationCycleCategory as fcom_category preserving type )                        as AllocationCycleCategory,
      ControllingArea,
      OperatingConcern,
      cast( AllocationCycleEndDate as fco_alloc_valid_to preserving type )                    as AllocationCycleEndDate,
      AllocationFrequency,
      cast( AllocationCreateDate as fcoua_alloc_created_on preserving type )                  as AllocationCreateDate,
      cast( CreatedByUser as fco_tag_created_user preserving type )                           as CreatedByUser,
      LastChangeDate,
      LastChangeTime,
      cast( LastChangedByUser as fco_tag_changed_user preserving type )                       as LastChangedByUser,
      cast( AllocationLastExecutedDate as fco_alloc_last_execute_data preserving type )       as AllocationLastExecutedDate,
      AllocationLastExecutedByUser,
      AllocationLastExecutionTime,
      AllocationCycleSet,
      ScaleNegativeTracingFactor,
      cast( AllocationPostingType as fco_alloc_posting_type preserving type )                 as AllocationPostingType,
      cast( AllocationActualPlanVariant as fco_alloc_ipknz preserving type )                  as AllocationActualPlanVariant,
      AllocationJob,
      AllocationIsCumulative,
      AllocIsCumulativeOptimized,
      AllocHasAggregatedProcess,
      AllocationCycleRunGroup,
      AllocationSubstitutionName,
      AllocFundMgmtIsActive,
      AllocationIsBalanceSheetActive,
      AllocHasDerivdFundFrmRcpnt,
      AllocIsDerivdFuncAreaFrmRcpnt,
      AllocIsDerivdGrantFrmRcpnt,
      AllocIsDerivdBudgedPerdRcpnt,
      AllocationLedgerGroup,
      AllocationIsPeriodShiftActive,
      AllocationPeriodDeltaSize,
      AllocIsProdnMnthDerivd,
      AllocationIsVariableQuantity,
      AllocationValuationType,
      cast( CycleIsDeltaProcessEnabled as fco_alloc_delta_process_enable preserving type )    as CycleIsDeltaProcessEnabled,
      cast(case when AllocationCycleIsIterative = 'I'
            then 'X'
            else ''
           end as fco_alloc_iterative preserving type)                                        as AllocationCycleIsIterative,
      cast( CycleIsParallelLedgerEnabled as fco_alloc_parallel_ledger preserving type )       as CycleIsParallelLedgerEnabled,
      cast( CycleIsAttributedLineItmEnbld as fco_alloc_enbl_attr_line_items preserving type ) as CycleIsAttributedLineItmEnbld,

      cast( dats_tims_to_tstmp(
        LastChangeDate,
        LastChangeTime,
        abap_system_timezone( $session.client,'NULL' ),
        $session.client, 'NULL' ) as vdm_lastchangedon )                                      as LastChangeDateTime,

      cast( '' as fco_alloc_posting_type_text )                                               as AllocationPostingTypeText,
      cast( _CycleCalc.AllocationStatus as fcoua_allocation_status preserving type )          as AllocationStatus,
      _Template.UnivAllocTopDwnDistrCycleHash,
      _Template.TopDwnDistrTmplName,
      _TemplateHeader,
      _AllocationPostingTypeText,
      _CycleCalc,
      _CycleRunGroup,
      _LedgerText,
      _CreatedByUser,
      _ChangedByUser,
      _LastExecByUser,
      _AllocationStatus,
      _ActualPlanVariant,
      _Template,
      _CycleNote,
      _CompanyCode,
      _ControllingArea,
      _Context
}