R_BUSSOLNORDITMUSERSTATUSTP

CDS View

Business Solution Order User Status - TP

R_BUSSOLNORDITMUSERSTATUSTP is a CDS View in S/4HANA. Business Solution Order User Status - TP. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
A_BusSolnOrdItmUserStatus_2 view_entity projection CONSUMPTION Item User Status
I_BusSolnOrdItmUserStatusTP view_entity projection TRANSACTIONAL Business Solution Order User Status - TP 
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel: {
  usageType:{
    dataClass:      #TRANSACTIONAL,
    serviceQuality: #C,
    sizeCategory:   #L
    }
}

@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}

@EndUserText.label: 'Business Solution Order User Status - TP'

define view entity R_BusSolnOrdItmUserStatusTP
  as select from I_SrvcMgmtObjectStatus as SolutionOrderItemStatus
    inner join   P_StatusObjectWithGUID as StatusObject              on SolutionOrderItemStatus.SrvcMgmtObjectUUID = StatusObject.StatusObjectUUID

    inner join   I_ServiceDocumentItem  as BusinessSolutionOrderItem on  SolutionOrderItemStatus.SrvcMgmtObjectUUID             =    BusinessSolutionOrderItem.ServiceDocumentItemUUID
                                                                     and BusinessSolutionOrderItem.ServiceObjectType            =    'BUS2000172'
                                                                     and SolutionOrderItemStatus.SrvcMgmtObjectStatus           like 'E%'
                                                                     and SolutionOrderItemStatus.SrvcMgmtObjectStatusIsInactive =    ' '

  association        to parent R_BusinessSolutionOrderItemTP as _BusinessSolutionOrderItemTP on  $projection.BusinessSolutionOrder     = _BusinessSolutionOrderItemTP.BusinessSolutionOrder
                                                                                             and $projection.BusinessSolutionOrderItem = _BusinessSolutionOrderItemTP.BusinessSolutionOrderItem

  association [0..1] to R_BusinessSolutionOrderTP            as _BusinessSolutionOrderTP     on  $projection.BusinessSolutionOrder = _BusinessSolutionOrderTP.BusinessSolutionOrder

  association [0..1] to I_StatusCode                         as _StatusCode                  on  $projection.UserStatus    = _StatusCode.StatusCode
                                                                                             and $projection.StatusProfile = _StatusCode.StatusProfile

  association [0..1] to I_StatusProfile                      as _StatusProfile               on  $projection.StatusProfile = _StatusProfile.StatusProfile
  
  association [1..*] to I_UserStatusText  as _UserStatusText  on $projection.UserStatus = _UserStatusText.UserStatus
                                                                 and $projection.StatusProfile = _UserStatusText.StatusProfile
{

  key BusinessSolutionOrderItem.ServiceDocument     as BusinessSolutionOrder,
  key BusinessSolutionOrderItem.ServiceDocumentItem as BusinessSolutionOrderItem,

      @ObjectModel.foreignKey.association: '_StatusCode'
      @ObjectModel.text.association: '_UserStatusText'
  key SolutionOrderItemStatus.SrvcMgmtObjectStatus  as UserStatus,

      @ObjectModel.foreignKey.association: '_StatusProfile'
      StatusObject.StatusProfile                    as StatusProfile,

      // Associations

      _StatusCode,
      _StatusProfile,
      _BusinessSolutionOrderItemTP,
      _BusinessSolutionOrderTP,
      _UserStatusText
}

Learn More