R_INSURANCEPOLICYTP

CDS View

Insurance Policy - TP

R_INSURANCEPOLICYTP is a CDS View in S/4HANA. Insurance Policy - TP. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_InsurancePolicy view_entity projection CONSUMPTION Insurance Policy 
@EndUserText.label: 'Insurance Policy - TP'
@VDM: {
  viewType:#TRANSACTIONAL,
  lifecycle.contract.type:#SAP_INTERNAL_API
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations: [  '_InsuranceContract',
                             '_InsurancePolicyholder']
}
@ObjectModel: {
   representativeKey: 'InsurPlcyUUID',
   semanticKey: [ 'InsurancePolicy' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   }
}

define root view entity R_InsurancePolicyTP
  as select from I_InsurancePolicy as InsurancePolicy

  composition [1..*] of R_InsuranceContractTP          as _InsuranceContract
  composition [1..*] of R_InsurPolicyPolicyHolderTP    as _InsurancePolicyholder
  composition [1..*] of R_InsurPlcyContrJrnlTP         as _InsurPlcyContrJrnl
  composition [0..*] of R_InsurPlcyPlannedProcessingTP as _InsurPlcyPlndProcg
  
  association [1..*] to I_InsurPlcyCashFlowHeader      as _InsurPlcyCashFlowHeader  on  $projection.InsurancePolicy = _InsurPlcyCashFlowHeader.InsurancePolicy

  association [1..1] to E_InsurancePolicy              as _Extension on  $projection.InsurPlcyUUID        = _Extension.InsurPlcyUUID
                                                                     and $projection.InsurPlcyJrnlNmbr    = _Extension.InsurPlcyJrnlNmbr
                                                                     and $projection.InsurPlcyJrnlEndNmbr = _Extension.InsurPlcyJrnlEndNmbr

{

  key InsurPlcyUUID,
      InsurancePolicy,
      InsurPlcyJrnlNmbr,
      InsurPlcyJrnlEndNmbr,
      InsurPlcyAuthznSlsProductGroup,
      InsurPlcyStartDateTime,
      @ObjectModel.sapObjectNodeTypeReference: 'InsurApplLifeCycleStatus'
      InsurApplLifeCycSts,
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPolicyDistributionChannel'
      InsurPlcyDistrChnl,
      @ObjectModel.sapObjectNodeTypeReference: 'Insurer'
      InsrrIDByInsrr,
      @ObjectModel.sapObjectNodeTypeReference: 'InsurancePolicyTemplate'
      InsurPlcySalesProductTemplate as InsurancePolicyPolicyControl,
      @ObjectModel.sapObjectNodeTypeReference: 'InsurPolicyAcquisitionType'
      InsurPlcyAcqnType,
      PrdcssrInsurancePolicy,
      InsurPolicyCancellationStatus,
      LastChangeDateTime,

      /* Associations */
      _InsuranceContract,
      _InsurancePolicyholder,
      _InsurPlcyContrJrnl,
      _InsurPlcyPlndProcg,
      _InsurPlcyCashFlowHeader

}

Learn More