R_CNDNCONTRBUSVOLSELCRITERIATP

@EndUserText.label: 'Business Volume Selection Criteria - TP'
@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #BLOCKED_DATA_EXCLUDED
}
@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #B,
     sizeCategory:   #S
   }
}
@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@Metadata: {
  ignorePropagatedAnnotations: true
}

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view entity R_CndnContrBusVolSelCriteriaTP
  as select from R_CndnContrBusVolSelCriteria

  association to parent R_ConditionContractTP as _ConditionContract on $projection.ConditionContract = _ConditionContract.ConditionContract
{

      @ObjectModel.foreignKey.association: '_ConditionContract'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_ConditionContractStdVH', element: 'ConditionContract' } }],
        semanticObject: 'ConditionContract'
      }
  key ConditionContract,
  key CndnContrBusVolUUID,

      @ObjectModel.foreignKey.association: '_BusVolFieldCombnType'
      BusVolFieldCombnType,
      BusVolFldCombnGroup,
      @ObjectModel.foreignKey.association: '_CndnContrBusVolSign'
      CndnContrBusVolSign,
      @ObjectModel.foreignKey.association: '_BusVolSelectionGroup'
      BusVolSelectionGroup,

      /* Validity */
      CndnContrBusVolValidFrom,
      CndnContrBusVolValidTo,

      /* Partners */
      @ObjectModel.foreignKey.association: '_Supplier'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_Supplier_VH', element: 'Supplier' } }],
        semanticObject: 'Supplier'
      }
      Supplier,
      @ObjectModel.foreignKey.association: '_Customer'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_Customer_VH', element: 'Customer' } }],
        semanticObject: 'Customer'
      }
      Customer,

      /* Organizational Data */
      @ObjectModel.foreignKey.association: '_CompanyCode'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } }]
      }
      CompanyCode,
      @ObjectModel.foreignKey.association: '_PurchasingOrganization'
      PurchasingOrganization,
      @ObjectModel.foreignKey.association: '_PurchasingGroup'
      PurchasingGroup,
      @ObjectModel.foreignKey.association: '_SalesOrganization'
      SalesOrganization,
      @ObjectModel.foreignKey.association: '_DistributionChannel'
      DistributionChannel,
      @ObjectModel.foreignKey.association: '_Division'
      Division,
      SalesOffice,
      SalesGroup,

      @ObjectModel.foreignKey.association: '_Plant'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_PlantStdVH', element: 'Plant' } }]
      }
      Plant,
      SupplierSubrange,
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_ProductGroupVH', element: 'ProductGroup' } }]
      }
      ProductGroup,
      @ObjectModel: {
        foreignKey: { association: '_Product' }
      }
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_ProductVH_2', element: 'Product' } }],
        semanticObject: 'Product'
      }
      Product,
      //      @ObjectModel: {

      //        foreignKey: { association: '_ProductType' }

      //      }

      // I_Producttype is internally deprecated and should not be used internally anymore, the successor I_ProcuctType_2 does not have the same fields

      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_ProductTypeVH', element: 'ProductType' } }]
      }
      ProductType,

      /* Hierarchies */
      @ObjectModel.foreignKey.association: '_CustomerHierarchy'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_Customer_VH', element: 'Customer' } }]
      }
      CustomerHierarchy,
      ProductHierarchy,
      ProdUnivHierarchyNode,

      @ObjectModel.foreignKey.association: '_SalesSpcfcProductGroup1'
      SalesSpcfcProductGroup1,
      @ObjectModel.foreignKey.association: '_SalesSpcfcProductGroup2'
      SalesSpcfcProductGroup2,
      @ObjectModel.foreignKey.association: '_SalesSpcfcProductGroup3'
      SalesSpcfcProductGroup3,
      @ObjectModel.foreignKey.association: '_SalesSpcfcProductGroup4'
      SalesSpcfcProductGroup4,
      @ObjectModel.foreignKey.association: '_SalesSpcfcProductGroup5'
      SalesSpcfcProductGroup5,

      @ObjectModel.foreignKey.association: '_SalesOrderReason'
      SalesOrderReason,

      /* Additional partners */
      @ObjectModel.foreignKey.association: '_Manufacturer'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_Supplier_VH', element: 'Supplier' } }]
      }
      Manufacturer,
      @ObjectModel.foreignKey.association: '_RoyaltyRecipient'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_Supplier_VH', element: 'Supplier' } }]
      }
      RoyaltyRecipient,
      @ObjectModel.foreignKey.association: '_CommissionRecipient'
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_Supplier_VH', element: 'Supplier' } }]
      }
      CommissionRecipient,
      @Consumption:{
        valueHelpDefinition: [{ entity: { name:'I_PersWrkAgrmtSrchHelp_1' , element: 'PersonWorkAgreement' } }]
      }
      WorkerCommissionRecipient,
      ShipToParty,
      PayerParty,

      //  CndnContrBusVolList,

      //  CndnContrCustomerList,

      //  CndnContrSupplierList,

      //  CndnContrPlantList,


      /* Service Contracts */
      @ObjectModel.foreignKey.association: '_ServiceDocumentType'
      ServiceDocumentType,
      @Consumption.semanticObject: 'ServiceContract'
      ServiceDocument,
      ServiceDocumentItem,

      CustomerGroup,

      /* Additional Customer Groups */
      AdditionalCustomerGroup1,
      AdditionalCustomerGroup2,
      AdditionalCustomerGroup3,
      AdditionalCustomerGroup4,
      AdditionalCustomerGroup5,

      /* Customer Condition Groups */
      CustomerConditionGroup1,
      CustomerConditionGroup2,
      CustomerConditionGroup3,
      CustomerConditionGroup4,
      CustomerConditionGroup5,

      /* Country/Region */
      Country,
      Region,

      ProductCommissionGroup,
      PricingReferenceProduct,
      SoldProduct,
      SalesDistrict,
      ProductPricingGroup,
      SalesVolumeRebateGroup,

      BizVolSelCndnContrProcVar,
      BizVolSelConditionContract,

      // !!! Do not expose above R_TP !!!

      // !!! Only added proforma, not to be exposed anywhere in C1 or C2 released layers! Discussion regarding internal and external format is necessary !!!

      // !!! Make sure to discuss before exposing it in views !!!

      WBSElementInternalID,

      CndnContrSuplrInvcDlvCostCat,
      ProductConditionGroup,

      /* Universal Customer Hierarchy */
      CustomerHierarchyRootNode,
      CustomerHierarchyNodeID,
      CustomerHierarchyNodeType,

      GLAccount,

      /* Object semantics */
      CndnContrSemanticCode,

      /* UUIDs */
      CndnContrSourceBusVolUUID,

      /* --- Root Entity --- */
      _ConditionContract,

      /* --- Associations --- */
      _BusVolFieldCombnType,
      _BusVolSelectionGroup,
      _CndnContrBusVolSign,
      _Supplier,
      _Customer,
      _CompanyCode,
      _PurchasingOrganization,
      _PurchasingGroup,
      _SalesOrganization,
      _DistributionChannel,
      _Division,
      _SalesOffice,
      _SalesGroup,
      _Plant,
      _Product,
      // I_Producttype is internally deprecated and should not be used internally anymore, the successor I_ProcuctType_2 does not have the same fields

      //      _ProductType,

      _CustomerHierarchy,
      _ProductHierarchy,
      _SalesSpcfcProductGroup1,
      _SalesSpcfcProductGroup2,
      _SalesSpcfcProductGroup3,
      _SalesSpcfcProductGroup4,
      _SalesSpcfcProductGroup5,
      _SalesOrderReason,
      _CommissionRecipient,
      _Manufacturer,
      _RoyaltyRecipient,
      _WorkerCommissionRecipient,
      _ShipToParty,
      _PayerParty,
      //      _CndnContrCustomerList,

      //      _CndnContrPlantList,

      //      _CndnContrSupplierList,

      _ServiceDocumentType,
      _CustomerGroup,
      _AdditionalCustomerGroup1,
      _AdditionalCustomerGroup2,
      _AdditionalCustomerGroup3,
      _AdditionalCustomerGroup4,
      _AdditionalCustomerGroup5,
      _Country,
      _Region,
      _ProductCommissionGroup,
      _PricingReferenceProduct,
      _SoldProduct,
      _SalesDistrict,
      _ProductPricingGroup,
      _BizVolSelCndnContrProcVar,
      _BizVolSelConditionContract,
      _WBSElementBasicData,
      _CndnContrSuplrInvcDlvCostCat

}