R_CELLCOMMENTTP

CDS View

Analytical Cell Comments-TP

R_CELLCOMMENTTP is a CDS View in S/4HANA. Analytical Cell Comments-TP. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_CellCommentTP view_entity projection CONSUMPTION Analytical Cell Comments-TP 
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Analytical Cell Comments-TP'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #B,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL

define root view entity R_CellCommentTP
as select from I_CellComment

  composition [0..*] of R_CellCommentContentTP as _CellCommentContent
  composition [0..*] of R_CellCommentTagTP            as _CellCommentTag

  association [1..*] to I_AnlytlCommentClassfctnText      as _AnlytlCommentClassfctnText
    on $projection.AnlytlCommentClassification            = _AnlytlCommentClassfctnText.AnlytlCommentClassification

  association [1..*] to I_AnlytlCommentStatusTxt      as _CommentStatusText
    on $projection.AnalyticalCommentStatus            = _CommentStatusText.AnalyticalCommentStatus
{
  key DocumentStoreCDSViewName,

  key CellCommentDocumentIdentifier,

      CellCommentTitle,

      AnalyticalCommentTitle,

      AnlytlCommentClassification,

      CellCommentTag,

      //@Semantics.user.createdBy: true

      @ObjectModel.text.element: ['CreatedByUserDescription']
      CellCommentCreatedByUser,

      @Semantics.text: true
      _CreatedByUser.UserDescription  as CreatedByUserDescription,

      //@Semantics.systemDateTime.createdAt: true

      CellCommentCreationDateTime,

      //@Semantics.user.lastChangedBy: true

      @ObjectModel.text.element: ['ChangedByUserDescription']
      CellCommentChangedByUser,

      @Semantics.text: true
      _ChangedByUser.UserDescription  as ChangedByUserDescription,

      //@Semantics.systemDateTime.localInstanceLastChangedAt: true

      CellCommentChangeDateTime,

      @ObjectModel.text.element: ['CopiedByUserDescription']
      AnalyticalCommentCopiedByUser,

      _CopiedByUser.UserDescription   as CopiedByUserDescription,

      AnalyticalCommentCopyDateTime,

      AnalyticalCommentStatus,

      CellCommentSource,

      CellCommentModelUUID,

      //cell comment context properties

      _CellCommentContext.AnalyticalCommentApplication,
      _CellCommentContext.SemanticObject,
      _CellCommentContext.SemanticObjectAction,
      _CellCommentContext.ReviewBookletPage,
      _CellCommentContext.AnlytlCommentDataProviderName,
      _CellCommentContext.AnlytlCmntNavgnParameterText,
      _CellCommentContext.AnlytlCmntContextModelBinary as MultiDimensionModelBin,




      _CellCommentContent,

      _CellCommentTag,

      _AnlytlCommentClassfctnText,

      _CommentStatusText


}

Learn More