R_CONCURINCOMINGDOCUMENTTP
Documents imported from Concur - TP
R_CONCURINCOMINGDOCUMENTTP is a CDS View in S/4HANA. Documents imported from Concur - TP. 1 CDS views read from this table.
CDS Views using this table (1)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_ConcurIncomingDocumentTP | view_entity | projection | CONSUMPTION | Concur Posting Documents Monitor |
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@EndUserText.label: 'Documents imported from Concur - TP'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.sapObjectNodeType.name: 'ConcurTrvlAndExpnMgmtDoc'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.sizeCategory: #XL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define root view entity R_ConcurIncomingDocumentTP
as select from I_ConcurDocumentsAllUnion as ConcurDocument
composition [0..*] of C_ConcurDocumentProtocol as _ConcurDocumentProtocol
composition [0..*] of C_ConcurDocumentAttachment as _ConcurDocumentAttachment
composition [0..*] of C_ConcurDocCustModif as _ConcurDocumentCustModif
composition [0..*] of C_ConcurDocumentPaymentInfo as _ConcurDocumentPaymentInfo
association [0..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [0..1] to I_BusinessPartner as _BusinessPartner on $projection.BusinessPartner = _BusinessPartner.BusinessPartner
association [0..1] to I_ConcurDocumentTypeText as _ConcurDocumentType on _ConcurDocumentType.ConcurDocumentType = $projection.ConcurDocumentType
and _ConcurDocumentType.Language = $session.system_language
association [1..1] to I_ConcurSystemConnection as _ConcurSystem on $projection.ConcurSystemKey = _ConcurSystem.ConcurSystemKey
association [0..1] to I_ConcurDocumentStatusText as _ConcurDocumentStatus on _ConcurDocumentStatus.ConcurDocumentStatus = $projection.ConcurDocumentStatus
and _ConcurDocumentStatus.Language = $session.system_language
association [0..1] to I_ConcurDocPaymentStatusText as _ConcurDocPaymentStatus on _ConcurDocPaymentStatus.ConcurDocPaymentStatus = $projection.PaymentStatus
and _ConcurDocPaymentStatus.Language = $session.system_language
association [0..1] to I_ConcurDocRefKeyTypeText as _ConcurDocRefKeyType on _ConcurDocRefKeyType.ConcurDocRefKeyType = $projection.DocRefKeyType
and _ConcurDocRefKeyType.Language = $session.system_language
association [0..1] to I_ConcurConfigRefKeyTypeText as _ConcurConfigRefKeyType on _ConcurConfigRefKeyType.ConcurConfigRefKeyType = $projection.ConfigRefKeyType
and _ConcurConfigRefKeyType.Language = $session.system_language
association [0..1] to I_ConcurDocCustModifText as _ConcurDocumentCustModifText on _ConcurDocumentCustModifText.ConcurDocCustModifType = $projection.ConcurDocCustModifType
and _ConcurDocumentCustModifText.Language = $session.system_language
association [0..*] to R_ConcurDocumentProtocol as _ConcurDocumentProtocol_2 on $projection.ConcurSystemKey = _ConcurDocumentProtocol_2.ConcurSystemKey
and $projection.ConcurDocumentType = _ConcurDocumentProtocol_2.ConcurDocumentType
and $projection.ConcurDocumentID = _ConcurDocumentProtocol_2.ConcurDocumentID
and $projection.ConcurDocumentRevisionNumber = _ConcurDocumentProtocol_2.ConcurDocumentRevisionNumber
{
// @ObjectModel.text.element: [ '_ConcurSystem.SystemConnectionDescription1' ]
key ConcurDocument.ConcurSystemKey as ConcurSystemKey,
key ConcurDocument.ConcurDocumentType as ConcurDocumentType,
key ConcurDocument.ConcurDocumentID as ConcurDocumentID,
key ConcurDocument.ConcurDocumentRevisionNumber as ConcurDocumentRevisionNumber,
ConcurDocument.ConcurDocumentStatus as ConcurDocumentStatus,
ConcurDocument.CompanyCode as CompanyCode,
ConcurDocument.DocumentKey as ConcurDocumentKey,
ConcurDocument.HashKey as ConcurDocumentHashText,
ConcurDocument.AcknowledgedInd as ConcurIsAcknowledged,
ConcurDocument.ConfirmedInd as ConcurIsConfirmed,
ConcurDocument.PaidInd as ConcurIsPaymentSent,
ConcurDocument.ModifiedInd as ConcurDocCustModifType,
ConcurDocument.DocumentName as ConcurDocumentName,
ConcurDocument.ConcurPayeeId as ConcurPayeeIdentifier,
cast( ConcurDocument.CreationTimstp as tzntstmpl preserving type ) as ConcurCreatedAtDateTime,
cast( ConcurDocument.UpdateTimstp as tzntstmpl preserving type ) as ConcurUpdatedAtDateTime,
ConcurDocument.Lognumber as Lognumber,
ConcurDocument.FinSrvDocId as FinSrvDocId,
ConcurDocument.ApiVersionId as ApiVersionId,
ConcurDocument.LogTraceUuid as LogTraceUuid,
ConcurDocument.DocRefKey as DocRefKey,
ConcurDocument.ExtDataInd as ExtDataInd,
ConcurDocument.AttachmentInd as AttachmentInd,
ConcurDocument.PaymentStatus as PaymentStatus,
ConcurDocument.BusinessPartner as BusinessPartner,
ConcurDocument.RetentionDate as RetentionDate,
ConcurDocument.SdmVersion as SdmVersion,
ConcurDocument.ReportNumber as ReportNumber,
ConcurDocument.AttachmentTotalNumber as AttachmentTotalNumber,
ConcurDocument.DocRefKeyType as DocRefKeyType,
ConcurDocument.ConfigRefKeyType as ConfigRefKeyType,
ConcurDocument.ReceiptTotalNumber as ReceiptTotalNumber,
ConcurDocument.ReceiptInd as ReceiptInd,
// Associations for value helps
_CompanyCode,
_BusinessPartner,
_ConcurSystem,
_ConcurDocumentType,
_ConcurDocumentStatus,
_ConcurDocPaymentStatus,
_ConcurDocRefKeyType,
_ConcurConfigRefKeyType,
// Associations to other entities
_ConcurDocumentProtocol,
_ConcurDocumentAttachment,
_ConcurDocumentPaymentInfo,
_ConcurDocumentCustModif,
_ConcurDocumentCustModifText,
_ConcurDocumentProtocol_2
}