R_MAINTENANCEITEMREASONTEXTTP

CDS View

Maintenance Item Reason Long Text

R_MAINTENANCEITEMREASONTEXTTP is a CDS View in S/4HANA. Maintenance Item Reason Long Text. 4 CDS views read from this table.

Used by 4 CDS view(s)

CDS Views using this table (4)

ViewTypeJoinVDMDescription
A_MaintenanceItemReasonText view_entity projection CONSUMPTION Maintenance Item Reason Long Text
C_MaintenanceItemReasonTextTP view_entity projection CONSUMPTION Maintenance Item Reason Long Text
C_MaintItemReasonTextTP_2 view_entity projection CONSUMPTION Maintenance Item Reason Long Text
I_MaintenanceItemReasonTextTP view_entity projection TRANSACTIONAL Maintenance Item Reason Long Text - TP 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Maintenance Item Reason Long Text'
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #TRANSACTIONAL
@VDM.usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #L

define view entity R_MaintenanceItemReasonTextTP
  as select from            I_MaintenanceItemReasonText as _MaintenanceItemReasonText
    left outer to many join I_TextObject                as _TextObject on  _TextObject.TextObjectType     = 'LTXT'
                                                                       and _TextObject.TextObjectCategory = 'MPCR'
                                                                       and _TextObject.TextObjectKey      = _MaintenanceItemReasonText.TextObjectKey
  association [0..1] to I_TextObjectPlainLongText        as _LongText              on  _LongText.TextObjectCategory = 'MPCR'
                                                                                   and _LongText.TextObjectType     = 'LTXT'
                                                                                   and _LongText.TextObjectKey      = $projection.TextObjectKey
                                                                                   and _LongText.Language           = $projection.Language
  association [1..1] to R_MaintenanceItemTP              as _MaintenanceItem       on  $projection.MaintenanceItem = _MaintenanceItem.MaintenanceItem
  association        to parent R_MaintenanceItemReasonTP as _MaintenanceItemReason on  $projection.MaintenanceItem            = _MaintenanceItemReason.MaintenanceItem
                                                                                   and $projection.NmbrOfMaintComplianceItems = _MaintenanceItemReason.NmbrOfMaintComplianceItems
{
  key  _MaintenanceItemReasonText.MaintenanceItem,
  key  _MaintenanceItemReasonText.NmbrOfMaintComplianceItems,
  key  _TextObject.Language,

       _MaintenanceItemReasonText.TextObjectKey,
       _MaintenanceItemReasonText.TextObjectCategory,
       _MaintenanceItemReasonText.TextObjectType,
       _LongText.PlainLongText,

       -- Associations --
       _MaintenanceItemReasonText._LongText,
       _MaintenanceItem,
       _MaintenanceItemReason
}
where _MaintenanceItemReason.MaintenanceComplianceTypeCode = 'R'

Learn More