R_MAINTMBLAPPLPUSHRECIPIENTTP

CDS View

Mobile Application Push Recipient - TP

R_MAINTMBLAPPLPUSHRECIPIENTTP is a CDS View in S/4HANA. Mobile Application Push Recipient - TP. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_MaintMblApplPushRecipientTP view_entity projection CONSUMPTION Mobile Application Push Recipient 
@AccessControl: {
  authorizationCheck: #MANDATORY,
  privilegedAssociations: [ '_PushMessage' ]
}

@EndUserText.label: 'Mobile Application Push Recipient - TP'

@ObjectModel: {
  sapObjectNodeType.name: 'MaintMblApplPushRecipient',
  usageType: {
    dataClass: #TRANSACTIONAL,
    serviceQuality: #A,
    sizeCategory: #S
  }
}

@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}

define view entity R_MaintMblApplPushRecipientTP
  as select from I_MblApplPushRecipients

  association        to parent R_MaintMblApplPushNotifTP as _PushNotification on _PushNotification.MobileApplicationPushInternal = $projection.MobileApplicationPushInternal
  association [0..*] to I_MblUsrApplPushStatusText       as _PushStatusText   on _PushStatusText.MobileUserApplicationPushSts = $projection.MobileUserApplicationPushSts
  association [1..1] to I_MobileDataUnitMessageQueue     as _PushMessage      on _PushMessage.MblApplMessageInternal = $projection.MblApplMessageInternal
{
  key MblApplPushItemInternal,
  key MobileApplicationPushInternal,

      MobileUserRecordInternal,
      MblApplMessageInternal,
      MobileUserInternal,
      MobileApplicationPushRecipient,
      MobileUserApplication,
      MblUsrApplPushEmlNotifIsEnbld,
      MobileUserApplicationPushSts,
      //Status icon and Semantic colors

      case MobileUserApplicationPushSts
          when 'NEW' then 0
          when 'ENQUEUE' then 2
          when 'PROCESS' then 0
          when 'SRV_COMP' then 3
          when 'COMPLETED' then 3
          when 'CANCEL' then 1
         else 0
      end as MblApplPushStatusCriticality,
      MobileUserApplPushExprtnDteTme,
      MblUsrApplPushCancelDteTme,
      MblApplPushServerConfDteTme,
      MblApplPushClientConfDteTme,
      MblApplClntErrDteTme,
      MobileUserApplPushCreatedBy,
      MblUsrApplPushCreatedDteTme,
      MobileUserApplPushChangedBy,
      MblUsrApplPushChangedDteTme,
      _PushMessage.MblApplOutbTrggrProcDteTme,

      /* Associations */
      _PushNotification,
      _PushStatusText,
      _PushMessage
}

Learn More