R_FINPOSTINGCLEARINGHEADERTP

CDS View

Posting and Clearing Service Header

R_FINPOSTINGCLEARINGHEADERTP is a CDS View in S/4HANA. Posting and Clearing Service Header. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
C_CustomerGuaranteeHeaderTP view_entity projection CONSUMPTION Manage Customer Guarantees Header
C_SupplierGuaranteeHeaderTP view_entity projection CONSUMPTION Manage Supplier Guarantees Header 
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: ['_CreatedByContactCard']
@EndUserText.label: 'Posting and Clearing Service Header'
@AbapCatalog.dataMaintenance: #RESTRICTED
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel.sapObjectNodeType.name: 'JournalEntryOperationalView'    //must have for BDEF

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@Metadata.ignorePropagatedAnnotations: true

@Consumption.dbHints: ['USE_HEX_PLAN']

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define root view entity R_FinPostingClearingHeaderTP
  as select from I_FinPostingClearingHeader

  composition of exact one to many R_FinPostingClearingItemTP as _DocItem

  association [0..1]       to R_FinPostingClearingItemTP      as _GuaranteeItem on  $projection.PostingClearingDocumentUUID = _GuaranteeItem.PostingClearingDocumentUUID
                                                                                and $projection.CompanyCode                 = _GuaranteeItem.CompanyCode
                                                                                and $projection.FiscalYear                  = _GuaranteeItem.FiscalYear
                                                                                and $projection.AccountingDocument          = _GuaranteeItem.AccountingDocument
                                                                                and $projection.PostingClearingDocDraftType = _GuaranteeItem.PostingClearingDocDraftType
                                                                                and _GuaranteeItem.SpecialGLCode            = '1'

  association [0..1]       to I_CompanyCode                   as _CompanyCode   on  $projection.CompanyCodeForEdit = _CompanyCode.CompanyCode
{
  key PostingClearingDocumentUUID,
  key CompanyCode,
  key FiscalYear,
  key AccountingDocument,
  key cast(' ' as fis_post_clear_doc_draft_type preserving type) as PostingClearingDocDraftType,

      @ObjectModel.editableFieldFor: 'CompanyCode'
      @ObjectModel.foreignKey.association: '_CompanyCode'
      cast( CompanyCode as fis_bukrs preserving type)            as CompanyCodeForEdit,
      @ObjectModel.editableFieldFor: 'FiscalYear'
      cast( FiscalYear as fis_gjahr_no_conv preserving type)     as FiscalYearForEdit,
      @ObjectModel.editableFieldFor: 'AccountingDocument'
      cast( AccountingDocument as farp_belnr_d preserving type)  as AccountingDocumentForEdit,

      /* BKPF fields */
      @ObjectModel.foreignKey.association: '_AccountingDocumentType'
      AccountingDocumentType,
      DocumentDate,
      PostingDate,
      PostingFiscalPeriod,
      JournalEntryCreationDate,
      JournalEntryCreationTime,
      ExchangeRateDate,
      AccountingDocCreatedByUser,
      TransactionCode,
      DocumentReferenceID,
      AccountingDocumentHeaderText,
      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      TransactionCurrency,
      AbsoluteExchangeRate,
      ExchRateIsIndirectQuotation,
      @ObjectModel.foreignKey.association: '_BusinessTransactionType'
      BusinessTransactionType,
      @ObjectModel.foreignKey.association: '_ReferenceDocumentType'
      ReferenceDocumentType,
      @ObjectModel.foreignKey.association: '_CompanyCodeCurrency'
      CompanyCodeCurrency,
      AdditionalCurrency1,
      TaxIsCalculatedAutomatically,
      TaxBaseAmountIsNetAmount,
      Branch,
      NmbrOfPages,
      Ledger,
      ExchangeRateType,
      JournalEntryLastChangeDateTime,

      /* Fields from internal processing purpose */
      cast( ''  as fdc_accdoc_tmp_doc_id )                       as PostingClearingSessionID,
      cast( ''  as dats )                                        as PostingClearingSessionCrtnDate,
      cast( ''  as tims )                                        as PostingClearingSessionCrtnTime,
      cast( ''  as laufi )                                       as PaymentRunIdentification,
      cast( '2' as fdc_data_entry_status_code )                  as PostingClearingDataEntryStatus,
      cast( ''  as char200 )                                     as PostingClearingHdrFldStsVal,
      cast( ''  as char50 )                                      as PostingClearingHdrMnlEntrVal,
      cast( ''  as abap_boolean preserving type )                as PostingClearingWrngIsReported,

      /* Foreign Key Associations */
      _CompanyCode,
      _AccountingDocumentType,
      _CompanyCodeCurrency,
      _TransactionCurrency,
      _BusinessTransactionType,
      _ReferenceDocumentType,
      _Branch,
      _CreatedByContactCard,

      /* Text Associations */
      _AccountingDocumentTypeText,
      _TransactionCurrencyText,

      /* Navigation Associations */
      _DocItem,
      _GuaranteeItem
}

Learn More