R_RECONTRREGISTRYENTRYTP

CDS View

Real Estate Registry Entry TP

R_RECONTRREGISTRYENTRYTP is a CDS View in S/4HANA. Real Estate Registry Entry TP. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_REContractRegistryEntryTP view_entity projection CONSUMPTION RE Contract Registry Entry 
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Real Estate Registry Entry TP'

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]

@ObjectModel.representativeKey:  'RERegistrationUUID'
@Analytics.technicalName: 'RRECNREGISTRY'
@ObjectModel.semanticKey: ['RERegistrationUUID' ]
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L


define view entity R_REContrRegistryEntryTP
  as select from I_RERegistrationEntryMerge
  association to parent R_REContractTP as _REContract on $projection.TargetInternalRealEstateNumber = _REContract.InternalRealEstateNumber
{
  key   RERegistrationUUID,
  key   TargetInternalRealEstateNumber,
        REStatusObjectSource,
        REStatusObjectTarget,
        RERegistrationReason,
        RERegistrationState,
        ValidityStartDate,
        ValidityEndDate,
        //        RERegistrationUUID,

        //        RERegistrationIntReference,

        RERegistrationIntReferenceText,
        //        RERegistrationInformation,

        RERegistrationInformationText,
        Responsible,
        RERegistrationPriority,
        CreatedByUser,
        CreationDate,
        CreationTime,
      @Semantics.systemDateTime.createdAt: true
          cast (dats_tims_to_tstmp( CreationDate,
                              CreationTime,
                              abap_system_timezone( $session.client,'NULL' ), $session.client, 'NULL' ) as vdm_creationdatetime) as CreationDateTime,
        RESourceOfCreation,
        LastChangedByUser,
        LastChangeDate,
        LastChangeTime,
        @Semantics.systemDateTime.lastChangedAt: true
        cast (dats_tims_to_tstmp( LastChangeDate,
                              LastChangeTime,
                              abap_system_timezone( $session.client,'NULL' ), $session.client, 'NULL' ) as vdm_lastchangedon)    as LastChangeDateTime,
        RESourceOfChange,

        _CreatedByUser,
        _ChangedByUser,
        _ResponsibleUser,
        _RERegistrationReason,
        _RERegistrationState,
        _REObjectTypeDetailsSource,
        _REObjectTypeDetailsTarget,

        _REContract
}
where
      IsCompleted                                      = ' '
  and _RERegistrationState.RERegistrationIsVisibleInWl = 'X'

Learn More