P_TAXEXPLAINERTAXCOMPONENT

CDS View

Tax component details for tax explainer

P_TAXEXPLAINERTAXCOMPONENT is a CDS View in S/4HANA. Tax component details for tax explainer. It contains 2 fields. 1 CDS views read from this table.

Used by 1 CDS view(s) 2 fields

CDS Views using this table (1)

ViewTypeJoinVDMDescription
P_TaxExplainerSlsOrdTaxComp view_entity inner COMPOSITE amount calculation for header

Fields (2)

KeyField CDS FieldsUsed in Views
KEY ConditionRateValue ConditionRateValue 1
KEY ConditionType ConditionType 1 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
//@EndUserText.label: 'Tax component details for tax explainer'

@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #COMPOSITE
@VDM.private: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
define view entity P_TaxExplainerTaxComponent
  as select from I_PricingElement              as PricingElement
    inner join   P_TaxExplainerConditionRecord as ConditionRecord on  PricingElement.ConditionRecord           = ConditionRecord.ConditionRecord
                                                                  and PricingElement.ConditionSequentialNumber = ConditionRecord.ConditionSequentialNumber
  association [0..*] to I_ConditionTypeText     as _Text      on  PricingElement.ConditionType        = _Text.ConditionType
                                                              and PricingElement.ConditionApplication = _Text.ConditionApplication
  association [0..*] to P_TaxExplainerTaxFactor as _TaxFactor on  $projection.ConditionTable = _TaxFactor.ConditionTable
                                                              and $projection.accesssequence = _TaxFactor.AccessSequence

{
  key    PricingElement.PricingDocument,
  key    PricingElement.PricingDocumentItem,
  key    PricingElement.ConditionType,
         coalesce(_Text[1: Language = $session.system_language].ConditionTypeName, _Text[1: Language = 'E'].ConditionTypeName) as ConditionTypeName,
         PricingElement.TransactionCurrency,
         @Semantics.amount.currencyCode: 'TransactionCurrency'
         PricingElement.ConditionBaseAmount,
         @Semantics.amount.currencyCode: 'TransactionCurrency'
         PricingElement.ConditionAmount,
         PricingElement.ConditionRateValue,
         '%'                                                                                                                   as ConditionRateValueUnit,

         //NonJSON Fields

         ConditionRecord.ConditionRecord,
         ConditionRecord.ConditionTable,
         PricingElement._PricingConditionType.AccessSequence,
         _TaxFactor

}
where
      PricingElement.ConditionCategory        =  'D'
  and PricingElement.ConditionIsForStatistics <> 'X'

Learn More