R_RABUSRECNCLNFORCONTRACTTP

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED

@EndUserText.label: 'Business Reconciliation Contract Info'

@ObjectModel.sapObjectNodeType.name: 'RevenueAccountingContract'
@ObjectModel.usageType: { sizeCategory: #XXL, serviceQuality: #C, dataClass: #MIXED }

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL

define root view entity R_RABusRecnclnForContractTP
  as select from P_RABusRecnclnForContract as _RABusRecnclnContract

    left outer to one join P_RADataValidationForContract as _DataValidationContract
      on _DataValidationContract.RevenueAccountingContract = _RABusRecnclnContract.RevenueAccountingContract

    left outer to one join P_RALiabilityAssetForContract as _LiabilityAssetContract
      on _LiabilityAssetContract.RevenueAccountingContract = _RABusRecnclnContract.RevenueAccountingContract

    left outer to one join P_RABusRecnclnPostdAmtForContr as PostedAmountForContract
      on  _RABusRecnclnContract.CompanyCode               = PostedAmountForContract.CompanyCode
      and _RABusRecnclnContract.AccountingPrinciple       = PostedAmountForContract.AccountingPrinciple
      and _RABusRecnclnContract.RevenueAccountingContract = PostedAmountForContract.RevenueAccountingContract

  composition [0..*] of R_RABusRecnclnForPerfOblgnTP as _BusRecnclnPerfOblgn

  association [1..1] to I_LogicalSystem            as _LogicalSystem
    on $projection.LogicalSystem = _LogicalSystem.LogicalSystem

  association [1..1] to I_RevnAcctgSenderComponent as _RevnAcctgSenderComponent
    on $projection.RevnAcctgSenderComponent = _RevnAcctgSenderComponent.RevnAcctgSenderComponent

{
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key _RABusRecnclnContract.CompanyCode,

      @ObjectModel.foreignKey.association: '_AccountingPrinciple'
  key _RABusRecnclnContract.AccountingPrinciple,

  key _RABusRecnclnContract.RevenueAccountingContract,

      _RABusRecnclnContract._Contract.RevnAcctgContractDescription                                                  as RevnAcctgContractDescription,
      _RABusRecnclnContract._Contract.BusinessPartner                                                               as BusinessPartner,
      _RABusRecnclnContract._Contract._BusinessPartner.BusinessPartnerName                                          as BusinessPartnerName,
      _RABusRecnclnContract._Contract.Customer                                                                      as Customer,
      _RABusRecnclnContract._Contract._Customer.CustomerName                                                        as CustomerName,
      _RABusRecnclnContract._Contract.RevnAcctgContractStatus                                                       as RevnAcctgContractStatus,

      _RABusRecnclnContract._Contract._RAContractStatus._Text[
        1: Language = $session.system_language].RevnAcctgContractStatusName                                         as RevnAcctgContractStatusName,

      // Flag to hide some contract header value

      case
        when _RABusRecnclnContract._Contract.RAContrBalanceDerivationRule = '1' 
        then cast('X' as boole_d preserving type)
        else cast(' ' as boole_d preserving type)
      end                                                                                                           as RAContrBalanceIsDfrrdRevn,

      case
        when _RABusRecnclnContract._Contract.RAContrBalanceDerivationRule = '2' 
        then cast('X' as boole_d preserving type)
        else cast(' ' as boole_d preserving type)
      end                                                                                                           as RAContrBalanceIsLiability,

      @ObjectModel.foreignKey.association: '_RevnAcctgSenderComponent'
      cast('' as farr_rai_srcco)                                                                                    as RevnAcctgSenderComponent,

      @ObjectModel.foreignKey.association: '_LogicalSystem'
      cast('' as farr_rai_srcls)                                                                                    as LogicalSystem,

      cast(' ' as boole_d preserving type)                                                                          as ReportIsOnlineMode,

      _RABusRecnclnContract.SalesDocumentCurrency,
      _RABusRecnclnContract.CompanyCodeCurrency,
      _RABusRecnclnContract.AdditionalCurrency1,
      _RABusRecnclnContract.AdditionalCurrency2,

      @Semantics.amount.currencyCode: 'SalesDocumentCurrency'
      cast(_RABusRecnclnContract.OplContractualPrcInSlsDocCrcy as farr_cds_op_cond_price preserving type)           as OplContractualPrcInSlsDocCrcy,

      @Semantics.amount.currencyCode: 'SalesDocumentCurrency'
      cast(_RABusRecnclnContract.DeltaEffectiveAmtInSlsDocCrcy as farr_contractual_price_org preserving type)       as DeltaEffectiveAmtInSlsDocCrcy, // Contract Price from Operational Doc


      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast(_RABusRecnclnContract.RAOplCostAmtInSlsDocCrcy as farr_cds_op_cond_cost preserving type)                 as RAOplCostAmtInSlsDocCrcy,

      @Semantics.amount.currencyCode: 'SalesDocumentCurrency'
      cast(_RABusRecnclnContract.TotalInvoicedAmtInSlsDocCrcy as farr_opl_invoiced_amt preserving type)             as TotalInvoicedAmtInSlsDocCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast(_RABusRecnclnContract.RAOplCostPriceAmtInSlsDocCrcy as farr_cds_cost_price preserving type)              as RAOplCostPriceAmtInSlsDocCrcy,

      @Semantics.amount.currencyCode: 'SalesDocumentCurrency'
      cast(_RABusRecnclnContract._Contract.TotContractualPrcInSlsDocCrcy as farr_transaction_price preserving type) as ContractualPrcInSlsDocCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast(_RABusRecnclnContract.RAPerfOblgnCostAmtInSlsDocCrcy as farr_cost_total preserving type)                 as RAPerfOblgnCostAmtInSlsDocCrcy, // Total Cost


      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast(_RABusRecnclnContract.RADeltaRecgdCostInSlsDocCrcy as farr_actual_cost  preserving type)                 as RADeltaRecgdCostInSlsDocCrcy, // actual cost


      @Semantics.amount.currencyCode: 'SalesDocumentCurrency'
      cast(_RABusRecnclnContract.RARecognizedRevnInSlsDocCrcy as farr_recog_amt  preserving type)                   as RARecognizedRevnInSlsDocCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast(_RABusRecnclnContract.RARecgdCostAmountInSlsDocCrcy as farr_recog_cost  preserving type)                 as RARecgdCostAmountInSlsDocCrcy,

      @Semantics.amount.currencyCode: 'SalesDocumentCurrency'
      cast(_RABusRecnclnContract.PerPerdInvoicedAmtInSlsDocCrcy as farr_invoiced_amt  preserving type)              as PerPerdInvoicedAmtInSlsDocCrcy, // Invoiced Amount


      @Semantics.amount.currencyCode: 'SalesDocumentCurrency'
      cast(PostedAmountForContract.PostedRevnInSlsDocCrcy as farr_cds_posted_rv preserving type)                    as PostedRevnInSlsDocCrcy,

      @Semantics.amount.currencyCode: 'SalesDocumentCurrency'
      cast(PostedAmountForContract.PostedInvoiceAmtInSlsDocCrcy as farr_cds_posted_ic preserving type)              as PostedInvoiceAmtInSlsDocCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast(PostedAmountForContract.RAPostedCostInSlsDocCrcy as farr_cds_posted_co preserving type)                  as RAPostedCostInSlsDocCrcy,

      @Semantics.amount.currencyCode: 'SalesDocumentCurrency'
      cast(PostedAmountForContract.RAPostedUnbilldRblsAmount as farr_cds_posted_ur preserving type)                 as RAPostedUnbilldRblsAmount,

      @Semantics.amount.currencyCode: 'SalesDocumentCurrency'
      cast(PostedAmountForContract.RADeferredRevenueInSlsDocCrcy as farr_cds_posted_dr preserving type)             as RADeferredRevenueInSlsDocCrcy,

      @Semantics.amount.currencyCode: 'SalesDocumentCurrency'
      cast(PostedAmountForContract.RAContractAssetsAmount as farr_cds_posted_ca preserving type)                    as RAContractAssetsAmount,

      @Semantics.amount.currencyCode: 'SalesDocumentCurrency'
      cast(PostedAmountForContract.RAContrLiabilitiesAmount as farr_cds_posted_cl preserving type)                  as RAContrLiabilitiesAmount,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast(PostedAmountForContract.PostdDfrrdCostAmtInSlsDocCrcy as farr_cds_posted_cj preserving type)             as PostdDfrrdCostAmtInSlsDocCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast(PostedAmountForContract.RAPostedRevenueAmtInCoCodeCrcy as farr_cds_posted_rv_lc1 preserving type)        as RAPostedRevenueAmtInCoCodeCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast(PostedAmountForContract.RAPostedInvoiceAmtInCoCodeCrcy as farr_cds_posted_ic_lc1 preserving type)        as RAPostedInvoiceAmtInCoCodeCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast(PostedAmountForContract.RAPostedCostAmountInCoCodeCrcy as farr_cds_posted_co_lc1 preserving type)        as RAPostedCostAmountInCoCodeCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast(PostedAmountForContract.PostdUnbilldRblAmtInCoCodeCrcy as farr_cds_posted_ur_lc1 preserving type)        as PostdUnbilldRblAmtInCoCodeCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast(PostedAmountForContract.PostedDfrrdRevnAmtInCoCodeCrcy as farr_cds_posted_dr_lc1 preserving type)        as PostedDfrrdRevnAmtInCoCodeCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast(PostedAmountForContract.RAPostdContrAstAmtInCoCodeCrcy as farr_cds_posted_ca_lc1 preserving type)        as RAPostdContrAstAmtInCoCodeCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast(PostedAmountForContract.PostdContrLbltyAmtInCoCodeCrcy as farr_cds_posted_cl_lc1 preserving type)        as PostdContrLbltyAmtInCoCodeCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast(PostedAmountForContract.PostdDfrrdCostAmtInCoCodeCrcy as farr_cds_posted_cj_lc1 preserving type)         as PostdDfrrdCostAmtInCoCodeCrcy,

      @Semantics.amount.currencyCode: 'AdditionalCurrency1'
      cast(PostedAmountForContract.RAPostedRevenueAmtInAddlCrcy1 as farr_cds_posted_rv_lc2 preserving type)         as RAPostedRevenueAmtInAddlCrcy1,

      @Semantics.amount.currencyCode: 'AdditionalCurrency1'
      cast(PostedAmountForContract.RAPostedInvoiceAmtInAddlCrcy1 as farr_cds_posted_ic_lc2 preserving type)         as RAPostedInvoiceAmtInAddlCrcy1,

      @Semantics.amount.currencyCode: 'AdditionalCurrency1'
      cast(PostedAmountForContract.RAPostedCostAmountInAddlCrcy1 as farr_cds_posted_co_lc2 preserving type)         as RAPostedCostAmountInAddlCrcy1,

      @Semantics.amount.currencyCode: 'AdditionalCurrency1'
      cast(PostedAmountForContract.PostedUnbilldRblAmtInAddlCrcy1 as farr_cds_posted_ur_lc2 preserving type)        as PostedUnbilldRblAmtInAddlCrcy1,

      @Semantics.amount.currencyCode: 'AdditionalCurrency1'
      cast(PostedAmountForContract.RAPostdDfrrdRevnAmtInAddlCrcy1 as farr_cds_posted_dr_lc2 preserving type)        as RAPostdDfrrdRevnAmtInAddlCrcy1,

      @Semantics.amount.currencyCode: 'AdditionalCurrency1'
      cast(PostedAmountForContract.RAPostedContrAstAmtInAddlCrcy1 as farr_cds_posted_ca_lc2 preserving type)        as RAPostedContrAstAmtInAddlCrcy1,

      @Semantics.amount.currencyCode: 'AdditionalCurrency1'
      cast(PostedAmountForContract.PostedContrLbltyAmtInAddlCrcy1 as farr_cds_posted_cl_lc2 preserving type)        as PostedContrLbltyAmtInAddlCrcy1,

      @Semantics.amount.currencyCode: 'AdditionalCurrency1'
      cast(PostedAmountForContract.RAPostdDfrrdCostAmtInAddlCrcy1 as farr_cds_posted_cj_lc2 preserving type)        as RAPostdDfrrdCostAmtInAddlCrcy1,

      @Semantics.amount.currencyCode: 'AdditionalCurrency2'
      cast(PostedAmountForContract.RAPostedRevenueAmtInAddlCrcy2 as farr_cds_posted_rv_lc3 preserving type)         as RAPostedRevenueAmtInAddlCrcy2,

      @Semantics.amount.currencyCode: 'AdditionalCurrency2'
      cast(PostedAmountForContract.RAPostedInvoiceAmtInAddlCrcy2 as farr_cds_posted_ic_lc3 preserving type)         as RAPostedInvoiceAmtInAddlCrcy2,

      @Semantics.amount.currencyCode: 'AdditionalCurrency2'
      cast(PostedAmountForContract.RAPostedCostAmountInAddlCrcy2 as farr_cds_posted_co_lc3 preserving type)         as RAPostedCostAmountInAddlCrcy2,

      @Semantics.amount.currencyCode: 'AdditionalCurrency2'
      cast(PostedAmountForContract.PostedUnbilldRblAmtInAddlCrcy2 as farr_cds_posted_ur_lc3 preserving type)        as PostedUnbilldRblAmtInAddlCrcy2,

      @Semantics.amount.currencyCode: 'AdditionalCurrency2'
      cast(PostedAmountForContract.RAPostdDfrrdRevnAmtInAddlCrcy2 as farr_cds_posted_dr_lc3 preserving type)        as RAPostdDfrrdRevnAmtInAddlCrcy2,

      @Semantics.amount.currencyCode: 'AdditionalCurrency2'
      cast(PostedAmountForContract.RAPostedContrAstAmtInAddlCrcy2 as farr_cds_posted_ca_lc3 preserving type)        as RAPostedContrAstAmtInAddlCrcy2,

      @Semantics.amount.currencyCode: 'AdditionalCurrency2'
      cast(PostedAmountForContract.PostedContrLbltyAmtInAddlCrcy2 as farr_cds_posted_cl_lc3 preserving type)        as PostedContrLbltyAmtInAddlCrcy2,

      @Semantics.amount.currencyCode: 'AdditionalCurrency2'
      cast(PostedAmountForContract.RAPostdDfrrdCostAmtInAddlCrcy2 as farr_cds_posted_cj_lc3 preserving type)        as RAPostdDfrrdCostAmtInAddlCrcy2,

      @Semantics.amount.currencyCode: 'SalesDocumentCurrency'
      cast(_RABusRecnclnContract.SrceRecgdRevnAmtInSlsDocCrcy as farr_sched_rv_cumltv  preserving type)             as SrceRecgdRevnAmtInSlsDocCrcy,

      @Semantics.amount.currencyCode: 'SalesDocumentCurrency'
      cast(_RABusRecnclnContract.SrceRecgdCostAmtInSlsDocCrcy as farr_sched_co_cumltv  preserving type)             as SrceRecgdCostAmtInSlsDocCrcy,

      @Semantics.amount.currencyCode: 'SalesDocumentCurrency'
      cast(_RABusRecnclnContract.SrceRecgdInvcAmtInSlsDocCrcy as farr_sched_ic_cumltv  preserving type)             as SrceRecgdInvcAmtInSlsDocCrcy,

      @Semantics.amount.currencyCode: 'SalesDocumentCurrency'
      cast(_RABusRecnclnContract.SuspendedRevnAmtInSlsDocCrcy as farr_cds_suspended_revenue preserving type)        as SuspendedRevnAmtInSlsDocCrcy,

      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      cast(_RABusRecnclnContract.SuspendedCostAmtInSlsDocCrcy as farr_cds_suspended_cost preserving type)           as SuspendedCostAmtInSlsDocCrcy,

      _RABusRecnclnContract.ContractualPriceCriticality,
      _RABusRecnclnContract.TotalCostCriticality,
      _RABusRecnclnContract.InvoicedAmountCriticality,
      _RABusRecnclnContract.OrderQuantityCriticality,
      _RABusRecnclnContract.ActualCostCriticality,

      cast(_RABusRecnclnContract.RAContractIsInconsistent as farr_inconsistency_error preserving type)              as RAContractIsInconsistent,

      _DataValidationContract.DataValidationHasError                                                                as DataValidationHasError,
      _DataValidationContract.ValidationDateTime                                                                    as ValidationDateTime,

      case
        when _LiabilityAssetContract.RAContrLiabilityAssetIsCalcd = 'X'
        then cast(' ' as farr_cds_liab_asset_bizrecon preserving type)
        else cast('X' as farr_cds_liab_asset_bizrecon preserving type)
      end                                                                                                           as RAContrLiabilityAssetIsCalcd,

      cast('' as farr_operational_doc)                                                                              as RevnAcctgOperationalDocument,

      _RABusRecnclnContract._Contract.IsBusinessPurposeCompleted,

      _RABusRecnclnContract._Contract,
      _BusRecnclnPerfOblgn,
      _RABusRecnclnContract._CompanyCode,
      _RABusRecnclnContract._AccountingPrinciple,
      _LogicalSystem,
      _RevnAcctgSenderComponent

}