R_MAINTNOTIFCODINGCODETP

CDS View

Code for Coding

R_MAINTNOTIFCODINGCODETP is a CDS View in S/4HANA. Code for Coding. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_MaintNotifCodingCode view_entity projection COMPOSITE Catalog Code 
//@AbapCatalog.sqlViewName: 'RNOTIFCDNGCOTP'

//@AbapCatalog.compiler.compareFilter: true

//@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK
//@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MASTER}
@EndUserText.label: 'Code for Coding'
define view entity R_MaintNotifCodingCodeTP as select from I_InspectionCode  
   association to parent  R_MaintNotifCodingCodeGrpTP as _MaintNotifCodeGrp
   on $projection.MaintNotifCodingCatalog       = _MaintNotifCodeGrp.MaintNotifCodingCatalog
   and $projection.MaintNotifCodingCodeGroup    = _MaintNotifCodeGrp.MaintNotifCodingCodeGroup
  
   association [1..*] to I_InspectionCodeText   as _Text
   on  $projection.MaintNotifCodingCatalog      = _Text.InspectionCatalog
   and $projection.MaintNotifCodingCodeGroup   = _Text.InspectionCodeGroup
   and $projection.MaintNotifCodingCode  = _Text.InspectionCatalog 
   
   association [1..1] to I_InspectionCodeGroup  as _MaintNotifGrp
   on  $projection.MaintNotifCodingCatalog      = _MaintNotifGrp.InspectionCatalog
   and $projection.MaintNotifCodingCodeGroup   = _MaintNotifGrp.InspectionCodeGroup
   
  {

   key I_InspectionCode.InspectionCatalog                  as MaintNotifCodingCatalog,
   key I_InspectionCode.InspectionCodeGroup                as MaintNotifCodingCodeGroup,
//@ObjectModel.text.element:['InspectionCodeText']

   key I_InspectionCode.InspectionCode                     as MaintNotifCodingCode,
    @UI.hidden: true
   _MaintNotifCodeGrp.MaintNotifCodeGrpStatus              as MaintNotifCodeGrpStatus,
   _MaintNotifCodeGrp.MaintNotifCodeGrpStatusText          as MaintNotifCodeGrpStatusText,

   I_InspectionCode._Text[1:Language=$session.system_language].InspectionCodeText as MaintNotifCodingCtlgCodeText,     
   _MaintNotifGrp._Text[1:Language=$session.system_language].InspSpecAddlCodeGroupText as MaintNotifCodingCodeGrpText, 
   _MaintNotifGrp._InspectionCatalog._InspectionCatalogText[1:Language=$session.system_language].InspSpecAdditionalCatalogText as MaintNotifCodingCatalogText,
  

   /* Associations */
   //Associations

  _Text
  ,_MaintNotifCodeGrp
  ,_MaintNotifGrp
 
} where InspectionCatalog = 'D'

Learn More