R_FUNCTIONALLOCATIONPARTNERTP

CDS View

Functional Location Partner

R_FUNCTIONALLOCATIONPARTNERTP is a CDS View in S/4HANA. Functional Location Partner. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
A_FunctionalLocationPartner view_entity projection COMPOSITE Functional Location Partner
I_FunctionalLocationPartnerTP view_entity projection TRANSACTIONAL Functional Location Partner - TP 
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Functional Location Partner'

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED
@AccessControl.personalData.blocking: #NOT_REQUIRED

define view entity R_FunctionalLocationPartnerTP 
as select from I_FunctionalLocation
   left outer join I_PlantMaintenancePartner on I_PlantMaintenancePartner.MaintObjectInternalID = I_FunctionalLocation.MaintObjectInternalID
   association to parent R_FunctionalLocationTP as _FunctionalLocation on $projection.FunctionalLocation = _FunctionalLocation.FunctionalLocation                                              
    {
      key cast(I_FunctionalLocation.FunctionalLocation  as tplnr_unconverted preserving type) as FunctionalLocation,
      key cast(I_PlantMaintenancePartner.PartnerFunction as parvw_unv preserving type ) as PartnerFunction,
      key I_PlantMaintenancePartner.MaintenancePartnerObjectNumber as FuncnlLocPartnerObjectNmbr,
      _FunctionalLocation.FunctionalLocationLabelName,
      I_PlantMaintenancePartner.Partner,
      I_PlantMaintenancePartner.CreatedByUser,
      I_PlantMaintenancePartner.CreationDate, 
      I_PlantMaintenancePartner.CreationTime,
      I_PlantMaintenancePartner.LastChangedByUser,
      I_PlantMaintenancePartner.LastChangeTime,
      I_PlantMaintenancePartner.LastChangeDate,           
      I_PlantMaintenancePartner.MaintObjectInternalID,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._PartnerFunction.SDDocumentPartnerType as PartnerFunctionType,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._ContactPerson.IsBusinessPurposeCompleted as CntctPersnIsBusPrpsCompleted,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._ContactPerson._Customer.CustomerAccountGroup as CntctPersnCustomerAccountGroup,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._ContactPerson._Customer.AuthorizationGroup as CntctPersnCustomerAuthznGroup,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._ContactPerson._Supplier.SupplierAccountGroup as CntctPersnSupplierAccountGroup,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._ContactPerson._Supplier.AuthorizationGroup as CntctPersnSupplierAuthznGroup,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._Customer.IsBusinessPurposeCompleted as CustomerIsBusPrpsCmpltd,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._Customer.CustomerAccountGroup,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._Customer.AuthorizationGroup as CustomerAuthznGrp,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._Employee.IsBusinessPurposeCompleted as EmployeeIsBusPrpsCmpltd,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._Employee.AuthorizationGroup as EmployeeAuthznGroup,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._Supplier.IsBusinessPurposeCompleted as SupplierIsBusPrpsCmpltd,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._Supplier.SupplierAccountGroup,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._Supplier.AuthorizationGroup as SupplierAuthznGrp,  
      _FunctionalLocation
          
    }where I_PlantMaintenancePartner.PartnerFunction is not null

Learn More