R_CONDITIONCONTRACTTP

@EndUserText.label: 'Condition Contract - TP'
@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #BLOCKED_DATA_EXCLUDED,
  privilegedAssociations: [  '_LastChangedByUser', '_CreatedByUser'  ]
}
@ObjectModel: {
  usageType.serviceQuality: #C,
  usageType.dataClass: #TRANSACTIONAL,
  usageType.sizeCategory: #XXL,
  semanticKey: [  'ConditionContract' ],
  representativeKey: 'ConditionContract',
  sapObjectNodeType.name: 'ConditionContract'
}
@AbapCatalog.extensibility: {
  extensible: true,
  dataSources: ['_Extension'],
  elementSuffix: 'CCH',
  quota: {
    maximumFields: 204, //This is calculated with formula - 2* <Customer Percentage from SCFD_REGISTRY> * <max number of fields in SCFD_REGISTRY>

    maximumBytes: 2040  //This is calculated with formula - 2* <Customer Percentage from SCFD_REGISTRY> * <number of chars as defined in SCFD_REGISTRY>

  } 
}
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@Metadata: {
  ignorePropagatedAnnotations: true
}
@Analytics: {
  technicalName: 'RCNDNCNTRTP'
} 

define root view entity R_ConditionContractTP
  as select from R_ConditionContract

  composition [0..*] of R_CndnContrSettlmtCalTP        as _CndnContrSettlmtCal
  composition [0..*] of R_CndnContrBusVolSelCriteriaTP as _CndnContrBusVolSelCriteria
  composition [0..*] of R_CndnContrActiveStatusTP      as _CndnContrActiveStatus
  composition [0..*] of R_CndnContrCndnRecordTP        as _CndnContrCndnRecord

  //Extension Association

  association [1..1] to E_ConditionContract            as _Extension on $projection.ConditionContract = _Extension.ConditionContract
{
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_ConditionContractStdVH', element: 'ConditionContract' } }],
        semanticObject: 'ConditionContract'
      }
  key ConditionContract,
      @ObjectModel.foreignKey.association: '_CndnContrType'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_CndnContrTypeStdVH', element: 'CndnContrType' } }]
      }
      CndnContrType,
      @ObjectModel.foreignKey.association: '_CndnContrProcVar'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_CndnContrProcVarStdVH', element: 'CndnContrProcVar' } }]
      }
      CndnContrProcVar,

      /* --- Condition Contract Partner --- */
      @ObjectModel.foreignKey.association: '_Supplier'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_Supplier_VH', element: 'Supplier' } }],
        semanticObject: 'Supplier'
      }
      Supplier,
      @ObjectModel.foreignKey.association: '_Customer'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_Customer_VH', element: 'Customer' } }],
        semanticObject: 'Customer'
      }
      Customer,
      @Consumption:{
        valueHelpDefinition: [{ entity: { name:'I_PersWrkAgrmtSrchHelp_1' , element: 'PersonWorkAgreement' } }]
      }
      PersonWorkAgreement,

      /* --- Basic Contract Data --- */
      @ObjectModel.foreignKey.association: '_CndnContrActvtnStatus'
      CndnContrActvtnStatus,
      @Semantics.businessDate.from: true
      CndnContrValidFrom,
      @Semantics.businessDate.to: true
      CndnContrValidTo,
      @ObjectModel.foreignKey.association: '_CndnContrClassfctnType'
      CndnContrClassfctnType,

      DocumentReferenceID,
      CndnContrAssgmtRef,
      ExternalDocumentReferenceID,
      CndnContrExternalPartner,
      @ObjectModel.foreignKey.association: '_CndnContrSourceDocCat'
      CndnContrSourceDocCat,
      CndnContrSourceDoc,
      CndnContrSourceDocItem,
      CndnContrSourceUUID,

      /* --- Administrational Data --- */
      //      @ObjectModel: {

      //        foreignKey: { association: '_CreatedByUser' }

      //      }

      @Semantics.user.createdBy: true
      CreatedByUser,
      @Semantics.systemDate.createdAt: true
      CreationDate,
      CreationTime,
      CreationTimeZone,
      CreationUTCDateTime,
      //      @ObjectModel: {

      //        foreignKey: { association: '_LastChangedByUser' }

      //      }

      @Semantics.user.lastChangedBy: true
      LastChangedByUser,
      @Semantics.systemDate.lastChangedAt: true
      LastChangedDate,
      LastChangeTime,
      LastChangeUTCDateTime,

      /* --- Organizational Data --- */
      @ObjectModel.foreignKey.association: '_CompanyCode'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } }]
      }
      CompanyCode,
      @ObjectModel.foreignKey.association: '_PurchasingOrganization'
      PurchasingOrganization,
      @ObjectModel.foreignKey.association: '_PurchasingGroup'
      PurchasingGroup,
      @ObjectModel.foreignKey.association: '_SalesOrganization'
      SalesOrganization,
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      DistributionChannel,
      @ObjectModel.foreignKey.association: '_Division'
      Division,
      @ObjectModel.foreignKey.association: '_SalesGroup'
      SalesGroup,
      @ObjectModel.foreignKey.association: '_SalesOffice'
      SalesOffice,

      /* --- Settlement Data --- */
      @ObjectModel.foreignKey.association: '_CndnContrSuplrSettlmtCat'
      CndnContrSuplrSettlmtCat,
      @ObjectModel.foreignKey.association: '_CndnContrCustSettlmtCat'
      CndnContrCustSettlmtCat,
      @ObjectModel.foreignKey.association: '_SettlmtProduct'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_ProductVH_2', element: 'Product' } }]
      }
      SettlmtProduct,
      @ObjectModel.foreignKey.association: '_CndnContrExtensionCalendar'
      CndnContrExtensionCalendar,
      @ObjectModel.foreignKey.association: '_PriorSupplier'
      PriorSupplier,
      @ObjectModel.foreignKey.association: '_BusVolTableGroup'
      BusVolTableGroup,
      @ObjectModel.foreignKey.association: '_AmountFieldGroup'
      AmountFieldGroup,
      @ObjectModel.foreignKey.association: '_CndnContrSettlmtCalcMethod'
      CndnContrSettlmtCalcMethod,

      /* --- Settlement Calendar Data --- */
      @ObjectModel.foreignKey.association: '_FinalSettlmtCalendar'
      FinalSettlmtCalendar,
      @ObjectModel.foreignKey.association: '_PartialSettlmtCalendar'
      PartialSettlmtCalendar,
      @ObjectModel.foreignKey.association: '_DeltaSettlmtCalendar'
      DeltaSettlmtCalendar,
      @ObjectModel.foreignKey.association: '_DeltaAccrualSettlmtCalendar'
      DeltaAccrualSettlmtCalendar,
      @ObjectModel.foreignKey.association: '_AccrualClearingSettlmtCal'
      AccrualClearingSettlmtCalendar,

      /* --- Complementing Data --- */
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_PrecedingConditionDocumentVH', element: 'PrecedingConditionDocument' } }]
      }
      PrecedingConditionDocument,

      CndnContrUUID,
      CndnContrPurposeCat,

      @ObjectModel.foreignKey.association: '_CndnContrCurrency'
      CndnContrCurrency,
      @ObjectModel.foreignKey.association: '_CndnContrUnit'
      CndnContrUnit,
      @ObjectModel.foreignKey.association: '_CndnContrWeightUnit'
      CndnContrWeightUnit,
      @ObjectModel.foreignKey.association: '_CndnContrVolumeUnit'
      CndnContrVolumeUnit,
      @ObjectModel.foreignKey.association: '_CndnContrPointsQtyUnit'
      CndnContrPointsQtyUnit,

      ExchangeRate,
      ExchangeRateDate,
      @ObjectModel.foreignKey.association: '_ExchangeRateType'
      ExchangeRateType,

      PaymentTerms,
      CashDiscount1Days,
      CashDiscount1Percent,
      CashDiscount2Days,
      CashDiscount2Percent,
      NetPaymentDays,
      PaymentMethod,

      @Semantics.booleanIndicator
      AccrualUpdateIsRequired,
      SettlmtPartTxRegnNmbr,
      @ObjectModel.foreignKey.association: '_TaxCountry'
      TaxCountry,
      @ObjectModel.foreignKey.association: '_SettlmtPartTxRegnCntry'
      SettlmtPartTxRegnCntry,

      @ObjectModel.foreignKey.association: '_CndnContrPrcgDetnRlvnceCat'
      CndnContrPrcgDetnRlvnceCat,
      @ObjectModel.foreignKey.association: '_BusVolTotAmtSpltCritraGrp'
      BusVolTotAmtSpltCritraGrp,
      CndnContrSettlementVariant,

      @ObjectModel.foreignKey.association: '_CndnContrPartnerCat'
      CndnContrPartnerCat,
      @ObjectModel.foreignKey.association: '_CndnContrProcessCategory'
      CndnContrProcessCategory,
      @ObjectModel.foreignKey.association: '_CndnContrSettlmtType'
      CndnContrSettlmtType,

      /* Worker related fields */
      CndnContrWorkerCostCenter,
      CndnContrWrkrControllingArea,
      CndnContrWorkerSettlmtCat,

      DataController,

      /* Semantic Code */
      CndnContrSemanticCode,

      /* Compositions */
      _CndnContrSettlmtCal,
      _CndnContrBusVolSelCriteria,
      _CndnContrActiveStatus,
      _CndnContrCndnRecord,

      /* Associations */
      _CndnContrType,
      _CndnContrProcVar,
      _Customer,
      _Supplier,
      _PersonWorkAgreement,
      _AccrualClearingSettlmtCal,
      _AmountFieldGroup,
      _BusVolTableGroup,
      _CndnContrClassfctnType,
      _CndnContrConditionUsage,
      _CndnContrCurrency,
      _CndnContrExtensionCalendar,
      _CndnContrActvtnStatus,
      _CndnContrPointsQtyUnit,
      //      _CndnContrPurposeCat,

      _CndnContrSourceDocCat,
      _CndnContrCustSettlmtCat,
      _CndnContrSuplrSettlmtCat,
      _CndnContrSettlmtCalcMethod,
      _CndnContrUnit,
      _CndnContrVolumeUnit,
      _CndnContrWeightUnit,
      _CompanyCode,
      _CreatedByUser,
      _DeltaAccrualSettlmtCalendar,
      _DeltaSettlmtCalendar,
      _DistributionChannel,
      _Division,
      _ExchangeRateType,
      _FinalSettlmtCalendar,
      _LastChangedByUser,
      _PartialSettlmtCalendar,
      _PrecedingConditionDocument,
      _PriorSupplier,
      _PurchasingGroup,
      _PurchasingOrganization,
      _SalesGroup,
      _SalesOffice,
      _SalesOrganization,
      _SettlmtProduct,
      _TaxCountry,
      _SettlmtPartTxRegnCntry,
      _CndnContrPrcgDetnRlvnceCat,
      _BusVolTotAmtSpltCritraGrp,
      _CndnContrSettlementVariant,
      _CndnContrPartnerCat,
      _CndnContrProcessCategory,
      _CndnContrSettlmtType,
      _CndnContrWorkerCostCenter,
      _CndnContrWrkrControllingArea,
      _CndnContrWorkerSettlmtCat

}