R_FINANCIALTRANSACTIONTP

CDS View

Financial Transaction - TP

R_FINANCIALTRANSACTIONTP is a CDS View in S/4HANA. Financial Transaction - TP. 3 CDS views read from this table.

Used by 3 CDS view(s)

CDS Views using this table (3)

ViewTypeJoinVDMDescription
A_FinTransIntrstRateInstr view_entity projection CONSUMPTION Interest Rate Instrument
A_FinTransIntrstRateInstr_2 view_entity projection CONSUMPTION Interest Rate Instrument
A_FinTransIntrstRateInstr_3 view_entity projection CONSUMPTION Interest Rate Instrument 
@AccessControl.authorizationCheck: #MANDATORY
@VDM.viewType: #TRANSACTIONAL
@ObjectModel:{
    usageType : {
        sizeCategory: #L,
        serviceQuality: #C,
        dataClass: #TRANSACTIONAL
    }
}
@EndUserText.label: 'Financial Transaction - TP'
@ObjectModel.representativeKey: 'FinancialTransaction'
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@ObjectModel.sapObjectNodeType.name: 'FinancialTransaction'
define root view entity R_FinancialTransactionTP
  as select from I_FinTransOverallView

  composition [1..1] of R_FinTransAttributeTP       as _Attribute

  composition [1..1] of R_FinTransAddlAttributeTP   as _AdditionalAttribute
  
  composition [1..*] of R_FinTransMainFlowTP        as _MainFlow
  
  composition [1..*] of R_FinTransRatingTP          as _Rating

  composition [1..*] of R_FinTransSPPIClassfctnTP   as _SPPIClassification
  
  composition [1..*] of R_FinTransPaytDetTP         as _PaymentDetail

  composition [0..*] of R_FinTransAdditionalFlowTP  as _AdditionalFlow

  composition [1..*] of R_FinTransCashFlowTP        as _CashFlow
  
  composition [1..*] of R_FinTransConditionTP       as _Condition
  
  composition [0..*] of R_FinTransExtTradeIdentifierTP as _ExtTradeIdentifier
  
  association [0..*] to I_FinTransIntrstRateAdjmt   as _InterestRateAdjustment on $projection.CompanyCode          = _InterestRateAdjustment.CompanyCode
                                                                              and $projection.FinancialTransaction = _InterestRateAdjustment.FinancialTransaction
  association [0..*] to I_FinTransFXRateAdjustment  as _FXRateAdjustment       on $projection.CompanyCode          = _FXRateAdjustment.CompanyCode
                                                                              and $projection.FinancialTransaction = _FXRateAdjustment.FinancialTransaction
  association [0..*] to I_FinTransPrcIdxAdjustment  as _PrcIdxAdjustment       on $projection.CompanyCode          = _PrcIdxAdjustment.CompanyCode
                                                                              and $projection.FinancialTransaction = _PrcIdxAdjustment.FinancialTransaction

  association [1..*] to I_FinTransInterestCondition as _InterestCondition     on  $projection.CompanyCode          = _InterestCondition.CompanyCode
                                                                              and $projection.FinancialTransaction = _InterestCondition.FinancialTransaction
  association [0..*] to I_FinTransInterestAdjmtCndn as _AdjustmentCondition   on  $projection.CompanyCode          = _AdjustmentCondition.CompanyCode
                                                                              and $projection.FinancialTransaction = _AdjustmentCondition.FinancialTransaction
  association [0..*] to I_FinTransRepaymentCndn     as _RepaymentCondition    on  $projection.CompanyCode          = _RepaymentCondition.CompanyCode
                                                                              and $projection.FinancialTransaction = _RepaymentCondition.FinancialTransaction
  association [0..*] to I_FinTransAccumulatingCndn  as _AccumulatingCondition on  $projection.CompanyCode          = _AccumulatingCondition.CompanyCode
                                                                              and $projection.FinancialTransaction = _AccumulatingCondition.FinancialTransaction
  association [0..*] to I_FinTransAccruedIntrstCndn as _AccruedCondition      on  $projection.CompanyCode          = _AccruedCondition.CompanyCode
                                                                              and $projection.FinancialTransaction = _AccruedCondition.FinancialTransaction


{

  key  CompanyCode,
  key  FinancialTransaction,
       FinancialInstrProductCategory,
       FinancialInstrumentActivity,
       FinancialInstrumentStatus,
       Counterparty,
       FinTransActyConclusionDate,
       FinTransActyConclusionTime,
       FinTransActyConclusionTimeZone,
       FinInstrExternalReference,
       MarketIdentifierCode,
       Trader,
       FinancialInstrContactPerson,
       CreatedByUser,
       FinTransCreationDate,
       FinTransCreationTime,
       LastChangedByUser,
       LastChangeDate,
       FinInstrumentLastChangedTime,
       FinancialInstrumentProductType,
       FinancialInstrTransactionType,
       TradeLegalBasis,
       ExternalTradeIdentifier,
       ClassificationOfFinInstr,
       TreasuryFinancialObject,

       _Attribute,
       _AdditionalAttribute,
       _MainFlow,
       _Rating,
       _SPPIClassification,
       _PaymentDetail,
       _AdditionalFlow,
       _CashFlow,
       _Condition,
       
       _InterestRateAdjustment,
       _FXRateAdjustment,
       _PrcIdxAdjustment,
       _ExtTradeIdentifier,
       _InterestCondition,
       _AdjustmentCondition,
       _RepaymentCondition,
       _AccumulatingCondition,
       _AccruedCondition
}

Learn More