R_TRANSPORDITEMBATCHTP

CDS View

Transportation Order Item Batch - TP

R_TRANSPORDITEMBATCHTP is a CDS View in S/4HANA. Transportation Order Item Batch - TP. 6 CDS views read from this table.

Used by 6 CDS view(s)

CDS Views using this table (6)

ViewTypeJoinVDMDescription
A_FreightBookingItemBatch view_entity projection CONSUMPTION Freight Booking Item Batch
A_FreightOrderItemBatch view_entity projection CONSUMPTION Freight Order Item Batch
A_FreightUnitItemBatch view_entity projection CONSUMPTION Freight Unit Item Batch
I_FreightBookingItemBatchTP view_entity projection TRANSACTIONAL Freight Booking Item Batch - TP
I_FreightOrderItemBatchTP view_entity projection TRANSACTIONAL Freight Order Item Batch - TP
I_FreightUnitItemBatchTP view_entity projection TRANSACTIONAL Freight Unit Item Batch - TP 
@EndUserText.label: 'Transportation Order Item Batch - TP'

@ObjectModel: { semanticKey:       ['Batch'],
                representativeKey: 'TranspOrdItemBatchUUID',
                usageType:         { sizeCategory:   #L,
                                     serviceQuality: #B,
                                     dataClass:      #TRANSACTIONAL }}

@AccessControl: { authorizationCheck:    #MANDATORY,
                  personalData.blocking: #('TRANSACTIONAL_DATA') }
                  
@VDM:         { viewType:                #TRANSACTIONAL,
                lifecycle.contract.type: #SAP_INTERNAL_API }

                  
@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST]
@Metadata.ignorePropagatedAnnotations: true

define view entity R_TranspOrdItemBatchTP
  as select from I_TranspOrdItemBatch as TransportationOrderItemBatch
  
  association        to parent R_TransportationOrderItemTP as _TransportationOrderItem on $projection.TransportationOrderItemUUID = _TransportationOrderItem.TransportationOrderItemUUID
  association [1..1] to R_TransportationOrderTP            as _TransportationOrder     on $projection.TransportationOrderUUID = _TransportationOrder.TransportationOrderUUID
{
      // Attributes

  key TransportationOrderItemBatch.TranspOrdItemBatchUUID,
      TransportationOrderItemBatch.TransportationOrderUUID,
      TransportationOrderItemBatch.TransportationOrderItemUUID,
      
      TransportationOrderItemBatch.Batch,
      TransportationOrderItemBatch.ProductID,
      
      TransportationOrderItemBatch.BatchBySupplier,
      TransportationOrderItemBatch.ManufactureDate,
      TransportationOrderItemBatch.ShelfLifeExpirationDate,
      
      // (Technical/Hidden) Attributes

      _TransportationOrder.TransportationOrderCategory, 

      // Associations

      @ObjectModel.association.type:  [ #TO_COMPOSITION_ROOT ]
      _TransportationOrder,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT ]
      _TransportationOrderItem
  }

Learn More