R_FUNDCORETP

CDS View

Manage Funds in Core using RAP

R_FUNDCORETP is a CDS View in S/4HANA. Manage Funds in Core using RAP. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_FundCore view_entity projection COMPOSITE Fund 
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.sapObjectNodeType.name: 'Fund'
@EndUserText.label: 'Manage Funds in Core using RAP'
define root view entity R_FundCoreTP
  as select from I_Fund as iFund
  //association [1]    to I_FinancialManagementArea as _FinMgmtAreaForEdit on $projection.financialmanagementareaforedit = _FinMgmtAreaForEdit.FinancialManagementArea

  composition [0..*] of R_FundCoreTextTP as _Text
  association [0..1] to I_User as _user_created on  $projection.FundCreatedBy = _user_created.UserID
  association [0..1] to I_User as _user_changed on  $projection.LastChangedByUser = _user_changed.UserID
  association [0..1] to E_Fund as _Extension    on  $projection.Fund                    = _Extension.Fund
                                                and $projection.FinancialManagementArea = _Extension.FinancialManagementArea
{
      //@ObjectModel.readOnly: true

  key iFund.FinancialManagementArea,
      //@ObjectModel.readOnly: true

  key iFund.Fund,
      //@ObjectModel.mandatory: true

      //iFund.FinancialManagementArea                                      as FinancialManagementAreaForEdit,

      //iFund.Fund                                                         as FundForEdit,

      iFund.FundType,
      iFund.FundPeriodicity,
      iFund.FundAuthznGrp,

      case
      when _user_created.UserDescription is initial then iFund.FundCreatedBy
      else _user_created.UserDescription end                             as CreatedByUserDescription,
      //@ObjectModel.readOnly: true

      case
      when _user_changed.UserDescription is initial then iFund.LastChangeUser
      else _user_changed.UserDescription end                             as LastChangedByUserDescription,
      iFund.FundCreatedBy,
      iFund.FundCreatedAt,
      iFund.LastChangeUser                                               as LastChangedByUser,
      iFund.LastChangeDate,
      iFund.ValidityStartDate,
      iFund.ValidityEndDate,
      iFund._Text[1:Language = $session.system_language].FundName        as FundName,
      iFund._Text[1:Language = $session.system_language].FundDescription as FundDescription,
      cast ( iFund.FundFinMgmtAreaForAuthzn as fikrs preserving type ) as FundFinMgmtAreaForAuthzn,
      iFund.FundResponsibleUser,

      iFund._FundAuthznGrp,
      iFund._FundType,
      iFund._FinMgmtArea,
      _Text,      
      iFund._FundPeriodicity
      //_FinMgmtAreaForEdit,

      // CONCAT_WITH_SPACE(iFund.FinancialManagementArea, iFund.Fund , 1 )  as ObjectKey

}

Learn More