R_CREDITLIMITREQUESTTP

@ObjectModel: { usageType: { serviceQuality: #C,
                             sizeCategory:   #XL,
                             dataClass:      #MIXED },
                semanticKey: [ 'CaseID' ],
                representativeKey: 'CaseUUID',
                sapObjectNodeType: { name: 'CreditLimitChangeRequest' } }
@VDM: { viewType:  #TRANSACTIONAL,
        lifecycle: { contract: { type: #SAP_INTERNAL_API } } }
@AccessControl: { authorizationCheck: #CHECK,
                  personalData: { blocking: #REQUIRED },
                  privilegedAssociations: [ '_CreatedByUserContactCard',
                                            '_LastChangeUserContactCard',
                                            '_ClosedByUserContactCard',
                                            '_CaseProcessorContactCard',
                                            '_CaseResponsibleContactCard',
                                            '_BlockedCreditDecisionDocument',
                                            '_OpenCreditDecisionDocument',
                                            '_BrokenPromisesToPay',
                                            '_CreditAnalystContactCard' ] }
@EndUserText: { label: 'Credit Limit Change Requests' }

define root view entity R_CreditLimitRequestTP
  as select from I_CreditLimitRequest

  // VDM Associations

  // Created By Contact Card

  association [0..1] to R_RblsMgmtUserContactCard      as _CreatedByUserContactCard      on  $projection.CaseCreatedBy = _CreatedByUserContactCard.ContactCardID

  // Last Changed By Contact Card

  association [0..1] to R_RblsMgmtUserContactCard      as _LastChangeUserContactCard     on  $projection.CaseLastChangedBy = _LastChangeUserContactCard.ContactCardID

  // Closed By Contact Card

  association [0..1] to R_RblsMgmtUserContactCard      as _ClosedByUserContactCard       on  $projection.CaseClosedBy = _ClosedByUserContactCard.ContactCardID

  // Credit Analyst Contact Card

  association [0..1] to R_RblsMgmtUserContactCard      as _CaseProcessorContactCard      on  $projection.CaseProcessor = _CaseProcessorContactCard.ContactCardID

  // Responsible Contact Card

  association [0..1] to R_RblsMgmtUserContactCard      as _CaseResponsibleContactCard    on  $projection.CaseResponsible = _CaseResponsibleContactCard.ContactCardID

  // Credit Management Account

  association [0..1] to R_CreditMgmtAccountTP          as _CreditManagementAccount       on  $projection.BusinessPartner = _CreditManagementAccount.BusinessPartner
                                                                                         and $projection.CreditSegment   = _CreditManagementAccount.CreditSegment

  // Processor User

  association [0..1] to I_BusinessUser                 as _ProcessorUser                 on  $projection.CaseProcessor = _ProcessorUser.UserID

  // Person Responsible User

  association [0..1] to I_BusinessUser                 as _PersonResponsibleUser         on  $projection.CaseResponsible = _PersonResponsibleUser.UserID

  // Credit Decision Document

  association [0..1] to I_CrdtAcctNrOfBlkdCrdtDcsnDocs as _BlockedCreditDecisionDocument on  $projection.BusinessPartner = _BlockedCreditDecisionDocument.BusinessPartner
                                                                                         and $projection.CreditSegment   = _BlockedCreditDecisionDocument.CreditSegment

  // Credit Decision Document V2

  association [0..1] to I_CrdtAcctNrOfOpenCrdtDcsnDocs as _OpenCreditDecisionDocument    on  $projection.BusinessPartner = _OpenCreditDecisionDocument.BusinessPartner
                                                                                         and $projection.CreditSegment   = _OpenCreditDecisionDocument.CreditSegment

  // Broken Promises to Pay

  association [0..1] to I_CrdtMNrOfBrokenPromisesToPay as _BrokenPromisesToPay           on  $projection.BusinessPartner = _BrokenPromisesToPay.BusinessPartner
                                                                                         and $projection.CreditSegment   = _BrokenPromisesToPay.CreditSegment

  // Credit Analyst

  association [0..1] to R_CrdtMAccountMainAnalyst      as _CreditAnalyst                 on  $projection.BusinessPartner = _CreditAnalyst.BusinessPartner
                                                                                         and $projection.CreditSegment   = _CreditAnalyst.CreditSegment
                                                                                         and _CreditAnalyst.UserID       is not initial

  // Business Partner Quick View Facet

  association [0..1] to R_CrdtMgmtBPQuickViewTP        as _QuickView                     on  $projection.BusinessPartner = _QuickView.BusinessPartner

  // BO Composition

  composition [0..*] of R_CrdtLmtChgReqApprvlHierTP    as _ApprovalHierarchy

  // Extension Include View

  association [1]    to E_CreditLimitRequest           as _Extension                     on  $projection.CaseUUID = _Extension.CaseUUID

{
      // VDM Fields

  key CaseUUID,
      CaseID,

      @ObjectModel: { foreignKey: { association: '_QuickView' } }
      BusinessPartner,

      CreditSegment,

      @ObjectModel: { foreignKey: { association: '_CaseProcessorContactCard' } }
      CaseProcessor,

      @ObjectModel: { foreignKey: { association: '_CaseResponsibleContactCard' } }
      CaseResponsible,

      CaseExternalReference,
      CaseTitle,

      @ObjectModel: { foreignKey: { association: '_CreatedByUserContactCard' } }
      CaseCreatedBy,

      @Semantics: { systemDateTime: { createdAt: true } }
      CaseCreatedOn                                                               as CreditCaseCreationDateTime,

      @ObjectModel: { foreignKey: { association: '_LastChangeUserContactCard' } }
      CaseLastChangedBy,

      @Semantics: { systemDateTime: { lastChangedAt: true } }
      CaseLastChangedOn                                                           as CreditCaseLastChangeDateTime,

      @ObjectModel: { foreignKey: { association: '_ClosedByUserContactCard' } }
      CaseClosedBy,

      @Semantics: { dateTime: true }
      CaseClosedTime                                                              as CreditCaseCloseDateTime,

      CasePlannedCloseDate,
      CaseReason,
      CaseType,
      CaseStatusProfile,
      CaseStatus,
      CaseSystemStatus,
      CasePriority,
      CaseAuthorizationLevel,
      CaseEscalationReason,
      CaseCategory,
      CaseStatusObjectNumber,
      CaseSystemStatusName,
      CaseUserStatusName,
      CreditLimitUtilizationPct,
      BusinessPartnerRating,
      CreditRiskClass,
      CrdtMgmtBusinessPartnerGroup,
      CreditSegmentCurrency,

      @Semantics: { amount: { currencyCode: 'CreditSegmentCurrency' } }
      CreditLimitAmount,

      @Semantics: { amount: { currencyCode: 'CreditSegmentCurrency' } }
      CreditLimitRequestedAmount,

      @Semantics: { amount: { currencyCode: 'CreditSegmentCurrency' } }
      CreditLimitApprovedAmount,

      @Semantics: { amount: { currencyCode: 'CreditSegmentCurrency' } }
      ExpectedSalesAmount,

      @Semantics: { amount: { currencyCode: 'CreditSegmentCurrency' } }
      cast( CustomerCreditExposureAmount as ukm_clcr_comm_total preserving type ) as CustomerCreditExposureAmount,

      CreditLimitValidityEndDate,

      @ObjectModel: { foreignKey: { association: '_CreditAnalystContactCard' } }
      _CreditAnalyst.UserID                                                       as CreditCoordinator,

      // Exposed Associations

      _BusinessPartner,
      _CaseSystemStatus,
      _CaseTypes,
      _CrdtMBusPartnerGroup,
      _CreditManagementBP,
      _CreditRiskClass,
      _CreditSegment,
      _Currency,
      _Escalation,
      _Individual,
      _CaseCategory,
      _Priority,
      _Reasons,
      _StatProfile,
      _CreatedByUserContactCard,
      _LastChangeUserContactCard,
      _ClosedByUserContactCard,
      _CaseResponsibleContactCard,
      _CaseProcessorContactCard,
      _CreditManagementAccount,
      _BlockedCreditDecisionDocument,
      _OpenCreditDecisionDocument,
      _BrokenPromisesToPay,
      _CreditAnalyst,
      _ProcessorUser,
      _PersonResponsibleUser,
      _CreditAnalyst._CreditAnalystContactCard,
      _QuickView,
      _ApprovalHierarchy

}