R_UNIVERSALALLOCATIONCYCLETP

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Allocation Cycle Draft'
@VDM: { viewType: #TRANSACTIONAL,
        lifecycle.contract.type: #SAP_INTERNAL_API }
@ObjectModel: {
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory: #M },
  sapObjectNodeType.name: 'AllocationCycle',
  semanticKey: [ 'AllocationType','AllocationCycle', 'AllocationCycleStartDate' ] }
@AccessControl.privilegedAssociations: [ '_CreatedByUser' ]
define root view entity R_UniversalAllocationCycleTP
  as select from R_UniversalAllocationCycle

  composition [0..*] of R_UniversalAllocationSegmentTP as _Segment
  composition [0..*] of R_UnivAllocFieldDerivationTP   as _FieldDerivation
  composition [0..*] of R_UnivAllocCycleFieldGroupTP   as _FieldGroup
  composition [0..*] of R_UnivAllocTagCycAssignmentTP  as _TagAssignment
  composition [0..*] of R_UnivAllocationCycleTextTP    as _Text
  composition [0..1] of R_UnivAllocTopDwnDistrTmplTP   as _TopDownDistributionTemplate
{
  key AllocationType,
  key AllocationCycle,
  key AllocationCycleStartDate,
      //AllocationCycleTimeZone,

      AllocationCycleName,
      Ledger,
      CompanyCode,
      AllocationCycleCategory,
      ControllingArea,
      OperatingConcern,
      AllocationCycleEndDate,
      AllocationFrequency,
      @Semantics.systemDate.createdAt: true
      AllocationCreateDate,
      @Semantics.user.createdBy: true
      CreatedByUser,
      @Semantics.systemDate.lastChangedAt: true
      LastChangeDate,
      @Semantics.systemTime.lastChangedAt: true
      LastChangeTime,
      @Semantics.user.lastChangedBy: true
      LastChangedByUser,
      AllocationLastExecutedDate,
      AllocationLastExecutedByUser,
      AllocationLastExecutionTime,
      AllocationCycleSet,
      ScaleNegativeTracingFactor,
      AllocationPostingType,
      AllocationActualPlanVariant,
      AllocationJob,
      AllocationIsCumulative,
      AllocIsCumulativeOptimized,
      AllocHasAggregatedProcess,
      AllocationCycleRunGroup,
      AllocationSubstitutionName,
      AllocFundMgmtIsActive,
      AllocationIsBalanceSheetActive,
      AllocHasDerivdFundFrmRcpnt,
      AllocIsDerivdFuncAreaFrmRcpnt,
      AllocIsDerivdGrantFrmRcpnt,
      AllocIsDerivdBudgedPerdRcpnt,
      AllocationLedgerGroup,
      AllocationIsPeriodShiftActive,
      AllocationPeriodDeltaSize,
      AllocIsProdnMnthDerivd,
      AllocationIsVariableQuantity,
      AllocationValuationType,
      CycleIsDeltaProcessEnabled,
      AllocationCycleIsIterative,
      CycleIsParallelLedgerEnabled,
      CycleIsAttributedLineItmEnbld,
      AllocationStatus,
      cast ( case AllocationStatus
        when 'P' then 2 //yellow

        when 'L' then 1 //red

        else 3 //green

      end as eve_tv_criticality ) as CriticalityCode,

      @Semantics.systemDateTime.lastChangedAt: true
      LastChangeDateTime,
      @Semantics.systemDateTime.localInstanceLastChangedAt: true
      LastChangeDateTime as LocalLastChangeDateTime,
      @Semantics.text: true
      cast( _CycleNote.NoteText as fcoua_cycle_note ) as NoteText,

      cast('' as fco_tag_id)                          as AllocationTagID,
      $session.system_language      as LanguageCode,
      
      @Semantics.booleanIndicator: true
      cast (case when AllocationType = 'ACDOC_PA' and AllocationPostingType = 'K'
                 then //TDD cycle

                    case when UnivAllocTopDwnDistrCycleHash = _TemplateHeader.TopDwnDistrTmplHash
                      then 'X'
                      else ''
                    end
                  else //other cycles

                    'X'
          end as fco_alloc_consistency preserving type) as AllocationCycleIsConsistent,
      
      _Segment,
      _FieldDerivation,
      _FieldGroup,
      _CycleNote,
      _TagAssignment,
      _Text,
      _TopDownDistributionTemplate,
      //Texts

      _AllocationPostingTypeText,
      _CycleCalc,
      _CycleRunGroup,
      _LedgerText,
      _CreatedByUser,
      _ChangedByUser,
      _LastExecByUser,
      _AllocationStatus,
      _ActualPlanVariant,
      _CompanyCode,
      _ControllingArea,
      _Context

}