R_MAINTENANCEITEMCAUSETEXTTP

CDS View

Maintenance Item Cause Long Text

R_MAINTENANCEITEMCAUSETEXTTP is a CDS View in S/4HANA. Maintenance Item Cause Long Text. 4 CDS views read from this table.

Used by 4 CDS view(s)

CDS Views using this table (4)

ViewTypeJoinVDMDescription
A_MaintenanceItemCauseText view_entity projection CONSUMPTION Maintenance Item Cause Long Text
C_MaintenanceItemCauseTextTP view_entity projection CONSUMPTION Maintenance Item Cause Long Text
C_MaintenanceItemCauseTextTP_2 view_entity projection CONSUMPTION Maintenance Item Cause Long Text
I_MaintenanceItemCauseTextTP view_entity projection TRANSACTIONAL Maintenance Item Cause Long Text - TP 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Maintenance Item Cause Long Text'
@VDM.viewType: #TRANSACTIONAL
@VDM.usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #L

define view entity R_MaintenanceItemCauseTextTP
  as select from            I_MaintenanceItemCauseText as _MaintenanceItemCauseText
    left outer to many join I_TextObject               as _TextObject on  _TextObject.TextObjectType     = 'LTXT'
                                                                      and _TextObject.TextObjectCategory = 'MPCR'
                                                                      and _TextObject.TextObjectKey      = _MaintenanceItemCauseText.TextObjectKey

  association [0..1] to I_TextObjectPlainLongText       as _LongText             on  _LongText.TextObjectCategory = 'MPCR'
                                                                                 and _LongText.TextObjectType     = 'LTXT'
                                                                                 and _LongText.TextObjectKey      = $projection.TextObjectKey
                                                                                 and _LongText.Language           = $projection.Language
  association [1..1] to R_MaintenanceItemTP             as _MaintenanceItem      on  $projection.MaintenanceItem = _MaintenanceItem.MaintenanceItem
  association        to parent R_MaintenanceItemCauseTP as _MaintenanceItemCause on  $projection.MaintenanceItem            = _MaintenanceItemCause.MaintenanceItem
                                                                                 and $projection.NmbrOfMaintComplianceItems = _MaintenanceItemCause.NmbrOfMaintComplianceItems

{

  key  _MaintenanceItemCauseText.MaintenanceItem,
  key  _MaintenanceItemCauseText.NmbrOfMaintComplianceItems,
  key  _TextObject.Language,
       _MaintenanceItemCauseText.TextObjectKey,
       _MaintenanceItemCauseText.TextObjectCategory,
       _MaintenanceItemCauseText.TextObjectType,
       _LongText.PlainLongText,

       /* Associations */
       _MaintenanceItemCauseText._LongText,

       /* Local Association */
       _MaintenanceItem,
       _MaintenanceItemCause
}
where _MaintenanceItemCause.MaintenanceComplianceTypeCode = 'C'

Learn More