R_PURCHASINGDOCUMENT
Purchasing Document
R_PURCHASINGDOCUMENT is a CDS View in S/4HANA. Purchasing Document. It contains 72 fields. 12 CDS views read from this table.
CDS Views using this table (12)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_MaintOrdOpOutlineAgreementVH | view_entity | from | CONSUMPTION | Outline Agreement |
| I_PurchaseOrder | view | from | BASIC | Purchase Order |
| I_Schedgagrmthdr | view | from | BASIC | Scheduling Agreement Header |
| P_PurContrMassUpdt | view | from | CONSUMPTION | Purchase Contract Hdr |
| P_PurContrValdtySts | view | from | CONSUMPTION | Contract Validity Status Calculation |
| R_CentralPurchaseContract | view | from | BASIC | Central Purchase Contract Base View |
| R_CentralRequestForQuotation | view | from | BASIC | Restricted View for Central Request For Quotation Header |
| R_CentralSupplierQuotation | view | from | BASIC | Restricted View for Central Supplier Quotation Header |
| R_PurchaseContract | view | from | BASIC | Purchase Contract Base View |
| R_PurchaseOrder | view | from | BASIC | Purchase Order Internal View |
| R_PurgSchedulingAgreementHdr | view_entity | from | BASIC | Scheduling Agreement Header |
| R_StockTransportOrder | view_entity | from | BASIC | Stock Transport Order |
Fields (72)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | PurchasingDocument | PurchaseContract,SchedulingAgreement | 3 |
| _CompanyCode | _CompanyCode | 1 | |
| _CreatedByUser | _CreatedByUser | 1 | |
| _DocumentCurrency | _DocumentCurrency | 2 | |
| _IncotermsClassification | _IncotermsClassification | 2 | |
| _InvoicingParty | _InvoicingParty | 2 | |
| _Language | _Language | 1 | |
| _PaymentTerms | _PaymentTerms | 1 | |
| _PurchasingDocumentCategory | _PurchasingDocumentCategory | 1 | |
| _PurchasingDocumentType | _PurchasingDocumentType | 1 | |
| _PurchasingGroup | _PurchasingGroup | 1 | |
| _PurchasingOrganization | _PurchasingOrganization | 2 | |
| _Supplier | _Supplier | 2 | |
| _SupplyingSupplier | _SupplyingSupplier | 2 | |
| BindingPeriodValidityEndDate | BindingPeriodValidityEndDate | 2 | |
| CashDiscount1Days | CashDiscount1Days | 4 | |
| CashDiscount1Percent | CashDiscount1Percent | 4 | |
| CashDiscount2Days | CashDiscount2Days | 4 | |
| CashDiscount2Percent | CashDiscount2Percent | 4 | |
| CompanyCode | CompanyCode | 4 | |
| CorrespncExternalReference | CorrespncExternalReference | 2 | |
| CorrespncInternalReference | CorrespncInternalReference | 3 | |
| CreatedByUser | CreatedByUser | 4 | |
| CreationDate | CreationDate | 4 | |
| DocumentCurrency | DocumentCurrency | 4 | |
| ExchangeRate | ExchangeRate | 2 | |
| ExchangeRateIsFixed | ExchangeRateIsFixed | 2 | |
| FollowOnDocumentCategory | FollowOnDocumentCategory | 2 | |
| FollowOnDocumentType | FollowOnDocumentType,PurgDocFollowOnDocumentType | 2 | |
| IncotermsClassification | IncotermsClassification | 4 | |
| IncotermsLocation1 | IncotermsLocation1 | 4 | |
| IncotermsLocation2 | IncotermsLocation2 | 4 | |
| IncotermsSupChnDvtgLocAddlUUID | IncotermsSupChnDvtgLocAddlUUID | 2 | |
| IncotermsSupChnLoc1AddlUUID | IncotermsSupChnLoc1AddlUUID | 2 | |
| IncotermsSupChnLoc2AddlUUID | IncotermsSupChnLoc2AddlUUID | 2 | |
| IncotermsTransferLocation | IncotermsTransferLocation | 4 | |
| IncotermsVersion | IncotermsVersion | 4 | |
| InvoicingParty | InvoicingParty | 2 | |
| IsEndOfPurposeBlocked | IsEndOfPurposeBlocked | 4 | |
| Language | Language | 4 | |
| LastChangeDateTime | LastChangeDateTime | 4 | |
| NetPaymentDays | NetPaymentDays | 4 | |
| OverallTrdCmplncEmbargoSts | OverallTrdCmplncEmbargoSts | 1 | |
| OvrlTrdCmplncLegalCtrlChkSts | OvrlTrdCmplncLegalCtrlChkSts | 1 | |
| OvrlTrdCmplncSnctndListChkSts | OvrlTrdCmplncSnctndListChkSts | 1 | |
| PaymentTerms | PaymentTerms | 4 | |
| PricingDocument | CentralSuplrQuotationCondition | 1 | |
| PricingProcedure | PricingProcedure | 1 | |
| PurchasingDocumentCategory | PurchasingDocumentCategory | 4 | |
| PurchasingDocumentDeletionCode | PurchasingDocumentDeletionCode | 2 | |
| PurchasingDocumentOrderDate | PurchasingDocumentOrderDate | 3 | |
| PurchasingDocumentOrigin | PurchasingDocumentOrigin | 2 | |
| PurchasingDocumentSubtype | PurchasingDocumentSubtype | 2 | |
| PurchasingDocumentType | PurchasingDocumentType | 2 | |
| PurchasingGroup | PurchasingGroup | 4 | |
| PurchasingOrganization | PurchasingOrganization | 2 | |
| PurgAggrgdProdCmplncSuplrSts | PurgAggrgdProdCmplncSuplrSts | 2 | |
| QuotationEarliestSubmsnDate | QuotationEarliestSubmsnDate | 1 | |
| QuotationLatestSubmissionDate | QuotationLatestSubmissionDate | 2 | |
| QuotationSubmissionDate | QuotationSubmissionDate | 3 | |
| ScheduleAgreementHasReleaseDoc | ScheduleAgreementHasReleaseDoc | 2 | |
| Supplier | Supplier | 3 | |
| SupplierAddressID | SupplierAddressID | 2 | |
| SupplierPhoneNumber | SupplierPhoneNumber | 2 | |
| SupplierQuotationExternalID | SupplierQuotationExternalID | 3 | |
| SupplierRespSalesPersonName | SupplierRespSalesPersonName | 2 | |
| SupplyingSupplier | SupplyingSupplier | 2 | |
| TargetAmount | PurchaseContractTargetAmount,TargetAmount | 4 | |
| ValidityEndDate | PurContrValidityEndDate,ValidityEndDate | 3 | |
| ValidityStartDate | PurContrValidityStartDate,ValidityStartDate | 3 | |
| VATRegistration | CompanyVATRegistration | 2 | |
| VATRegistrationCountry | VATRegistrationCountry | 2 |
@EndUserText.label: 'Purchasing Document'
@AccessControl.authorizationCheck:#PRIVILEGED_ONLY
@VDM.viewType : #BASIC
@Metadata.ignorePropagatedAnnotations: true
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel: {
representativeKey: 'PurchasingDocument',
usageType.serviceQuality: #A,
usageType.sizeCategory: #L,
usageType.dataClass: #TRANSACTIONAL
}
@Analytics.technicalName: 'RMMPURCHASINGDOC'
@AccessControl.privilegedAssociations: [ '_SupplierAddress' ]
define view entity R_PurchasingDocument
as select from ekko as ekko //PurgDoc
association [1..1] to I_PurchasingDocumentCategory as _PurchasingDocumentCategory on $projection.PurchasingDocumentCategory = _PurchasingDocumentCategory.PurchasingDocumentCategory
association [0..1] to I_PurchasingDocumentType as _PurchasingDocumentType on $projection.PurchasingDocumentCategory = _PurchasingDocumentType.PurchasingDocumentCategory
and $projection.PurchasingDocumentType = _PurchasingDocumentType.PurchasingDocumentType
association [0..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [0..1] to I_User as _CreatedByUser on $projection.CreatedByUser = _CreatedByUser.UserID
association [0..1] to I_Supplier as _Supplier on $projection.Supplier = _Supplier.Supplier
association [0..1] to I_Supplier as _SupplyingSupplier on $projection.SupplyingSupplier = _SupplyingSupplier.Supplier
association [0..1] to I_Supplier as _InvoicingParty on $projection.InvoicingParty = _InvoicingParty.Supplier
association [0..1] to I_PaymentTerms as _PaymentTerms on $projection.PaymentTerms = _PaymentTerms.PaymentTerms
association [0..1] to I_Address as _SupplierAddress on $projection.ManualSupplierAddressID = _SupplierAddress.AddressID
association [0..1] to I_OrganizationAddress as _SupplierAddress_2 on $projection.ManualSupplierAddressID = _SupplierAddress_2.AddressID
and _SupplierAddress_2.AddressPersonID = ' '
and _SupplierAddress_2.AddressRepresentationCode = ' '
association [0..1] to I_PurchasingOrganization as _PurchasingOrganization on $projection.PurchasingOrganization = _PurchasingOrganization.PurchasingOrganization
association [0..1] to I_PurchasingGroup as _PurchasingGroup on $projection.PurchasingGroup = _PurchasingGroup.PurchasingGroup
association [0..1] to I_Currency as _DocumentCurrency on $projection.DocumentCurrency = _DocumentCurrency.Currency
association [0..1] to I_IncotermsClassification as _IncotermsClassification on $projection.IncotermsClassification = _IncotermsClassification.IncotermsClassification
association [0..1] to I_IncotermsVersion as _IncotermsVersion on $projection.IncotermsVersion = _IncotermsVersion.IncotermsVersion
association [0..1] to I_Plant as _SupplyingPlant on $projection.SupplyingPlant = _SupplyingPlant.Plant
association [0..*] to I_PurchasingDocumentItem as _PurchasingDocumentItem on $projection.PurchasingDocument = _PurchasingDocumentItem.PurchasingDocument
association [0..*] to I_PurchasingDocumentPartner as _PurchasingDocumentPartner on $projection.PurchasingDocument = _PurchasingDocumentPartner.PurchasingDocument
association [0..1] to I_PurchasingDocumentOrigin as _PurchasingDocumentOrigin on $projection.PurchasingDocumentOrigin = _PurchasingDocumentOrigin.PurchasingDocumentOrigin
association [0..1] to I_ReleaseCode as _ReleaseCode on $projection.ReleaseCode = _ReleaseCode.ReleaseCode
association [0..1] to I_PurchaseContract as _PurchaseContract on $projection.PurchaseContract = _PurchaseContract.PurchaseContract
association [0..1] to I_Language as _Language on $projection.Language = _Language.Language
association [0..1] to I_TaxCalculationProcedure as _PricingProcedure on $projection.PricingProcedure = _PricingProcedure.TaxCalculationProcedure
association [0..1] to I_PurchasingProcessingStatus as _PurchasingProcessingStatus on $projection.PurchasingProcessingStatus = _PurchasingProcessingStatus.PurchasingProcessingStatus
association [0..1] to I_OvrlTrdCmplncLegalCtrlChkSts as _OvrlTrdCmplncLegalCtrlChkSts on $projection.OvrlTrdCmplncLegalCtrlChkSts = _OvrlTrdCmplncLegalCtrlChkSts.OvrlTrdCmplncLegalCtrlChkSts
association [0..1] to I_OvrlTradeCmplncEmbargoStatus as _OverallTrdCmplncEmbargoSts on $projection.OverallTrdCmplncEmbargoSts = _OverallTrdCmplncEmbargoSts.OverallTrdCmplncEmbargoSts
association [0..1] to I_OvTrdCmplncSnctndListChkSts as _OvrlTrdCmplncSnctndListChkSts on $projection.OvrlTrdCmplncSnctndListChkSts = _OvrlTrdCmplncSnctndListChkSts.OvrlTrdCmplncSnctndListChkSts
// Text associations
association [0..*] to I_IncotermsClassificationText as _IncotermsClassificationText on $projection.IncotermsClassification = _IncotermsClassificationText.IncotermsClassification
association [0..*] to I_IncotermsVersionText as _IncotermsVersionText on $projection.IncotermsVersion = _IncotermsVersionText.IncotermsVersion
association [0..*] to I_CurrencyText as _DocumentCurrencyText on $projection.DocumentCurrency = _DocumentCurrencyText.Currency
association [0..*] to I_CountryText as _TaxReturnCountryText on $projection.TaxReturnCountry = _TaxReturnCountryText.Country
association [0..*] to I_CountryText as _VATRegistrationCountryText on $projection.VATRegistrationCountry = _VATRegistrationCountryText.Country
association [0..*] to I_PurgTotProdCmplncSuplrStsT as _PurgTotProdCmplncSuplrStsT on $projection.PurgAggrgdProdCmplncSuplrSts = _PurgTotProdCmplncSuplrStsT.PurgAggrgdProdCmplncSuplrSts
association [0..*] to I_PurgTotProdMarketabilityStsT as _PurgTotProdMarketabilityStsT on $projection.PurgAggrgdProdMarketabilitySts = _PurgTotProdMarketabilityStsT.PurgAggrgdProdMarketabilitySts
association [0..*] to I_PurgAggrgdSftyDataSheetStsT as _PurgAggrgdSftyDataSheetStsT on $projection.PurgAggrgdSftyDataSheetStatus = _PurgAggrgdSftyDataSheetStsT.PurgAggrgdSftyDataSheetStatus
association [0..*] to I_PurgTotDangerousGoodsStsT as _PurgTotDangerousGoodsStsT on $projection.PurgProdCmplncTotDngrsGoodsSts = _PurgTotDangerousGoodsStsT.PurgProdCmplncTotDngrsGoodsSts
association [0..*] to I_OvTrdComplLegalCtrlChkStsTxt as _OvTrdComplLegalCtrlChkStsTxt on $projection.OvrlTrdCmplncLegalCtrlChkSts = _OvTrdComplLegalCtrlChkStsTxt.OvrlTrdCmplncLegalCtrlChkSts
association [0..*] to I_OvrlTradeCmplncEmbargoStsTxt as _OvrlTradeCmplncEmbargoStsTxt on $projection.OverallTrdCmplncEmbargoSts = _OvrlTradeCmplncEmbargoStsTxt.OverallTrdCmplncEmbargoSts
association [0..*] to I_OvTrdComplSanctListChkStsTxt as _OvTrdComplSanctListChkStsTxt on $projection.OvrlTrdCmplncSnctndListChkSts = _OvTrdComplSanctListChkStsTxt.OvrlTrdCmplncSnctndListChkSts
{
key ekko.ebeln as PurchasingDocument,
@ObjectModel.foreignKey.association: '_PurchasingDocumentCategory'
ekko.bstyp as PurchasingDocumentCategory,
@ObjectModel.foreignKey.association: '_PurchasingDocumentType'
ekko.bsart as PurchasingDocumentType,
ekko.bsakz as PurchasingDocumentSubtype,
ekko.process_indicator as PurchasingDocumentProcessCode,
@ObjectModel.foreignKey.association: '_CompanyCode'
ekko.bukrs as CompanyCode,
ekko.loekz as PurchasingDocumentDeletionCode,
ekko.isaged as PurchasingDocumentIsAged,
ekko.pincr as ItemNumberInterval,
ekko.upinc as ItemNumberIntervalForSubItems,
@ObjectModel.foreignKey.association: '_PurchasingDocumentOrigin'
ekko.statu as PurchasingDocumentOrigin,
ekko.frgrl as ReleaseIsNotCompleted,
@ObjectModel.foreignKey.association: '_ReleaseCode'
ekko.frgke as ReleaseCode,
ekko.frgsx as PurchasingReleaseStrategy,
ekko.frgzu as PurgReleaseSequenceStatus,
ekko.lands as TaxReturnCountry,
@Semantics.systemDate.createdAt: true
ekko.aedat as CreationDate,
ekko.lastchangedatetime as LastChangeDateTime,
@Semantics.user.createdBy: true
ekko.ernam as CreatedByUser,
@ObjectModel.foreignKey.association: '_Supplier'
cast ( ekko.lifnr as md_supplier preserving type) as Supplier,
ekko.verkf as SupplierRespSalesPersonName,
cast (ekko.telf1 as telfnr0) as SupplierPhoneNumber,
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'ManualSupplierAddressID'
ekko.adrnr as SupplierAddressID, //obsolete
@ObjectModel.foreignKey.association: '_SupplierAddress_2'
ekko.adrnr as ManualSupplierAddressID,
ekko.ihrez as CorrespncExternalReference,
ekko.unsez as CorrespncInternalReference,
@ObjectModel.foreignKey.association: '_PurchasingOrganization'
ekko.ekorg as PurchasingOrganization,
@ObjectModel.foreignKey.association: '_PurchasingGroup'
ekko.ekgrp as PurchasingGroup,
//_CompanyCode.FiscalYearVariant as FiscalYearVariant,
@ObjectModel.foreignKey.association: '_DocumentCurrency'
ekko.waers as DocumentCurrency,
cast ( ekko.wkurs as fis_exchange_rate preserving type ) as ExchangeRate,
@Semantics.businessDate.at
ekko.bedat as PurchasingDocumentOrderDate,
@ObjectModel.foreignKey.association: '_SupplyingSupplier'
ekko.llief as SupplyingSupplier,
@ObjectModel.foreignKey.association: '_SupplyingPlant'
ekko.reswk as SupplyingPlant,
@ObjectModel.foreignKey.association: '_InvoicingParty'
ekko.lifre as InvoicingParty,
ekko.kunnr as Customer,
@ObjectModel.foreignKey.association: '_PurchaseContract'
ekko.konnr as PurchaseContract,
@Semantics.language: true
@ObjectModel.foreignKey.association: '_Language'
ekko.spras as Language,
ekko.absgr as PurgReasonForDocCancellation,
ekko.memory as PurchasingCompletenessStatus,
@ObjectModel.foreignKey.association: '_IncotermsClassification'
ekko.inco1 as IncotermsClassification,
ekko.inco2 as IncotermsTransferLocation,
@ObjectModel.foreignKey.association: '_PaymentTerms'
cast( zterm as farp_dzterm preserving type) as PaymentTerms,
cast (ekko.zbd1t as dzbd1t preserving type) as CashDiscount1Days,
cast (ekko.zbd2t as dzbd2t preserving type) as CashDiscount2Days,
cast (ekko.zbd3t as dzbd3t preserving type) as NetPaymentDays,
ekko.zbd1p as CashDiscount1Percent,
ekko.zbd2p as CashDiscount2Percent,
@ObjectModel.foreignKey.association: '_PricingProcedure'
ekko.kalsm as PricingProcedure,
@Semantics.amount.currencyCode: 'DocumentCurrency'
@DefaultAggregation:#NONE
ekko.ktwrt as TargetAmount,
ekko.distributiontype as PurgDocumentDistributionType,
ekko.singlecardinalitydistrtype as PurgSingleCardinalityDistrType,
ekko.knumv as PricingDocument,
ekko.kdatb as ValidityStartDate,
ekko.kdate as ValidityEndDate,
ekko.lphis as ScheduleAgreementHasReleaseDoc,
ekko.angdt as QuotationLatestSubmissionDate,
ekko.bnddt as BindingPeriodValidityEndDate,
ekko.ihran as QuotationSubmissionDate,
ekko.submi as PurchasingCollectiveNumber,
ekko.angnr as SupplierQuotationExternalID,
ekko.ausnr as RequestForQuotation,
ekko.kufix as ExchangeRateIsFixed,
@ObjectModel.foreignKey.association: '_IncotermsVersion'
ekko.incov as IncotermsVersion,
ekko.inco2_l as IncotermsLocation1,
ekko.inco3_l as IncotermsLocation2,
cast ( ekko.inco2_key as /scmtms/inc_loc_1_key_nc preserving type ) as IncotermsSupChnLoc1AddlUUID,
cast ( ekko.inco3_key as /scmtms/inc_loc_2_key_nc preserving type ) as IncotermsSupChnLoc2AddlUUID,
cast ( ekko.inco4_key as /scmtms/inc_dv_plce_dst_key_nc preserving type ) as IncotermsSupChnDvtgLocAddlUUID,
@ObjectModel.foreignKey.association: '_PurchasingProcessingStatus'
ekko.procstat as PurchasingProcessingStatus,
@Semantics.amount.currencyCode: 'DocumentCurrency'
ekko.rlwrt as PurgReleaseTimeTotalAmount,
ekko.dptyp as DownPaymentType,
ekko.dppct as DownPaymentPercentageOfTotAmt,
@Semantics.amount.currencyCode: 'DocumentCurrency'
ekko.dpamt as DownPaymentAmount,
ekko.dpdat as DownPaymentDueDate,
cast ( ekko.description as vdm_purgdoc_name preserving type ) as PurchasingDocumentName,
ekko.qtn_erlst_submsn_date as QuotationEarliestSubmsnDate,
ekko.bwbdt as LatestRegistrationDate,
ekko.followon_doc_cat as FollowOnDocumentCategory,
ekko.vsart as PurgDocDefaultShippingType,
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'PurgDocFollowOnDocumentType'
ekko.followon_doc_type as FollowOnDocumentType,
ekko.followon_doc_type as PurgDocFollowOnDocumentType,
ekko.stceg as VATRegistration,
ekko.stceg_l as VATRegistrationCountry,
ekko.intra_rel as IsIntrastatReportingRelevant,
ekko.intra_excl as IsIntrastatReportingExcluded,
@Semantics.booleanIndicator: true
ekko.iseopblocked as IsEndOfPurposeBlocked, //IsEopBlocked
ekko.active_id as ActivePurchasingDocument,
ekko.cr_stat as PurgDocChangeRequestStatus,
ekko.revno as PurchasingDocumentVersion,
ekko.externalreferenceid as PurgDocExternalReference,
// Product Compliance Status
ekko.total_status_dg as PurgProdCmplncTotDngrsGoodsSts,
ekko.total_status_pcs as PurgAggrgdProdCmplncSuplrSts,
ekko.total_status_pma as PurgAggrgdProdMarketabilitySts,
ekko.total_status_sds as PurgAggrgdSftyDataSheetStatus,
// Trade Compliance Status
@ObjectModel.foreignKey.association: '_OverallTrdCmplncEmbargoSts'
ekko.total_status_emcst as OverallTrdCmplncEmbargoSts,
@ObjectModel.foreignKey.association: '_OvrlTrdCmplncSnctndListChkSts'
ekko.total_status_slcst as OvrlTrdCmplncSnctndListChkSts,
@ObjectModel.foreignKey.association: '_OvrlTrdCmplncLegalCtrlChkSts'
ekko.total_status_lccst as OvrlTrdCmplncLegalCtrlChkSts,
ekko.parent_id as PurchasingParentDocument,
ekko.grouping_id as ProcmtHubCompanyCodeGroupingID,
ekko.has_catalog_relevant_items as PurgHasCatalogRelevantItems,
//Indicator Goods Receipt Message
cast(ekko.weakt as BT_MsgOnGdsRcptIsReqd preserving type) as MsgOnGoodsReceiptIsRequested,
ekko.contr_cnsmpn_check_is_rqd as ContrCnsmpnCheckOnChangeIsRqd,
_CompanyCode,
_PurchasingDocumentType,
_PurchasingDocumentCategory,
_Supplier,
_SupplyingSupplier,
_InvoicingParty,
_PaymentTerms,
_PurchasingOrganization,
_PurchasingGroup,
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: '_SupplierAddress_2'
_SupplierAddress,
_SupplierAddress_2,
_DocumentCurrency,
_CreatedByUser,
_IncotermsClassification,
_IncotermsVersion,
_SupplyingPlant,
_PurchasingDocumentOrigin,
_ReleaseCode,
_PurchaseContract,
_Language,
_PricingProcedure,
_PurchasingDocumentItem,
_PurchasingDocumentPartner,
_PurchasingProcessingStatus,
_OvrlTrdCmplncLegalCtrlChkSts,
_OverallTrdCmplncEmbargoSts,
_OvrlTrdCmplncSnctndListChkSts,
// Text associations for CustomUI
_IncotermsClassificationText,
_IncotermsVersionText,
_DocumentCurrencyText,
_TaxReturnCountryText,
_VATRegistrationCountryText,
_PurgTotProdCmplncSuplrStsT,
_PurgTotProdMarketabilityStsT,
_PurgAggrgdSftyDataSheetStsT,
_PurgTotDangerousGoodsStsT,
_OvTrdComplLegalCtrlChkStsTxt,
_OvrlTradeCmplncEmbargoStsTxt,
_OvTrdComplSanctListChkStsTxt
}