P_SALESCONTRACTPROCESSFLOW10

@ClientHandling.algorithm: #SESSION_VARIABLE 
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@VDM.private: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #COMPOSITE
@AbapCatalog.sqlViewName: 'PSLSCONPROCFL10'
@AbapCatalog.preserveKey:true 
@AbapCatalog.compiler.compareFilter:true
@EndUserText.label: 'Contract process flow level 1-0'
define view P_SalesContractProcessFlow10
  with parameters P_SalesContract: vbeln_von
  as select from P_SalesContractProcessFlow0(P_SalesContract: $parameters.P_SalesContract) as Level0
    inner join I_SDDocumentProcessFlow as _ProcessFlow on Level0.SalesContract       = _ProcessFlow.PrecedingDocument
                                                      and Level0.SalesContractItem   = _ProcessFlow.PrecedingDocumentItem
                                                      and Level0.SDDocumentCategory  = _ProcessFlow.PrecedingDocumentCategory
    left outer to one join I_SDDocumentCategory  as _SDDocumentCategory on _SDDocumentCategory.SDDocumentCategory = _ProcessFlow.SubsequentDocumentCategory
    association [0..1] to I_UnitOfMeasure as _BaseUnit           on $projection.BaseUnit = _BaseUnit.UnitOfMeasure
    association [0..1] to I_Currency      as _StatisticsCurrency on $projection.StatisticsCurrency = _StatisticsCurrency.Currency
{ 
  key  Level0.SalesContract,
  key  _ProcessFlow.PrecedingDocument,
  key  _ProcessFlow.PrecedingDocumentItem,
  key  _ProcessFlow.PrecedingDocumentCategory,
  key  _ProcessFlow.SubsequentDocument ,
  key  _ProcessFlow.SubsequentDocumentItem,
  key  _ProcessFlow.SubsequentDocumentCategory,
       @Semantics.quantity.unitOfMeasure: 'BaseUnit'
       _ProcessFlow.QuantityInBaseUnit,
       _ProcessFlow.BaseUnit,
       @Semantics.amount.currencyCode: 'StatisticsCurrency'
       _ProcessFlow.NetAmount,
       @Semantics.currencyCode: true
       _ProcessFlow.StatisticsCurrency,
       cast( '' as status_bez )                           as SDProcessStatusDesc,
       cast( '0000' as gjahr )                            as FiscalYear,
       cast( '' as bukrs )                                as CompanyCode,
       cast( '0000' as mjahr )                            as MaterialDocumentYear,
       cast( ( case SubsequentDocumentCategory 
               when 'C' then 'SalesOrder'
               when 'J' then 'OutboundDelivery'
               when 'H' then 'CustomerReturn'
               when 'K' then 'CreditMemoRequest'
               when 'L' then 'DebitMemoRequest'
               when 'M' then 'BillingDocument'
               when 'N' then 'BillingDocument'
               when 'O' then 'BillingDocument'
               when 'P' then 'BillingDocument'
               when 'S' then 'BillingDocument'
               end ) as bpf_sem_obj )                               as SemanticObject,
       _SDDocumentCategory._Text[1:Language=$session.system_language].SDDocumentCategoryName  as SDDocumentCategoryName,
       _ProcessFlow.CreationDate,
       _ProcessFlow.CreationTime,
       _BaseUnit, 
       _StatisticsCurrency
}