R_ENTPROJTEAMROLESTAFFINTTP

CDS View

Enterprise Project Role Staffing Internal

R_ENTPROJTEAMROLESTAFFINTTP is a CDS View in S/4HANA. Enterprise Project Role Staffing Internal. 4 CDS views read from this table.

Used by 4 CDS view(s)

CDS Views using this table (4)

ViewTypeJoinVDMDescription
C_EnterpriseProjectEntitlement view_entity from CONSUMPTION Enterprise Project Entitlements list
C_EntPrjProfnlSrvcProjRespyTP view_entity projection CONSUMPTION Manage Prof Srvc Proj Responsibilities
C_EntProjBriefRoleStaffingTP view_entity projection CONSUMPTION Enterprise Project Brief role staffing
C_EntProjTeamRoleStaffIntTP view_entity projection CONSUMPTION Enterprise Project Role Staffing Internal 
@AccessControl.authorizationCheck: #MANDATORY

@EndUserText.label: 'Enterprise Project Role Staffing Internal'
@ObjectModel: {
   semanticKey:       [ 'ProjectEntitlementUUID' ],
   usageType:{
     serviceQuality:  #C,
     dataClass:       #MIXED,
     sizeCategory:    #L
   }
 }
@VDM: {
    viewType: #TRANSACTIONAL,
    lifecycle.contract.type: #SAP_INTERNAL_API
}

@Consumption.dbHints:[ 'USE_HEX_PLAN' ]
define view entity R_EntProjTeamRoleStaffIntTP

  as select from I_EntProjectEntitlement 
  association to parent I_EnterpriseProjectTP_2           as  _EnterpriseProject    on $projection.ProjectUUID     = _EnterpriseProject.ProjectUUID  
  association [1..1] to R_EntProjectTeamMemberTP          as _TeamMember            on $projection.TeamMemberUUID  = _TeamMember.TeamMemberUUID
  association [1..1] to R_EnterpriseProjectRoleTP         as _Role                  on $projection.ProjectRoleUUID = _Role.ProjectRoleUUID
  association [1..1] to I_PPM_ProjectRoleTypeText         as _ProjectRoleTypeText   on $projection.ProjectRoleType = _ProjectRoleTypeText. ProjectRoleType 
                                                                                    and  _ProjectRoleTypeText.LanguageCode = $session.system_language
  association [1..1] to R_EntProjBusinessUser             as _BusinessUser          on $projection.businesspartneruuid = _BusinessUser.BusinessPartnerUUID
  association [1..1] to I_WorkplaceAddress                as _WorkplaceAddress      on $projection.businesspartneruuid = _WorkplaceAddress.BusinessPartnerUUID                                                                                  
//For Cat 7 Authorization                                                                                      

  association [0..1] to I_EnterpriseProjectForUser        as _EnterpriseProjectForUser on _EnterpriseProjectForUser.ProjectUUID = $projection.ProjectUUID
{
  key ProjectEntitlementUUID,
      ProjectUUID,
      ProjectRoleUUID,
      TeamMemberUUID,
      _Role.ProjectRoleType as ProjectRoleType,
      _TeamMember.BusinessPartnerUUID,
      _TeamMember._BusinessPartner.BusinessPartner,
      
        
      @Semantics.user.createdBy: true
      CreatedByUser,
      @Semantics.systemDateTime.createdAt: true
      CreationDateTime,
      @Semantics.user.lastChangedBy: true
      LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      LastChangeDateTime,
//Association      

      _TeamMember, 
      _Role,
      _EnterpriseProject,
      _ProjectRoleTypeText,
      _TeamMember._BusinessPartner,
      _WorkplaceAddress,
      _EnterpriseProjectForUser,
      _BusinessUser
      }

Learn More