P_OVERDUESALESORDERUNION

CDS View

Overdue Sales Order Union

P_OVERDUESALESORDERUNION is a CDS View in S/4HANA. Overdue Sales Order Union. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_OverdueSalesOrder view from COMPOSITE Overdue Sales Order 
@ClientHandling.algorithm: #SESSION_VARIABLE 
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #S
@VDM.private: true
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AbapCatalog.sqlViewName: 'PSDOVRDSLSORDER'

define view P_OverdueSalesOrderUnion
as
select from I_SalesOrderInDelivShipgIssue
{
    key SalesOrder,
        
    Issue, // DE05 - Shipping Issue in Delivery

    
    @DefaultAggregation: #MIN
    min(DueDays) as DueDays,
  
    @DefaultAggregation: #SUM
    cast(cast( 1 as abap.int4 ) as number_of_sales_orders) as NumberOfSalesOrders
} 
group by SalesOrder, SalesOrderType, Issue, SalesOrganization, DistributionChannel, OrganizationDivision

union all

select from I_SalesOrderInDelivNoInvoice
{
    key SalesOrder,
        
    Issue, // IN02 - Invoicing Issue in Delivery

    
    @DefaultAggregation: #MIN
    min(DueDays) as DueDays,
  
    @DefaultAggregation: #SUM
    cast(cast( 1 as abap.int4 ) as number_of_sales_orders) as NumberOfSalesOrders
}
group by SalesOrder, SalesOrderType, Issue, SalesOrganization, DistributionChannel, OrganizationDivision

union all

select from I_SalesOrderOverdueDelivery
{
    key SalesOrder,
        
    Issue, // SO05 - Delivery Issue in Sales Orders

    
    @DefaultAggregation: #MIN
    min(DueDays) as DueDays,
  
    @DefaultAggregation: #SUM
    cast(cast( 1 as abap.int4 ) as number_of_sales_orders) as NumberOfSalesOrders
}
group by SalesOrder, SalesOrderType, Issue, SalesOrganization, DistributionChannel, OrganizationDivision

Learn More