R_FINANCIALTRANSACTIONNPVTP

CDS View

Fin Transaction Net Present Value - TP

R_FINANCIALTRANSACTIONNPVTP is a CDS View in S/4HANA. Fin Transaction Net Present Value - TP. 3 CDS views read from this table.

Used by 3 CDS view(s)

CDS Views using this table (3)

ViewTypeJoinVDMDescription
A_FinancialTransactionNPV view_entity projection CONSUMPTION Financial Transaction Net Present Value
C_FinancialTransactionNPVTP view_entity projection CONSUMPTION Financial Transaction Net Present Value
I_FinancialTransactionNPVTP view_entity projection TRANSACTIONAL Fin Transaction Net Present Value - TP 
@AccessControl.authorizationCheck: #MANDATORY

@EndUserText.label: 'Fin Transaction Net Present Value - TP'

@ObjectModel.sapObjectNodeType.name: 'FinancialTransactionNPV'
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #TRANSACTIONAL }

@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]
@VDM.viewType: #TRANSACTIONAL
@AbapCatalog.extensibility: {
  extensible: true,
  dataSources: ['_Extension'],
  elementSuffix: 'NEX',
  quota: {
    maximumFields: 100,
    maximumBytes: 100000
  }
}
@AbapCatalog.extensibility.allowNewCompositions
define root view entity R_FinancialTransactionNPVTP
  as select from R_FinancialTransactionNPV

  association [1..1] to E_FinancialTransactionNPV as _Extension
    on
        $projection.CompanyCode                 = _Extension.CompanyCode
    and $projection.FinancialTransaction        = _Extension.FinancialTransaction
    and $projection.FinancialTransactionNPVType = _Extension.FinancialTransactionNPVType
    and $projection.NetPresentValueValidityDate = _Extension.NetPresentValueValidityDate

{
  key CompanyCode,
  key FinancialTransaction,
  key FinancialTransactionNPVType,
  key NetPresentValueValidityDate,

      TreasuryContractType,
      NetPresentValueAmountInNPVCrcy,
      NetPresentValueCurrency,
      IntrinsicValueAmountInNPVCrcy,
      TimeValueAmountInNPVCrcy,
      CleanPriceAmountInNPVCrcy,
      IncomingNPVAmountInNPVCrcy,
      OutgoingNPVAmountInNPVCrcy,
      RiskFreeNPVAmountInNPVCrcy,
      CreditValueAdjmtAmtInNPVCrcy,
      DebitValueAdjmtAmtInNPVCrcy,
      CreditValueAdjustmentType,

      @Semantics.user.createdBy: true
      CreatedByUser,

      CreationTransactionCode,
      FinTransNPVCreationDate,
      FinTransNPVCreationTime,

      FinTransNPVCreationDateTime,
      FinTransNPVChangeDateTime,

      @Semantics.user.lastChangedBy: true
      LastChangedByUser,

      ChangeTransactionCode,
      FinTransNPVChangeDate,
      FinTransNPVChangeTime,

      cast(coalesce(FinTransNPVChangeDateTime, FinTransNPVCreationDateTime) as ftr_npv_last_change_tstmp preserving type)
                                                                                                                        as FinTransNPVLastChangeDateTime,

      FinTransNPVCalculationLogUUID,
      FinancialTransactionNPVHash,

      _CompanyCode,
      _FinancialTransaction,
      _NPVType,
      _NPVTypeText,
      _UserCreate,
      _UserLastChange,
      _NPVCurrency
}

Learn More