R_PROJDMNDEXPENSEDISTRIBUTION

CDS View

Distribution of Proj Demand for Expense

R_PROJDMNDEXPENSEDISTRIBUTION is a CDS View in S/4HANA. Distribution of Proj Demand for Expense. 3 CDS views read from this table.

Used by 3 CDS view(s)

CDS Views using this table (3)

ViewTypeJoinVDMDescription
I_ProjDmndExpenseDistribution view_entity from BASIC Distribution of Proj Demand for Expense
P_ProjDmndExpenseDistrAggrgn view_entity right_outer COMPOSITE SDM: Private CDS View
R_ProjDmndExpenseDistrTP view_entity from TRANSACTIONAL Distribution of Demand for Expense - TP 
@Analytics.technicalName: 'RPrjDmndExpnDistr'
@AccessControl.authorizationCheck: #MANDATORY

@VDM: { viewType                 : #BASIC,
        lifecycle.contract.type  : #SAP_INTERNAL_API}

@ObjectModel: {
    modelingPattern: #ANALYTICAL_DIMENSION,
    supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ],
    representativeKey       : 'ProjDmndExpnDistributionUUID',
    usageType.dataClass     : #TRANSACTIONAL,
    usageType.serviceQuality: #A,
    usageType.sizeCategory  : #M
}

@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Distribution of Proj Demand for Expense'

define view entity R_ProjDmndExpenseDistribution
  as select from dmndexpensedistr

  association [1] to R_ProjectDemand        as _Root              on $projection.ProjectDemandUUID = _Root.ProjectDemandUUID
  association [1] to R_ProjectDemandExpense as _Expense           on $projection.ProjectDemandExpenseUUID = _Expense.ProjectDemandExpenseUUID

  association [1] to I_EnterpriseProject    as _EnterpriseProject on $projection.ProjectUUID = _EnterpriseProject.ProjectUUID  
{
  key projdmndexpndistributionuuid   as ProjDmndExpnDistributionUUID,
      projectdemandexpenseuuid       as ProjectDemandExpenseUUID,
      projectdemanduuid              as ProjectDemandUUID,
      projdmndreferencedplandatauuid as ProjDmndReferencedPlanDataUUID,
      projdmndexpndistrperiodval     as ProjDmndExpnDistrPeriodVal,
      projdmndexpndistryearval       as ProjDmndExpnDistrYearVal,
      @Semantics.amount.currencyCode: 'ProjDmndExpnDistrAmountCrcy'
      projdmndexpndistramount        as ProjDmndExpnDistrAmount,
      @Semantics.amount.currencyCode: 'ProjDmndExpnDistrRevnAmtCrcy'
      projdmndexpndistrrevenueamt    as ProjDmndExpnDistrRevenueAmt,
      @ObjectModel.foreignKey.association: '_EnterpriseProject'
      
      //Casting to a type which annotates Change Document Relevance as false. This field is already written into Change Document in root node .

      //cast(projectuuid as tv_proj_dmnd_uuid_chg_doc preserving type ) as ProjectUUID, "commented out, please see message 2380013083

      cast(projectuuid as tv_project_uuid_chg_doc preserving type ) as ProjectUUID,
      
      //Casting to a type which annotates Change Document Relevance as false. This field is already written into Change Document in root node .

      //cast(referencedobjectuuid as tv_proj_dmnd_uuid_chg_doc preserving type ) as ReferencedObjectUUID, "commented out, please see message 2380013083

      cast(referencedobjectuuid as tv_dmnd_ref_obj_uuid_chg_doc preserving type ) as ReferencedObjectUUID,
      
      projdmndexpndistramountcrcy    as ProjDmndExpnDistrAmountCrcy,
      projdmndexpndistrrevnamtcrcy   as ProjDmndExpnDistrRevnAmtCrcy,
      @Semantics.user.createdBy: true
      createdbyuser                  as CreatedByUser,
      @Semantics.systemDateTime.createdAt: true
      creationdatetime               as CreationDateTime,
      @Semantics.user.lastChangedBy: true
      lastchangedbyuser              as LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      lastchangedatetime             as LastChangeDateTime,

      _Root,
      _Expense,

      _EnterpriseProject

}

Learn More