R_PROCUREMENTPROJECTTP

CDS View

Procurement Project - TP

R_PROCUREMENTPROJECTTP is a CDS View in S/4HANA. Procurement Project - TP. 4 CDS views read from this table.

Used by 4 CDS view(s)

CDS Views using this table (4)

ViewTypeJoinVDMDescription
A_ProcurementProject view_entity projection CONSUMPTION Procurement Project
C_ProcurementProjectTP view_entity projection CONSUMPTION Procurement Project - TP
ESH_N_PROCUREMENTPROJECT view from Anchor view -PROCUREMENTPROJECT
I_ProcurementProjectTP view_entity projection TRANSACTIONAL Procurement Project - TP 
@AccessControl: {
  authorizationCheck: #MANDATORY,
  privilegedAssociations: [ '_CreatedByUser', '_ChangedByUser']
}

@ObjectModel:{representativeKey: 'ProcurementProjectUUID',
              semanticKey: ['ProcurementProject'],
              usageType: {
                dataClass: #TRANSACTIONAL,
                serviceQuality: #B,
                sizeCategory: #L
              },
              sapObjectNodeType.name: 'ProcurementProject' }
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@EndUserText.label: 'Procurement Project - TP'
@AbapCatalog.extensibility: {
  extensible: true,
  dataSources: ['_Extension'],
  allowNewDatasources: false,
  elementSuffix: 'PPJ',
  quota: { maximumFields: 404,
           maximumBytes: 40400 },
  allowNewCompositions: true }

define root view entity R_ProcurementProjectTP
  as select from R_ProcurementProject as ProcurementProject

  composition [*] of R_ProcurementProjectPlantTP     as _ProcurementProjectPlant

  //Extension

  association [1..1] to E_ProcurementProject         as _Extension                  on $projection.ProcurementProjectUUID = _Extension.ProcurementProjectUUID
  association [0..*] to I_SrcgProjSourcingOriginText as _SrcgProjSourcingOriginText on $projection.SourcingOrigin = _SrcgProjSourcingOriginText.SourcingOrigin
  association [0..*] to I_SrcgProjSourcingScenarioText as _SrcgProjSourcingScenarioText on $projection.SourcingScenario = _SrcgProjSourcingScenarioText.SourcingScenario
{

  key ProcurementProjectUUID,

      ProcurementProject,

      ProcurementProjectName,

      ExternalProjectReference,

      CompanyCode,

      LastChangedByUser,

      CreatedByUser,

      LastChangeDateTime,

      CreationDateTime,

      ProcurementProjectActvtnSts,

      SourcingOrigin,
      SourcingScenario,

      ProcmtPlanningSubprojectUUID,

      IsEndOfPurposeBlocked,
      cast( '' as vdm_companycodeisnotauthorized preserving type ) as CompanyCodeIsNotAuthorized,
      
      @ObjectModel.editableFieldFor: 'CompanyCode'
      CompanyCode                       as CompanyCodeForEdit,

      //composition

      _ProcurementProjectPlant,
      //text

      _CompanyCode,
      _ProcurementProjActvtnStsTxt,
      //contact card

      _CreatedByUser,
      _ChangedByUser,
      _SrcgProjSourcingOriginText,
      _SrcgProjSourcingScenarioText

}

Learn More