R_ACCRENGINEACCRSUBOBJITEMTP

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Accrual Subobject Item'
@ObjectModel.usageType: {
  serviceQuality: #C,
  sizeCategory: #M,
  dataClass: #MASTER
 }
@VDM.viewType: #TRANSACTIONAL
@Metadata.ignorePropagatedAnnotations: true
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel.semanticKey: ['AccrualEngineAccrualObjectType','AccrualObjectLogicalSystem','CompanyCode','AccrualObject','AccrualSubobject',
                           'AccrualItemType','Ledger','AccrSubobjectItmValdtyEndDte']
define view entity R_AccrEngineAccrSubobjItemTP
  as select from I_AccrEngineAccrSubobjItem
  association        to parent R_AccrEngineAccrualSubobjectTP as _AccrualSubobject    on  $projection.AccrualEngineAccrualObjectType = _AccrualSubobject.AccrualEngineAccrualObjectType
                                                                                      and $projection.AccrualObjectLogicalSystem     = _AccrualSubobject.AccrualObjectLogicalSystem
                                                                                      and $projection.CompanyCode                    = _AccrualSubobject.CompanyCode
                                                                                      and $projection.AccrualObject                  = _AccrualSubobject.AccrualObject
                                                                                      and $projection.AccrualSubobject               = _AccrualSubobject.AccrualSubobject
  association [0..1] to I_AccrEngineAccrItemType              as _AccrItemTypeForEdit on  $projection.AccrualEngineAccrualObjectType = _AccrItemTypeForEdit.AccrualEngineAccrualObjectType
                                                                                      and $projection.AccrualItemTypeForEdit         = _AccrItemTypeForEdit.AccrualItemType
  association [0..1] to I_AccrItemTypeForLedgerGroup          as _AccrLedgerGroup     on  $projection.AccrualEngineAccrualObjectType = _AccrLedgerGroup.AccrualEngineApplication
                                                                                      and $projection.CompanyCode                    = _AccrLedgerGroup.CompanyCode
                                                                                      and $projection.AccrualItemType                = _AccrLedgerGroup.AccrualItemType
                                                                                      and $projection.Ledger                         = _AccrLedgerGroup.Ledger
  association [0..1] to I_CompanyCode                as _CompanyCode         on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_Currency                   as _TransactionCurrency on  $projection.TransactionCurrency = _TransactionCurrency.Currency
  association [1..1] to I_Currency                   as _CompanyCodeCurrency on  $projection.CompanyCodeCurrency = _CompanyCodeCurrency.Currency
  association [0..1] to I_Currency                   as _GlobalCurrency      on  $projection.GlobalCurrency = _GlobalCurrency.Currency
{
      @ObjectModel.foreignKey.association: '_AccrObjectType'
  key AccrualEngineAccrualObjectType,
      @ObjectModel.foreignKey.association: '_AccrLogicalSystem'
  key AccrualObjectLogicalSystem,
      @ObjectModel.foreignKey.association: '_AccrCompanyCode'
  key CompanyCode,
  key AccrualObject,
  key AccrualSubobject,
      @ObjectModel.foreignKey.association: '_AccrItemType'
      //      @ObjectModel.text.element: ['AccrualItemTypeName']

  key AccrualItemType,
      @ObjectModel.foreignKey.association: '_Ledger'
  key Ledger,
  key AccrSubobjectItmValdtyEndDte,
//      cast( _AccrItemType._Text[1:Language = $session.system_language].AccrualItemTypeName as ace_itemtype_txt ) as AccrualItemTypeName,

      @ObjectModel.foreignKey.association: '_AccrItemTypeForEdit'
      AccrualItemType                                                                                            as AccrualItemTypeForEdit,

      _AccrLedgerGroup.LedgerGroup,
      @ObjectModel.foreignKey.association: '_PerdcPostgFrqcy'
      @ObjectModel.text.element: ['AccrPerdcPostingFrequencyName']
      _AccrLedgerGroup.AccrPerdcPostingFrequency,
      @Semantics.text: true
      _AccrLedgerGroup._PerdcPostgFrqcy._Text[1:Language=$session.system_language].AccrPerdcPostingFrequencyName,
      AccrSubobjectItmValdtyStrtDte,
      @ObjectModel.foreignKey.association: '_AccrMethod'
      AccrualMethod,
      AccrSubobjHdrStartOfLifeDate,
      AccrSubobjHdrEndOfLifeDate,
      AccrualItemIsObsolete,
      @ObjectModel.foreignKey.association: '_PlanAccrItemType'
      PlanAccrualItemType,
      @ObjectModel.foreignKey.association: '_PlanAccrMethod'
      PlanAccrualMethod,
      @ObjectModel.foreignKey.association: '_ActualAccrItemType'
      ActualAccrualItemType,
      @ObjectModel.foreignKey.association: '_ActualAccrMethod'
      ActualAccrualMethod,
      @ObjectModel.foreignKey.association: '_DeferralItemType'
      DeferralItemType,
      @ObjectModel.foreignKey.association: '_DeferralMethod'
      DeferralMethod,
      @Semantics.quantity.unitOfMeasure: 'TotalAccrualQuantityUnit'
      TotalAccrualQuantity,
      TotalAccrualQuantityUnit,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      TotalAccrAmountInTransCrcy,
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      TotalAccrAmtInCompanyCodeCrcy,
      @Semantics.amount.currencyCode: 'GlobalCurrency'
      TotalAccrAmountInGlobalCrcy,
      @Semantics.amount.currencyCode: 'FreeDefinedCurrency1'
      TotalAccrAmountInFreeDfndCrcy1,
      @Semantics.amount.currencyCode: 'FreeDefinedCurrency2'
      TotalAccrAmountInFreeDfndCrcy2,
      @Semantics.amount.currencyCode: 'FreeDefinedCurrency3'
      TotalAccrAmountInFreeDfndCrcy3,
      @Semantics.amount.currencyCode: 'FreeDefinedCurrency4'
      TotalAccrAmountInFreeDfndCrcy4,
      @Semantics.amount.currencyCode: 'FreeDefinedCurrency5'
      TotalAccrAmountInFreeDfndCrcy5,
      @Semantics.amount.currencyCode: 'FreeDefinedCurrency6'
      TotalAccrAmountInFreeDfndCrcy6,
      @Semantics.amount.currencyCode: 'FreeDefinedCurrency7'
      TotalAccrAmountInFreeDfndCrcy7,
      @Semantics.amount.currencyCode: 'FreeDefinedCurrency8'
      TotalAccrAmountInFreeDfndCrcy8,
      TransactionCurrency,
      cast( _CompanyCode.Currency as fins_currh preserving type )  as CompanyCodeCurrency,
      cast( _CompanyCode._ControllingArea.ControllingAreaCurrency as fins_currk preserving type ) as GlobalCurrency,
//      CompanyCodeCurrency,

//      GlobalCurrency,

      FreeDefinedCurrency1,
      FreeDefinedCurrency2,
      FreeDefinedCurrency3,
      FreeDefinedCurrency4,
      FreeDefinedCurrency5,
      FreeDefinedCurrency6,
      FreeDefinedCurrency7,
      FreeDefinedCurrency8,
      @ObjectModel.foreignKey.association: '_OpngPostgDocumentType'
      AccrOpngPostgDocumentType,
      @ObjectModel.foreignKey.association: '_PerdcPostgDocumentType'
      AccrPerdcPostgDocumentType,
      @ObjectModel.foreignKey.association: '_ClsgPostgDocumentType'
      AccrClsgPostgDocumentType,
      @ObjectModel.foreignKey.association: '_OpngPostgAccrAccount'
      AccrOpngPostgAccrAccount,
      @ObjectModel.foreignKey.association: '_OpngPostgOffstgAccount'
      AccrOpngPostgOffstgAccount,
      @ObjectModel.foreignKey.association: '_PerdcPostgAccrAccount'
      AccrPerdcPostgAccrAccount,
      @ObjectModel.foreignKey.association: '_PerdcPostgOffstgAccount'
      AccrPerdcPostgOffstgAcct,
      @ObjectModel.foreignKey.association: '_ClsgPostgAccrAccount'
      AccrClsgPostgAccrAccount,
      @ObjectModel.foreignKey.association: '_ClsgPostgOffstgAccount'
      AccrClsgPostgOffstgAccount,
      AccrualItemLastChangeDateTime,
      /* Associations */
      _AccrualSubobject,
      _AccrCompanyCode,
      _AccrItemType,
      _AccrItemTypeForEdit,
      _AccrLedgerGroup._PerdcPostgFrqcy,
      _AccrLogicalSystem,
      _AccrMethod,
      _AccrObj,
      _AccrObjectType,
      _AccrSubobj,
      _ActualAccrItemType,
      _ActualAccrMethod,
      _ActualItem,
      _BaseUnit,
      _ClsgPostgAccrAccount,
      _ClsgPostgDocumentType,
      _ClsgPostgOffstgAccount,
      _CompanyCodeCurrency,
      _DeferralItem,
      _DeferralItemType,
      _DeferralMethod,
      _FreeDefinedCurrency1,
      _FreeDefinedCurrency2,
      _FreeDefinedCurrency3,
      _FreeDefinedCurrency4,
      _FreeDefinedCurrency5,
      _FreeDefinedCurrency6,
      _FreeDefinedCurrency7,
      _FreeDefinedCurrency8,
      _GlobalCurrency,
      _Ledger,
      _OpngPostgAccrAccount,
      _OpngPostgDocumentType,
      _OpngPostgOffstgAccount,
      _PerdcPostgAccrAccount,
      _PerdcPostgDocumentType,
      _PerdcPostgOffstgAccount,
      _PlanAccrItemType,
      _PlanAccrMethod,
      _PlanItem,
      _TransactionCurrency
      //  _association_name // Make association public

}