R_INSURANCEPOLICYTP_2

@EndUserText.label: 'Policy'
@VDM: {
  viewType:#TRANSACTIONAL,
  lifecycle.contract.type:#SAP_INTERNAL_API
}
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')

@ObjectModel: {
   semanticKey: [ 'InsurancePolicy' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   }
}
@ObjectModel.sapObjectNodeType.name: 'InsurancePolicy'
define root view entity R_InsurancePolicyTP_2
  as select from I_InsurPlcyBasic as Policy
  
  association [0..*] to R_InsurPlcyContractTP          as _Contract                 on  $projection.InsurPlcyUUID = _Contract.InsurPlcyUUID
  association [0..*] to R_InsurPlcyContrBndlTP         as _ContractBundle           on  $projection.InsurPlcyUUID = _ContractBundle.InsurPlcyUUID
  association [1..*] to R_InsurPlcyPolicyHolderTP_2    as _PolicyHolder             on  $projection.InsurPlcyUUID = _PolicyHolder.InsurPlcyUUID
  association [0..*] to R_InsurPlcyReltdContractTP     as _RelatedContract          on  $projection.InsurPlcyUUID = _RelatedContract.InsurPlcyUUID
  association [0..*] to R_InsurPlcyExternalReferenceTP as _ExternalReference        on  $projection.InsurPlcyUUID = _ExternalReference.InsurPlcyUUID
  association [0..*] to R_InsurPlcyAgentTP             as _Agent                    on  $projection.InsurPlcyUUID = _Agent.InsurPlcyUUID
  association [0..*] to R_InsurPlcyClauseTP_2          as _Clause                   on  $projection.InsurPlcyUUID = _Clause.InsurPlcyUUID
  association [0..*] to R_InsurPlcyCommissionTP        as _Commission               on  $projection.InsurPlcyUUID = _Commission.InsurPlcyUUID
  association [0..*] to R_InsurPlcyDistrPlnRelshpTP    as _DistributionPlan         on  $projection.InsurPlcyUUID = _DistributionPlan.InsurPlcyUUID
  association [1..*] to R_InsurPlcyContrJrnlHdrTP      as _ContractJournalHeader    on  $projection.InsurPlcyUUID = _ContractJournalHeader.InsurPlcyUUID
  association [0..*] to R_InsurPlcyApplJrnlHdrTP       as _ApplicationJournalHeader on  $projection.InsurPlcyUUID = _ApplicationJournalHeader.InsurPlcyUUID
  association [0..*] to R_InsurPlcyCashFlowHdrTP       as _CashFlowDocumentHeader   on  $projection.InsurPlcyUUID = _CashFlowDocumentHeader.InsurPlcyUUID

  association [1..1] to E_InsurancePolicy              as _Extension                on  $projection.InsurPlcyUUID        = _Extension.InsurPlcyUUID
                                                                                    and $projection.InsurPlcyJrnlEndNmbr = _Extension.InsurPlcyJrnlEndNmbr
                                                                                    and $projection.InsurPlcyJrnlNmbr    = _Extension.InsurPlcyJrnlNmbr

{
  key InsurPlcyUUID,
      InsurPlcyJrnlNmbr,
      InsurPlcyJrnlEndNmbr,
      InsurancePolicy,
      /*this is used in the Acces control role so should not be commented...comment in A view*/
      InsurPlcyAuthznSlsProductGroup,
      InsurPlcyStartDateTime,
      InsurApplLifeCycSts,
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPolicyDistributionChannel'
      InsurPlcyDistrChnl,
      InsrrIDByInsrr,
      InsurPlcySalesProductTemplate,
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPolicyAcquisitionType'
      InsurPlcyAcqnType,
      InsurPlcyBusinessObject,
      PrdcssrInsurancePolicy,
      LastChangeDateTime,
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyNoActiveContract'
      InsurPolicyCancellationStatus,
      InsurancePlcyPolicyIsCancelled,
      InsurancePolicyNumberOld,
      InsurPlcyExchRateType,
      InsurPlcyCrcy,
      InsurancePolicyNoteIdentifier,
      LongText,
      TextObjectCategory,
      TextObjectKey,
      Language,
      InsurPlcyExtApplNmbr,
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyCommsnPostingCode'
      InsurPlcyCommissionPostingCode,
      InsurancePolicyDuplicateID,
      InsurancePolicyGenerationDate,
      //@ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyGenerationDetDateSource'

      InsurPlcySrceOfGnrtnDteCode,
      InsurancePolicyKey,
      InsurPlcySrceDocStsDateTime,
      InsurPlcyChangeOptionNumber,
      InsurPlcyChgOptnApplID,
      InsurPlcyChangeOptionText,
      InsurancePolicyIsChangeOption,
      InsurPlcyHasPndgCommsnCase,
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyChangeOptionCategory'
      InsurPlcyChangeOptionCategory,
      InsurMstrPlcyJrnlNmbr,
      InsurMstrPlcySmplApplID,
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyChangeOptionReason'
      InsurPlcyChgOptnRsn,
      InsuranceMasterPolicyNumber,
      InsurPlcyIsCoinsurPrtcpnt,
      InsurPlcyGnrtnDetnDte,
      InsurPlcyHasPolicyProcessing,
      //      @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyShiftMode'

      InsurancePolicyShiftType,
      InsurancePolicySubjectCode,
      InsurancePolicyHasReassessment,
      InsurPlcyReassessmentNoteID,
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPlcyPremWaiverAnnulment'
      InsurPlcyPremWvrAnnulmentRsn,
      InsurPlcyContractualDpndcySts,
      cast ( ' ' as boolean preserving type ) as InsurPlcyIsReleasePolicy,
      cast ( ' ' as boolean preserving type ) as InsurPlcyIsSavePolicy,
      cast ( ' ' as boolean preserving type ) as InsurPlcyIsCalctPolicy,
      cast ( ' ' as boolean preserving type ) as InsurPlcyIsSmltePolicy,


      /*Associations*/
      _Contract,
      _ContractBundle,
      _PolicyHolder,
      _RelatedContract,
      _ExternalReference,
      _Agent,
      _Clause,
      _Commission,
      _DistributionPlan,
      _ContractJournalHeader,
      _ApplicationJournalHeader,
      _CashFlowDocumentHeader


}