R_CNSLDTNPOSTINGRULEGROUPTP

CDS View

Posting Rule Group - TP

R_CNSLDTNPOSTINGRULEGROUPTP is a CDS View in S/4HANA. Posting Rule Group - TP. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_CnsldtnPostingRuleGroupTP view_entity projection CONSUMPTION Rule Group 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Posting Rule Group - TP'
@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}
@ObjectModel: {
    sapObjectNodeType.name: 'ConsolidationPostingRuleGroup',
    usageType: {
      serviceQuality: #C,
      sizeCategory: #M,
      dataClass: #TRANSACTIONAL
    }
}
define root view entity R_CnsldtnPostingRuleGroupTP
  as select from I_CnsldtnPostingRuleGroup
  composition of exact one to many R_CnsldtnPstRlGroupRelationTP as _Node
  composition [0..*] of R_CnsldtnPstRlGroupTextTP                as _Text
  association [0..1]       to I_CnsldtnPostingRuleGroupText      as _Description               on  $projection.ConsolidationPostingRuleGroup = _Description.ConsolidationPostingRuleGroup
                                                                                               and _Description.Language                     = $session.system_language
  association [0..1]       to I_CnsldtnChartOfAccountsT          as _ChartOfAccountsText       on  $projection.ConsolidationChartOfAccounts = _ChartOfAccountsText.ConsolidationChartOfAccounts
                                                                                               and _ChartOfAccountsText.Language            = $session.system_language
  association [0..*]       to I_CnsldtnPostingRuleStatusVH       as _CnsldtnPstRlGroupStatusVH on  _CnsldtnPstRlGroupStatusVH.ConsolidationPostingRuleStatus = $projection.CnsldtnPostingRuleGroupStatus
  association [0..1]       to I_UserContactCard                  as _CreatedByUser             on  $projection.CreatedByUser = _CreatedByUser.ContactCardID
  association [0..1]       to I_UserContactCard                  as _ChangedByUser             on  $projection.ChangedBy = _ChangedByUser.ContactCardID
{
  key ConsolidationPostingRuleGroup,
      _Description.CnsldtnPstRlGroupLongText,
      _Description.CnsldtnPostingRuleGroupText,
      ConsolidationChartOfAccounts,
      _ChartOfAccountsText.ConsolidationChartOfAcctsText,
      CnsldtnPostingRuleGroupStatus,
      @Semantics.user.createdBy: true
      CreatedByUser,
      @Semantics.systemDateTime.createdAt: true
      CreationDateTime,
      @Semantics.user.localInstanceLastChangedBy: true
      ChangedBy,
      @Semantics.systemDateTime.localInstanceLastChangedAt: true
      ChangedDateTime,
      @Semantics.systemDateTime.lastChangedAt: true
      LastChangeDateTime,
      case CnsldtnPostingRuleGroupStatus
      when '1' then 3
      when '2' then 2
      else 0
      end as MandateStatusCriticality,
      /* Associations */
      _Node,
      _Text,
      _Description,
      _ChartOfAccountsText,
      _CnsldtnPstRlGroupStatusVH,
      _CreatedByUser,
      _ChangedByUser
}

Learn More