P_PE_JOURNALENTRYFSSTRUCTURE2

CDS View

Peru Journal Entry with Financial Statement Structure 2

P_PE_JOURNALENTRYFSSTRUCTURE2 is a CDS View in S/4HANA. Peru Journal Entry with Financial Statement Structure 2. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
P_PE_JournalEntryFSStructure view from CONSUMPTION Peru Journal Entry with Financial Statement Structure 
@AbapCatalog.sqlViewName: 'PPEJRNLEFSS2'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.private:true
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED

define view P_PE_JournalEntryFSStructure2
  with parameters
    P_CompanyCode                 : fis_bukrs,
    P_FiscalYear                  : fis_gjahr_no_conv,
    P_Ledger                      : rldnr,
    P_FinancialStatementHierarchy : hryid

  as select from I_FinancialStatementStructure as FinancialStatement

    inner join   I_JournalEntryItem            as JournalEntryItem on  JournalEntryItem.CompanyCode = $parameters.P_CompanyCode
                                                                   and JournalEntryItem.FiscalYear  = $parameters.P_FiscalYear
                                                                   and JournalEntryItem.Ledger      = $parameters.P_Ledger
                                                                   and JournalEntryItem.GLAccount   = FinancialStatement.HierarchyNodeVal

{
  key JournalEntryItem.CompanyCode,
  key JournalEntryItem.FiscalYear,
  key JournalEntryItem.AccountingDocument,
  key JournalEntryItem.Ledger,
  key FinancialStatement.FinancialStatementHierarchy,
  key JournalEntryItem.GLAccount,

      max( JournalEntryItem.AmountInTransactionCurrency ) as AmountInTransactionCurrency

}
where
      FinancialStatement.FinancialStatementNodeType  = 'G'
  and FinancialStatement.FinancialStatementHierarchy = $parameters.P_FinancialStatementHierarchy

group by
  JournalEntryItem.CompanyCode,
  JournalEntryItem.FiscalYear,
  JournalEntryItem.AccountingDocument,
  JournalEntryItem.Ledger,
  FinancialStatement.FinancialStatementHierarchy,
  JournalEntryItem.GLAccount

Learn More