P_RBLSITMFORKEYDTEDUEPERD1

CDS View

Cash Collection Tracker 1

P_RBLSITMFORKEYDTEDUEPERD1 is a CDS View in S/4HANA. Cash Collection Tracker 1. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
P_RblsItmForKeyDteDuePerd2 view from COMPOSITE Open Accounts Receivables for Smart Business Apps 2 
@AbapCatalog.sqlViewName: 'PRBLSKDATDUE1'
@VDM.viewType: #COMPOSITE
@VDM.private:true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
define view P_RblsItmForKeyDteDuePerd1                 
with parameters
    P_KeyDate    : bzdat,
    P_PeriodType : fis_period_type
    
  as select from  P_RblsItmForKeyDteRepPeriod( P_KeyDate: :P_KeyDate,
                                         P_PeriodType: :P_PeriodType ) as Period
                                         
  inner join I_OperationalAcctgDocItem as Receivables
  on Period.CompanyCode = Receivables.CompanyCode                                                          
{
  key Receivables.CompanyCode,
  key Receivables.AccountingDocument,
  key Receivables.AccountingDocumentItem,
  key Receivables.FiscalYear,
      Receivables.InvoiceReference,
      Receivables.InvoiceItemReference,
      Receivables.InvoiceReferenceFiscalYear,
      Receivables.ClearingDate,
      Receivables.PostingDate,
      Receivables.DocumentDate,
      Receivables.FinancialAccountType,
      Receivables.DebitCreditCode,
      Receivables.Customer,
      Receivables.FollowOnDocumentType,
      Receivables.NetDueDate,
      Receivables.SpecialGLCode,
      Receivables.GLAccount,
      Receivables.CompanyCodeCurrency as DisplayCurrency,
      Receivables.CompanyCodeCurrency,
      Receivables.FunctionalCurrency,
      Receivables.TransactionCurrency,
      Receivables.AmountInCompanyCodeCurrency as OpenDueAmountInDisplayCrcy,
      Receivables.AmountInCompanyCodeCurrency,
      Receivables.AccountingDocumentCategory,
      Receivables.AmountInFunctionalCurrency,
      Receivables.AmountInTransactionCurrency,
      Receivables.PostingKey,
      Receivables.IsUsedInPaymentTransaction,
      Receivables.BusinessArea,
      Receivables.FiscalPeriod, 
      
      Period.ReportingPeriodStartDate,
      Period.ReportingPeriodEndDate,
      Period.ReportingPeriod,
      Period.ReportingYear
}

where
// receivables

  Receivables.FinancialAccountType = 'D'
  and Receivables.AccountingDocumentCategory =  ''  
  and Receivables.IsUsedInPaymentTransaction = ' ' 
  and  
  ( 
  //  Overdue items

  ( Receivables.NetDueDate  <  Period.ReportingPeriodStartDate  
    and ( Receivables.ClearingDate = '00000000' or Receivables.ClearingDate >= Period.ReportingPeriodStartDate ) )
//  Due this period  

  or
  ( Receivables.NetDueDate  >= Period.ReportingPeriodStartDate
    and Receivables.NetDueDate  <= Period.ReportingPeriodEndDate
    and Receivables.PostingDate < Period.ReportingPeriodStartDate )
  or 
//  New Invoices

  (     Receivables.PostingDate >= Period.ReportingPeriodStartDate 
    and Receivables.PostingDate <= Period.ReportingPeriodEndDate 
    and Receivables.NetDueDate  >= Period.ReportingPeriodStartDate 
    and Receivables.NetDueDate  <= Period.ReportingPeriodEndDate
    and Receivables.PostingDate <= $parameters.P_KeyDate
    //and  _PostingKey.IsUsedInPaymentTransaction = ' ' 

    ) 
  )

Learn More