R_PRODSUBSTNCTRLTP

CDS View

Product Substitution Control TP

R_PRODSUBSTNCTRLTP is a CDS View in S/4HANA. Product Substitution Control TP. 3 CDS views read from this table.

Used by 3 CDS view(s)

CDS Views using this table (3)

ViewTypeJoinVDMDescription
A_ProdSubstnCtrl view_entity projection CONSUMPTION Product Substitution Control
A_ProdSubstnCtrl_2 view_entity projection CONSUMPTION Product Substitution Control
C_ProdSubstnCtrlTP view_entity projection CONSUMPTION Product Substitution Control 
//@AbapCatalog: {

//  compiler.compareFilter: true,

//  preserveKey: true,

//  sqlViewName: 'RPRODSUBCTRLTP'

//}

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking:#NOT_REQUIRED,
  privilegedAssociations: [
    '_CreatedByUser',
    '_LastChangedByUser'
  ]
}
//@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'Product Substitution Control TP'
@ObjectModel: {
  representativeKey: 'MDSubstnControl',
  usageType: {
    dataClass: #MASTER,
    serviceQuality: #C,
    sizeCategory: #S
  }
}
@ObjectModel.sapObjectNodeType.name: 'ProductSubstitutionControl'
@VDM: {
  lifecycle: {
    contract.type: #SAP_INTERNAL_API
  },
  viewType: #TRANSACTIONAL
}
define root view entity R_ProdSubstnCtrlTP
  as select from R_MDSubstnCtrlTP
  association [0..1] to I_UserContactCard           as _CreatedByUser      on  $projection.CreatedByUser = _CreatedByUser.ContactCardID
  association [0..1] to I_UserContactCard           as _LastChangedByUser  on  $projection.LastChangedByUser = _LastChangedByUser.ContactCardID
  association [0..1] to P_MDSubstnCtrlByAssgdGrp    as _GroupsCount        on  $projection.MDSubstnObjectType = _GroupsCount.MDSubstnObjectType
                                                                           and $projection.MDSubstnControl    = _GroupsCount.MDSubstnControl

  association [0..1] to P_SubstnCtrlAssgmtByAccUUID as _RelatedAccessCount on  $projection.MDSubstnObjectType = _RelatedAccessCount.MDSubstnObjectType
                                                                           and $projection.MDSubstnControl    = _RelatedAccessCount.MDSubstnControl
  composition [0..*] of R_ProdSubstnCtrlTextTP      as _Text
  composition [0..*] of R_ProdSubstnCtrlGrpTP       as _ControlGroup
{
  key MDSubstnObjectType,
  key MDSubstnControl,
      MDSubstnHasDefaultGroup,
      CreatedByUser,
      CreationDateTime,
      LastChangedByUser,
      LastChangeDateTime,

      _GroupsCount.MDSubstnNmbrOfAssignedGroups        as MDSubstnNmbrOfAssignedGroups,
      _RelatedAccessCount.MDSubstnNmbrOfAssignedAccess as MDSubstnNmbrOfAssignedAccess,

      /* Associations */
      _MDObjectType,
      _CreatedByUser,
      _LastChangedByUser,
      _Text,
      _ControlGroup,
      _UnassgdGrp
}
where
  MDSubstnObjectType = 'Product'

Learn More