R_INSURANCEPOLICYCOVERAGETP
Cvrg of Cvrg Package in Plcy - TP
R_INSURANCEPOLICYCOVERAGETP is a CDS View in S/4HANA. Cvrg of Cvrg Package in Plcy - TP. 1 CDS views read from this table.
CDS Views using this table (1)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| A_InsurancePolicyCoverage | view_entity | projection | CONSUMPTION | Coverage of Coverage Package |
@EndUserText.label: 'Cvrg of Cvrg Package in Plcy - TP'
@VDM: {
viewType:#TRANSACTIONAL,
lifecycle.contract.type:#SAP_INTERNAL_API
}
@AccessControl: {
authorizationCheck: #PRIVILEGED_ONLY,
personalData.blocking: #('TRANSACTIONAL_DATA'),
privilegedAssociations: [ '_InsurPlcyCvrgSurchrgDiscount',
'_InsurancePolicyCvrgLimit',
'_InsurancePolicyCvrgClause',
'_InsurPolicyCvrgDeductible',
'_InsurancePolicyInsuredObject',
'_InsurPlcySubCoverage',
'_InsurCvrgPlndProcessing']
}
@ObjectModel: {
representativeKey: 'InsurPlcyCoverageID',
semanticKey: [ 'InsurPlcyInsuranceCoverage' ],
usageType: {
dataClass: #TRANSACTIONAL,
serviceQuality: #C,
sizeCategory: #XL
}
}
define view entity R_InsurancePolicyCoverageTP
as select from I_InsurancePolicyCoverage
association to parent R_InsurPlcyCoveragePackageTP as _InsurPlcyCoveragePackage on $projection.InsurPlcyUUID = _InsurPlcyCoveragePackage.InsurPlcyUUID
and $projection.InsurPlcyInsurContr = _InsurPlcyCoveragePackage.InsurPlcyInsurContr
and $projection.InsurPlcyCoveragePackageID = _InsurPlcyCoveragePackage.InsurPlcyCoveragePackageID
composition [0..*] of R_InsurPlcyCvrgSurchrgDiscTP as _InsurPlcyCvrgSurchrgDiscount
composition [0..*] of R_InsurancePolicyCvrgLimitTP as _InsurancePolicyCvrgLimit
composition [0..*] of R_InsurancePolicyCvrgClauseTP as _InsurancePolicyCvrgClause
composition [0..*] of R_InsurPolicyCvrgDeductibleTP as _InsurPolicyCvrgDeductible
composition [0..*] of R_InsurPolicyInsuredObjectTP as _InsurancePolicyInsuredObject
composition [0..*] of R_InsurPlcySubCoverageTP as _InsurPlcySubCoverage
composition [0..*] of R_InsurCvrgPlannedProcessingTP as _InsurCvrgPlndProcessing
association [1..1] to E_InsurancePolicyCoverage as _Extension on $projection.InsurPlcyUUID = _Extension.InsurPlcyUUID
and $projection.InsurPlcyInsurContr = _Extension.InsurPlcyInsurContr
and $projection.InsurPlcyCoveragePackageID = _Extension.InsurPlcyCoveragePackageID
and $projection.InsurPlcyCoverageID = _Extension.InsurPlcyCoverageID
and $projection.InsurPlcyJrnlNmbr = _Extension.InsurPlcyJrnlNmbr
and $projection.InsurPlcyJrnlEndNmbr = _Extension.InsurPlcyJrnlEndNmbr
association [1..1] to E_InsurancePolicyPremium as _Extension_Prem on $projection.InsurPlcyUUID = _Extension_Prem.InsurPlcyUUID
and $projection.InsurPlcyInsurContr = _Extension_Prem.InsurPlcyInsurContr
and $projection.InsurPlcyCoveragePackageID = _Extension_Prem.InsurPlcyCoveragePackageID
and $projection.InsurPlcyCoverageID = _Extension_Prem.InsurPlcyCoverageID
and 0 = _Extension_Prem.InsurPlcyCoverageOptionID
and 0 = _Extension_Prem.InsurPlcyInsuredObjectID
//and 0 = _Extension_Prem.InsurPlcyPremSubjectID
and $projection.InsurancePolicyPremium = _Extension_Prem.InsurancePolicyPremium
and $projection.InsurPlcyPremiumJournalNumber = _Extension_Prem.InsurPlcyJrnlNmbr
and $projection.InsurPlcyPremJournalEndNumber = _Extension_Prem.InsurPlcyJrnlEndNmbr
{
key InsurPlcyUUID,
key InsurPlcyInsurContr,
key InsurPlcyCoveragePackageID,
key InsurPlcyCoverageID,
InsurPlcyProductPackageID as InsurPolicyContractPackageID,
InsurPlcyJrnlNmbr,
InsurPlcyJrnlEndNmbr,
InsurPlcyInsuranceCoverage,
InsurPlcyElementaryProdTmpl as InsurancePolicyCoverageControl,
InsurPlcyCoverageStartDateTime,
InsurPlcyCoverageEndDateTime,
InsurPlcyCvrgPremExmpReason,
InsurPlcyCvrgLifeCycleStatus,
InsurContrCanclnRsn,
InsurPlcyCvrgCanclnDateTime,
InsurPlcyCoverageSuspension,
InsurPlcyCvrgSuspnStrtDateTime,
InsurPlcyCvrgSuspnEndDateTime,
InsurPlcyCvrgInsuredSumAmount,
InsurPlcyCvrgInsrdSumCalcMeth,
InsurPlcyCvrgInsuredSumPercent,
InsurPlcyCoverageCurrency,
InsurancePolicyPremium,
InsurPlcyPremiumJournalNumber,
InsurPlcyPremJournalEndNumber,
InsurPerdPremBfrTaxPaytAmt,
InsurPerdPremAftTaxPaytAmt,
InsurPremType,
InsurPlcyCvrgIsPremiumExempt,
InsurPlcyCvrgPremExmpEndDate,
InsurPlcyPremiumCurrency,
InsurPlcyTotAnnPremAmt,
InsurPlcyPerdPremBfrTxPaytAmt,
InsurPlcyPremiumTemplate as InsurancePolicyPremiumControl,
LastChangeDateTime,
/* Associations */
_InsurPlcyCoveragePackage,
_InsurPlcyCvrgSurchrgDiscount,
_InsurancePolicyCvrgLimit,
_InsurancePolicyCvrgClause,
_InsurPolicyCvrgDeductible,
_InsurancePolicyInsuredObject,
_InsurPlcySubCoverage,
_InsurCvrgPlndProcessing
}