P_SALESDOCITEMINHERITEDPARTNER

CDS View

Inherited Partners of Sales Document

P_SALESDOCITEMINHERITEDPARTNER is a CDS View in S/4HANA. Inherited Partners of Sales Document. It contains 23 fields. 1 CDS views read from this table.

Used by 1 CDS view(s) 23 fields

CDS Views using this table (1)

ViewTypeJoinVDMDescription
P_SalesDocItemCompletePartner view union_all COMPOSITE Sales Doc Inherited and Item Partner

Fields (23)

KeyField CDS FieldsUsed in Views
KEY PartnerFunction PartnerFunction 1
KEY SalesDocumentItem SalesDocumentItem 1
_Address _Address 1
_BPRefAddressForDocSpcfcAddr _BPRefAddressForDocSpcfcAddr 1
_BusinessPartnerAddress _BusinessPartnerAddress 1
_ContactPerson _ContactPerson 1
_DfltAddrRprstn _DfltAddrRprstn 1
_PartnerFunction _PartnerFunction 1
_SalesDocument _SalesDocument 1
AddressID AddressID 1
AddressObjectType AddressObjectType 1
AddressPersonID AddressPersonID 1
BPAddrDeterminationTransaction BPAddrDeterminationTransaction 1
BPRefAddressIDForDocSpcfcAddr BPRefAddressIDForDocSpcfcAddr 1
ContactPerson ContactPerson 1
Customer Customer 1
PartnerIsOneTimeAccount PartnerIsOneTimeAccount 1
Personnel Personnel 1
ReferenceBusinessPartner ReferenceBusinessPartner 1
SDDocPartnerAddressRefType SDDocPartnerAddressRefType 1
Supplier Supplier 1
UnloadingPointName UnloadingPointName 1
VATRegistration VATRegistration 1 
@AbapCatalog: {
  sqlViewName: 'PSLSDOCITMINHPT',
  compiler.compareFilter: true,
  preserveKey: true
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
   representativeKey: 'PartnerFunction',
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #B,
     sizeCategory:   #XL
   }
}

@VDM: {
  private: true,
  viewType: #COMPOSITE
}

@AccessControl.authorizationCheck: #NOT_REQUIRED

define view P_SalesDocItemInheritedPartner 
  as select from I_SalesDocumentItem         as _Item
  
  inner join I_SalesDocumentPartner          as _Partner on _Item.SalesDocument = _Partner.SalesDocument
  
  left outer join I_SalesDocumentItemPartner as _ItemPartner on _Partner.SalesDocument   = _ItemPartner.SalesDocument
                                                            and _Item.SalesDocumentItem  = _ItemPartner.SalesDocumentItem
                                                            and _Partner.PartnerFunction = _ItemPartner.PartnerFunction
                                                            
{
  key _Partner.SalesDocument,
  
  key _Item.SalesDocumentItem,
  
  key _Partner.PartnerFunction,
  
      _Partner.Customer,
      
      _Partner.Supplier,
      
      _Partner.ContactPerson,
      
      _Partner.ReferenceBusinessPartner,
      
      _Partner.Personnel,
      
      _Partner.AddressID,
      
      _Partner.AddressPersonID,
      
      _Partner.AddressObjectType,
      
      _Partner.SDDocPartnerAddressRefType,
      
      _Partner.BPAddrDeterminationTransaction,
      
      _Partner.BPRefAddressIDForDocSpcfcAddr,
      
      _Partner.PartnerIsOneTimeAccount,
      
      _Partner.VATRegistration,
      
      _Partner.UnloadingPointName,
      
      _Partner._Address,
      
      _Partner._DfltAddrRprstn,
      
      _Partner._BusinessPartnerAddress,
      
      _Partner._BPRefAddressForDocSpcfcAddr,
      
      _Partner._SalesDocument,
      
      _Partner._PartnerFunction,
      
      _Partner._ContactPerson
} 

  where _ItemPartner.PartnerFunction is null

Learn More