R_ANALYTICALCOMMENTCONTENTTP

CDS View

Analysis comment content entity-TP

R_ANALYTICALCOMMENTCONTENTTP is a CDS View in S/4HANA. Analysis comment content entity-TP. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_AnalyticalCommentContentTP view_entity projection CONSUMPTION Analysis comment content entity-TP 
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Analysis comment content entity-TP'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #B,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL
define view entity R_AnalyticalCommentContentTP
  as select from I_AnalyticalCommentContent
  association     to parent R_AnalyticalCommentThreadTP as _AnalyticalCommentThread  on $projection.AnalyticalCommentThreadUUID = _AnalyticalCommentThread.AnalyticalCommentThreadUUID

  composition [0..*] of R_AnlytlCommentMentionedUserTP     as _AnalyticalCommentMention

{
  key AnalyticalCommentContentUUID,

      AnalyticalCommentThreadUUID,

      AnalyticalCommentVersion,

      FreeDfndAnlytlCmntCntntBinary,
      
      AnlytlCommentContentPlainText,
      
      @Semantics.user.createdBy: true
      @ObjectModel.text.element: ['CreatedByUserDescription']
      CreatedByUser,

      @Semantics.text: true
      case _CreatedByUser.UserDescription
        when '' then CreatedByUser
        else _CreatedByUser.UserDescription
      end as CreatedByUserDescription,

      @Semantics.systemDateTime.createdAt: true
      CreationDateTime,

      @Semantics.user.lastChangedBy: true
      @ObjectModel.text.element: ['ChangedByUserDescription']
      LastChangedByUser,
      
      @Semantics.text: true
      case _ChangedByUser.UserDescription
        when '' then LastChangedByUser
        else _ChangedByUser.UserDescription
      end as ChangedByUserDescription,

      @Semantics.systemDateTime.localInstanceLastChangedAt: true
      LastChangeDateTime,

      _AnalyticalCommentThread,

      _AnalyticalCommentMention

}

Learn More