R_CNSLDTNGRPSTRUCTUREFILTERTP

CDS View

Cnsldtn Group Structure Filter - TP

R_CNSLDTNGRPSTRUCTUREFILTERTP is a CDS View in S/4HANA. Cnsldtn Group Structure Filter - TP. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_CnsldtnGrpStructureFilterTP view_entity projection CONSUMPTION Consolidation Group Structure Filter 
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Cnsldtn Group Structure Filter - TP'
@Metadata.ignorePropagatedAnnotations: true
@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}
@ObjectModel: {
    sapObjectNodeType.name: 'CnsldtnGroupStructureFilter',
    usageType: {
      serviceQuality: #C,
      sizeCategory: #M,
      dataClass: #TRANSACTIONAL
    }
}

define root view entity R_CnsldtnGrpStructureFilterTP
  as select from I_CnsldtnGroupStructureFilter
  composition [0..*] of R_CnsldtnGrpStrucFltMethodTP   as _Method
  composition [0..*] of R_CnsldtnGrpStrucFilterTextTP  as _Text
  composition [0..*] of R_CnsldtnGrpStrucFltrMethChgTP as _MethodChange
  composition [0..*] of R_CnsldtnGrpStrucFltrEvtTP     as _Event
  association [0..1] to R_CnsldtnGrpStrucFilterTextTP  as _Description                on  $projection.CnsldtnGroupStructureFilter = _Description.CnsldtnGroupStructureFilter
                                                                                      and _Description.Language                   = $session.system_language
  association [0..*] to I_CnsldtnPostingRuleStatusVH   as _CnsldtnPostingRuleStatusVH on  _CnsldtnPostingRuleStatusVH.ConsolidationPostingRuleStatus = $projection.ConsolidationPostingRuleStatus
  association [0..1] to I_UserContactCard              as _CreatedByUser              on  $projection.CreatedByUser = _CreatedByUser.ContactCardID
  association [0..1] to I_UserContactCard              as _ChangedByUser              on  $projection.ChangedBy = _ChangedByUser.ContactCardID

{
  key CnsldtnGroupStructureFilter,
      _Description.CnsldtnGrpStructureFilterText as CnsldtnGrpStructureFilterText,
      _Description.CnsldtnGrpStrucFltrLongText   as CnsldtnGrpStrucFltrLongText,
      ConsolidationPostingRuleStatus,
      @Semantics.user.createdBy: true
      CreatedByUser,
      @Semantics.systemDateTime.createdAt: true
      CreationDateTime,
      @Semantics.user.localInstanceLastChangedBy: true
      ChangedBy,
      @Semantics.systemDateTime.localInstanceLastChangedAt: true
      ChangedDateTime,
      @Semantics.systemDateTime.lastChangedAt: true
      LastChangeDateTime,
      case ConsolidationPostingRuleStatus
      when '1' then 3
      when '2' then 2
      else 0
      end                                        as MandateStatusCriticality,
      /* Associations */
      _CnsldtnGrpStrucFilterText,
      _Method,
      _Text,
      _MethodChange,
      _Description,
      _CnsldtnPostingRuleStatusVH,
      _Event,
      _CreatedByUser,
      _ChangedByUser
}

Learn More