R_UNIVALLOCATIONSEGMENTTEXTTP

CDS View

Text for Allocation Segment

R_UNIVALLOCATIONSEGMENTTEXTTP is a CDS View in S/4HANA. Text for Allocation Segment. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_UnivAllocationSegmentTextTP view_entity projection CONSUMPTION Allocation Segment Description 
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Text for Allocation Segment'
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel: {
  dataCategory: #TEXT,
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #A,
    sizeCategory: #M } }
define view entity R_UnivAllocationSegmentTextTP
  as select from I_UnivAllocationSegmentText

  association        to parent R_UniversalAllocationSegmentTP as _Segment  on  $projection.AllocationType           = _Segment.AllocationType
                                                                           and $projection.AllocationCycle          = _Segment.AllocationCycle
                                                                           and $projection.AllocationCycleStartDate = _Segment.AllocationCycleStartDate
                                                                           and $projection.AllocationCycleSegment   = _Segment.AllocationCycleSegment

  association [1..1] to R_UniversalAllocationCycleTP          as _Cycle    on  $projection.AllocationType           = _Cycle.AllocationType
                                                                           and $projection.AllocationCycle          = _Cycle.AllocationCycle
                                                                           and $projection.AllocationCycleStartDate = _Cycle.AllocationCycleStartDate

  association [0..1] to I_Language                            as _Language on  $projection.LanguageCode = _Language.Language

{
  key LanguageCode,
  key AllocationType,
  key AllocationCycle,
  key AllocationCycleStartDate,
  key AllocationCycleSegment,
      AllocationSegmentDescription,

      _Cycle,
      _Segment,
      _Language
}

Learn More