R_BANKTP

@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}

@Search.searchable: false

@AbapCatalog.extensibility: {
  extensible: true,
  elementSuffix: 'BNK',
  allowNewDatasources: false,
  dataSources: ['_Extension'],
  quota: {
    maximumFields: 500,
    maximumBytes: 5000
  },
  allowNewCompositions: true
}

@ObjectModel:{
   sapObjectNodeType:{ name: 'Bank'},
   usageType: {
     serviceQuality: #C,
     sizeCategory: #L,
     dataClass: #TRANSACTIONAL }
 }
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: [ '_BankAddress' ]
@EndUserText.label: 'Transactional Bank'
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define root view entity R_BankTP
  as select from I_BankEnhanced as Bank
  composition [1..1] of R_BankAddressTP         as _BankAddress
  association [1..1] to C_BankCategoryVH        as _BankCategory      on  $projection.BankCategory = _BankCategory.BankCategory
  association [1..1] to E_Bank                  as _Extension         on  $projection.BankCountry    = _Extension.BankCountry
                                                                      and $projection.BankInternalID = _Extension.BankInternalID
  association [1..1] to I_BankCountryFieldCheck as _CountryFieldCheck on  $projection.BankCountry = _CountryFieldCheck.BankCountry
{
      @ObjectModel.foreignKey.association: '_Country'
  key BankCountry,
  key BankInternalID,
      @Semantics.text: true
      BankName,
      LongBankName,
      BankBranch,
      LongBankBranch,
      ShortStreetName,
      StreetName,
      ShortCityName,
      CityName,
      Region,
      AddressRegion,
      SWIFTCode,
      BankNetworkGrouping,
      IsMarkedForDeletion,
      BankNumber,
      CheckDigitCalculationMethod,
      AddressID,
      BankDataFileFormat,
      BankCategory,
      _BankCategory.BankCategoryDescription                                                                               as BankCategoryDescription,

      cast ( concat_with_space( concat( $session.client , BankCountry ), BankInternalID, 1 ) as bf_bank_change_dodument ) as BankChangeDocument,
      cast ( concat( 'CA02', AddressID ) as bf_bank_address_change_doc )                                                  as BankAddressChangeDocument,

      @Semantics.booleanIndicator:true
      case
        when BankCategory is not null and BankCategory is not initial then cast( 'X' as bf_bank_internal_flag preserving type)

        else cast( ' ' as bf_bank_internal_flag preserving type)
      end                                                                                                                 as BankIsInternal,
      @Semantics.booleanIndicator:true
      case
        when BankCategory is null or BankCategory is initial then cast( 'X' as bf_bank_standard_flag preserving type)
        else cast( ' ' as bf_bank_standard_flag preserving type)
      end                                                                                                                 as BankIsStandard,

      cast( dats_tims_to_tstmp( CreationDate , cast('120000' as uzeit),
                          abap_system_timezone( $session.client,'NULL' ),
                          $session.client,
                         'NULL' ) as timestampl )                                                                         as LastChangeDateTime,

      concat_with_space( BankInternalID,
        concat('(', concat( LongBankName,')'
       ) ), 1 )                                                                                                           as BankKeyForDisplay,

      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CA_BNK_RAP_MB_UI_FIELD_EXIT'
      @Semantics.booleanIndicator:true
      @UI.hidden: true
      abap.char' '                                                                                                        as LongBankBranchIsHidden,
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CA_BNK_RAP_MB_UI_FIELD_EXIT'
      @Semantics.booleanIndicator:true
      @UI.hidden: true
      abap.char' '                                                                                                        as BankNumberIsHidden,
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CA_BNK_RAP_MB_UI_FIELD_EXIT'
      @Semantics.booleanIndicator:true
      @UI.hidden: true
      abap.char' '                                                                                                        as SWIFTCodeIsHidden,
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CA_BNK_RAP_MB_UI_FIELD_EXIT'
      @Semantics.booleanIndicator:true
      @UI.hidden: true
      abap.char' '                                                                                                        as BankNetworkGroupingIsHidden,
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CA_BNK_RAP_MB_UI_FIELD_EXIT'
      @Semantics.booleanIndicator:true
      @UI.hidden: true
      abap.char' '                                                                                                        as BankAddressIsHidden,
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CA_BNK_RAP_MB_UI_FIELD_EXIT'
      @Semantics.booleanIndicator:true
      @UI.hidden: true
      abap.char' '                                                                                                        as BankScriptedAddressIsHidden,
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CA_BNK_RAP_MB_UI_FIELD_EXIT'
      @Semantics.booleanIndicator:true
      @UI.hidden: true
      abap.char' '                                                                                                        as BankCategoryIsHidden,

      _CountryFieldCheck.BankCountryCheckKey,

      @Semantics.systemDate.createdAt: true
      CreationDate                                                                                                        as CreationDate,
      @Semantics.user.createdBy: true
      CreatedByUser                                                                                                       as CreatedByUser,

      _BankAddress,
      _Region,
      _BankCategory,
      _Country

}