R_RECONTRREMINDERRULEPARAMTP

CDS View

Real Estate Reminder Rule Parameter

R_RECONTRREMINDERRULEPARAMTP is a CDS View in S/4HANA. Real Estate Reminder Rule Parameter. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_REContrReminderRuleParamTP view_entity projection CONSUMPTION Real Estate Reminder Rule Parameter TP 
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Real Estate Reminder Rule Parameter'

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]

@ObjectModel.representativeKey:  'REReminderNumber'
@ObjectModel.semanticKey: ['InternalRealEstateNumber', 'REReminderNumber' ]
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #L


define view entity R_REContrReminderRuleParamTP
  as select from I_REReminderObjRuleParam
  association        to parent R_REContrReminderRuleMainTP as _REReminderRuleMain  on  $projection.InternalRealEstateNumber = _REReminderRuleMain.InternalRealEstateNumber
                                                                                   and $projection.REReminderNumber         = _REReminderRuleMain.REReminderNumber
//                                                                                   and $projection.REReminderRule           = _REReminderRuleMain.REReminderRule

  association [1..1] to R_REContractTP                     as _REContract          on  $projection.InternalRealEstateNumber = _REContract.InternalRealEstateNumber
  association [1..1] to I_REReminderObjRuleParamAddl       as _REReminderParamAddl on  $projection.InternalRealEstateNumber  = _REReminderParamAddl.InternalRealEstateNumber
                                                                                   and $projection.REReminderNumber          = _REReminderParamAddl.REReminderNumber
                                                                                   and $projection.REReminderRuleParamNumber = _REReminderParamAddl.REReminderRuleParamNumber
{
  key InternalRealEstateNumber,
  key REReminderNumber,
  key REReminderRuleParamNumber,
  key REReminderRule,
      REReminderParamType,
      REReminderParamDate,
      REReminderParamNmbr,
      REReminderParamIsBoolean,

      _REReminderParamAddl.REReminderParamDateIsHidden as REReminderParamDateIsHidden,
      _REReminderParamAddl.REReminderParamNmbrIsHidden as REReminderParamNmbrIsHidden,
      _REReminderParamAddl.REReminderParamIndIsHidden  as REReminderParamIndIsHidden,

      /* Associations */
      _REReminderRuleMain,
      _REReminderParamAddl,
      _REReminderParam,
      _REReminderRule,
      _REContract
} where
  InternalRealEstateNumber like 'IS%'

Learn More