R_ORGLCHANGEPRODUCTTP

CDS View

Organizational Change Products

R_ORGLCHANGEPRODUCTTP is a CDS View in S/4HANA. Organizational Change Products. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
C_OrglChangeProductTP view_entity projection CONSUMPTION Organizational Change Products
I_OrglChangeProductTP view_entity projection TRANSACTIONAL Organizational Change Products - TP 
@AccessControl.authorizationCheck:       #CHECK
@AccessControl.personalData.blocking:    #BLOCKED_DATA_EXCLUDED

@VDM.viewType:                           #TRANSACTIONAL
@VDM.lifecycle.contract.type:            #SAP_INTERNAL_API

@ObjectModel.usageType.sizeCategory:     #XL
@ObjectModel.usageType.serviceQuality:   #C
@ObjectModel.usageType.dataClass:        #MIXED
@ObjectModel.semanticKey:                ['OrganizationalChange', 'Product']
@ObjectModel.representativeKey:          'Product'


@EndUserText.label:                     'Organizational Change Products'

@Metadata.ignorePropagatedAnnotations:   true



define view entity R_OrglChangeProductTP
  as select from I_OrganizationalChangeProduct

  association        to parent R_OrganizationalChangeTP as _OrganizationalChange on $projection.OrganizationalChange = _OrganizationalChange.OrganizationalChange
  association [0..1] to I_Plant                         as _PlantForEdit         on $projection.PlantForEdit = _PlantForEdit.Plant
  association [0..1] to I_Product                       as _ProductForEdit       on $projection.ProductForEdit = _ProductForEdit.Product
{

        @ObjectModel.foreignKey.association: '_OrganizationalChange'
  key   OrganizationalChange,
        @ObjectModel.foreignKey.association: '_Product'
  key   Product,
        @ObjectModel.foreignKey.association: '_Plant'
  key   Plant,
        @ObjectModel.editableFieldFor: 'Product'
        Product as ProductForEdit,
        @ObjectModel.editableFieldFor: 'Plant'
        Plant   as PlantForEdit,
        ControllingArea,


        ProfitCenter,


        ProfitCenterByOrglChange,

        @Semantics.systemDateTime.localInstanceLastChangedAt: true
        LastChangeDateTime,

        @Semantics.user.lastChangedBy: true
        LastChangedByUser,

        _OrganizationalChange,
        _Plant,
        _Product,
        _PlantForEdit,
        _ProductForEdit,
        _ProfitCtr,
        _ProfitCtrNew,
        _ProfitCenterBfrOrglChangeText,
        _ProfitCenterByOrglChangeText



}

Learn More