R_BILLINGDOCUMENTPARTNERTP

CDS View

Billing Document Partner - TP

R_BILLINGDOCUMENTPARTNERTP is a CDS View in S/4HANA. Billing Document Partner - TP. 3 CDS views read from this table.

Used by 3 CDS view(s)

CDS Views using this table (3)

ViewTypeJoinVDMDescription
A_BillingDocumentPartner_2 view_entity projection CONSUMPTION Header Partners
C_BillingDocumentPartnerManage view_entity projection CONSUMPTION Billing Document Partner
I_BillingDocumentPartnerTP view_entity projection TRANSACTIONAL Billing Document Partner - TP 
@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}
@AccessControl: {
  authorizationCheck: #MANDATORY,  
  personalData.blocking: #('TRANSACTIONAL_DATA')

}
@ObjectModel: {
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL 
   },
    semanticKey: ['BillingDocument', 'PartnerFunction']
}

@EndUserText.label: 'Billing Document Partner - TP'

define view entity R_BillingDocumentPartnerTP 
  as select from I_BillingDocumentPartner
  association to parent R_BillingDocumentTP as _BillingDocument  
                                            on $projection.BillingDocument = _BillingDocument.BillingDocument
  association [0..1] to I_BusPartAddress    as _BusinessPartnerAddressCP      on I_BillingDocumentPartner.AddressID                   = _BusinessPartnerAddressCP.AddressID
                                                                              and $projection.ContactPerson is not initial
                                                                              and I_BillingDocumentPartner.SDDocPartnerAddressRefType =  'I'
{
   key BillingDocument,                                                                                           
   key cast(PartnerFunction as parvw_unv preserving type ) as PartnerFunction,
   
   Customer,
   Supplier,
   Personnel,
   ContactPerson,
   ReferenceBusinessPartner,
    
   case ContactPerson
        when '0000000000' then
         _BusinessPartnerAddress.AddressUUID
       else
         _BusinessPartnerAddressCP.AddressUUID
   end as BusinessPartnerAddressUUID,
   
   AddressID,
   AddressPersonID,
   AddressObjectType,
   cast(case SDDocPartnerAddressRefType
             when 'E' then 'X'
             when 'F' then 'X'
             else ' '
           end                 as sd_pd_doc_spec_addr_flag preserving type)          as SDDocPartnerAddrIsDocSpecific,
   VATRegistration,
   @Semantics.text: true
   UnloadingPointName,    
    
   _BillingDocument,
   _PartnerFunction   
}
where
_BillingDocument.BillingDocumentIsTemporary = ' '

Learn More