R_COMMITMENTITEMTP

CDS View

Manage Commitment Item - TP

R_COMMITMENTITEMTP is a CDS View in S/4HANA. Manage Commitment Item - TP. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_CommitmentItem view_entity projection CONSUMPTION Commitment Item 
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.usageType.dataClass: #MASTER
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@EndUserText.label: 'Manage Commitment Item - TP'

define root view entity R_CommitmentItemTP
  as select from I_CommitmentItem as iComItem

  association [1..1] to E_CommitmentItem as _Extension 
       on  $projection.FinancialManagementArea = _Extension.FinancialManagementArea
       and $projection.FinMgmtAreaFiscalYear   = _Extension.FinMgmtAreaFiscalYear
       and $projection.CommitmentItem          = _Extension.CommitmentItem

{

      @ObjectModel.readOnly: true      
  key iComItem.FinancialManagementArea,
      @ObjectModel.readOnly: true      
  key iComItem.FinMgmtAreaFiscalYear,
      @ObjectModel.readOnly: true
  key iComItem.CommitmentItem,      
      iComItem.CommitmentItemInternalId,
      iComItem.CommitmentItemShortID,
      iComItem.CommitmentItemIsPostingEnabled,
      iComItem.CmtmtItmFinancialTransaction,
      iComItem.CommitmentItemCategory,
      iComItem.CommitmentItemType,
      iComItem.ParentCommitmentItem,
      iComItem.FundsCenter,
      iComItem.CmtmtItmDefaultFundsCenter,
      iComItem.CmtmtItmCarryFwdItmCategory,
      iComItem.CommitmentItemIsStatistical,
      iComItem.CommitmentItemAuthznGrp,
      iComItem.CmtmtItemFinMgmtAreaForAuthzn,
      iComItem.ValidityEndDate,
      iComItem.ValidityStartDate,
      iComItem.CommitmentItemExpirationDate,

      iComItem._Text[1:Language = $session.system_language].CommitmentItemName                  as CommitmentItemName,
      iComItem._Text[1:Language = $session.system_language].CommitmentItemDescription           as CommitmentItemDescription,
      iComItem._Text[1:Language = $session.system_language].CommitmentItemDescription2          as CommitmentItemDescription2,
      iComItem._Text[1:Language = $session.system_language].CommitmentItemDescription3          as CommitmentItemDescription3,
      @ObjectModel.readOnly:  true
      iComItem._CommitmentItemHierarchy[1:CommitmentItemHierarchyVariant = '000'].CreationDate  as CreationDate,
      @ObjectModel.readOnly:  true
      iComItem._CommitmentItemHierarchy[1:CommitmentItemHierarchyVariant = '000'].CreatedByUser as CreatedByUser,
      iComItem._FinMgmtArea,
      iComItem._FiscalYearForFinMgmtArea,
      iComItem._Text,
      iComItem._FinancialTransaction,
      iComItem._CommitmentItemCategory,
      iComItem._CommitmentItemHierarchy

}

Learn More