P_OPERATIONACTIVITYCOMPONENT
OA Planned Component, Incl. Unplanned Assemblies
P_OPERATIONACTIVITYCOMPONENT is a CDS View in S/4HANA. OA Planned Component, Incl. Unplanned Assemblies. It contains 47 fields. 1 CDS views read from this table.
CDS Views using this table (1)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_OperationActivityComponent | view | from | CONSUMPTION | Operation Activity Component |
Fields (47)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | OpActyNtwkInstance | OpActyNtwkInstance | 1 |
| _StorageLocation | _StorageLocation | 1 | |
| BaseUnit | BaseUnit | 1 | |
| BillOfMaterial | BillOfMaterial | 1 | |
| BillOfMaterialInternalID | BillOfMaterialInternalID | 1 | |
| BillOfMaterialVariant | BillOfMaterialVariant | 1 | |
| BillOfMaterialVersion | BillOfMaterialVersion | 1 | |
| BOMItem | BOMItem | 1 | |
| BOMItemCategory | BOMItemCategory | 1 | |
| BOMItemInternalChangeCount | BOMItemInternalChangeCount | 1 | |
| BOOOpBOMItemInternalID | BOOOpBOMItemInternalID | 1 | |
| FormulaKey | FormulaKey | 1 | |
| GoodsMovementIsAllowed | GoodsMovementIsAllowed | 1 | |
| InheritedBOMItemNode | InheritedBOMItemNode | 1 | |
| IsBatchManagementRequired | IsBatchManagementRequired | 1 | |
| IsBulkMaterialComponent | IsBulkMaterialComponent | 1 | |
| LeadingOpActyNtwkElement | LeadingOpActyNtwkElement | 1 | |
| LeadingOpActyNtwkInstance | LeadingOpActyNtwkInstance | 1 | |
| LeadingReservation | LeadingReservation | 1 | |
| LeadingReservationItem | LeadingReservationItem | 1 | |
| LeadingReservationRecordType | LeadingReservationRecordType | 1 | |
| LogicalComponent | LogicalComponent | 1 | |
| MaterialComponentIsMissing | MaterialComponentIsMissing | 1 | |
| MaterialComponentQuantity | MaterialComponentQuantity | 1 | |
| MatlCompAssembleControl | MatlCompAssembleControl | 1 | |
| MatlCompDiscontinuationType | MatlCompDiscontinuationType | 1 | |
| MatlCompInstceAssyIsRequired | MatlCompInstceAssyIsRequired | 1 | |
| MfgOrderComponentUsageQuantity | MfgOrderComponentUsageQuantity | 1 | |
| MfgRefStrucBOMLeafAssgmtUUID | MfgRefStrucBOMLeafAssgmtUUID | 1 | |
| MfgRefStrucItmDetIsContextual | MfgRefStrucItmDetIsContextual | 1 | |
| MfgRefStructureItemDetailUUID | MfgRefStructureItemDetailUUID | 1 | |
| ProductionPlant | ProductionPlant | 1 | |
| RelatedOpActyNtwkElement | RelatedOpActyNtwkElement | 1 | |
| RelatedOpActyNtwkInstance | RelatedOpActyNtwkInstance | 1 | |
| RelatedRecordType | RelatedRecordType | 1 | |
| RelatedReservationItem | RelatedReservationItem | 1 | |
| RequiredQuantity | RequiredQuantity | 1 | |
| ReservationIsFinallyIssued | ReservationIsFinallyIssued | 1 | |
| SerialNumberProfile | SerialNumberProfile | 1 | |
| StockCheckMessageType | StockCheckMessageType | 1 | |
| StorageLocation | StorageLocation | 1 | |
| VariableSizeComponentQuantity | VariableSizeComponentQuantity | 1 | |
| VariableSizeComponentUnit | VariableSizeComponentUnit | 1 | |
| VariableSizeDimension1 | VariableSizeDimension1 | 1 | |
| VariableSizeDimension2 | VariableSizeDimension2 | 1 | |
| VariableSizeDimension3 | VariableSizeDimension3 | 1 | |
| VariableSizeDimensionUnit | VariableSizeDimensionUnit | 1 |
@AbapCatalog.sqlViewName: 'PMPEOACOMP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #XL, dataClass: #CUSTOMIZING}
@VDM.viewType: #CONSUMPTION
@VDM.private: true
define view P_OperationActivityComponent
as select from P_OperationActivityCompUnion as OperationActivityCompUnion
inner join I_MatlPlntCompAssembleControl as MfgOrderProductPlant on OperationActivityCompUnion.Material = MfgOrderProductPlant.Product
and OperationActivityCompUnion.Plant = MfgOrderProductPlant.Plant
association [0..1] to I_StorageLocation as _StorageLocation on $projection.Plant = _StorageLocation.Plant
and $projection.StorageLocation = _StorageLocation.StorageLocation
association [1..1] to I_MatlCompAssembleControl as _MatlCompAssembleControl on $projection.MatlCompAssembleControl = _MatlCompAssembleControl.MatlCompAssembleControl
association [0..1] to I_BillOfMaterialItemCategory as _BOMItemCategory on $projection.BOMItemCategory = _BOMItemCategory.BillOfMaterialItemCategory
association [0..1] to I_BOMItmMfgRefStrucItmAssgmt as _BOMItmMfgRefStrucItmAssgmt on $projection.MfgRefStrucBOMLeafAssgmtUUID = _BOMItmMfgRefStrucItmAssgmt.MfgRefStrucBOMLeafAssgmtUUID
association [0..1] to I_MfgRefStrucItemWithDetails as _MfgRefStrucItemWithDetails on $projection.MfgRefStructureItemDetailUUID = _MfgRefStrucItemWithDetails.MfgRefStructureItemUUID
and $projection.MfgRefStrucItmDetIsContextual = ''
association [0..1] to I_MfgRefHierItemWithDetails as _MfgRefHierItemWithDetails on $projection.MfgRefStructureItemDetailUUID = _MfgRefHierItemWithDetails.MfgRefHierarchyItemUUID
and $projection.MfgRefStrucItmDetIsContextual = 'X'
{
key OperationActivityCompUnion.OpActyNtwkInstance,
key OperationActivityCompUnion.OpActyNtwkElement,
key OperationActivityCompUnion.Reservation,
key OperationActivityCompUnion.ReservationItem,
key OperationActivityCompUnion.RecordType,
key cast(OperationActivityCompUnion.Material as mpe_component_matnr preserving type ) as Material,
key OperationActivityCompUnion.Plant, --> Coming from RESB (for planned assemblies) or goods movement (for unplanned assemblies)
OperationActivityCompUnion.StorageLocation,
OperationActivityCompUnion.ProductionPlant, --> Coming from AUFK (for planned assemblies only)
OperationActivityCompUnion.AssemblySequenceNumber,
OperationActivityCompUnion.BaseUnit,
@Semantics.quantity.unitOfMeasure: 'EntryUnit'
cast(round(fltp_to_dec( OperationActivityCompUnion.MfgOrderComponentUsageQuantity as abap.dec(13,4) ), 3)
as mpe_usage_qty ) as MfgOrderComponentUsageQuantity,
@Semantics.quantity.unitOfMeasure: 'EntryUnit'
cast(round(fltp_to_dec( OperationActivityCompUnion.RequiredQuantity as abap.dec(13,4) ), 3)
as co_menge ) as RequiredQuantity,
@Semantics.quantity.unitOfMeasure: 'EntryUnit'
cast(case OperationActivityCompUnion.MaterialCompIsVariableSized
-- Variable-size item: Assembly typically has to be done in PC, but base unit e.g. is square meter
when 'X' then OperationActivityCompUnion.QuantityInEntryUnit
else OperationActivityCompUnion.MaterialComponentQuantity
end as mpe_consumed_qty preserving type) as MaterialComponentQuantity, --ConsumedQuantity
@Semantics.quantity.unitOfMeasure: 'BaseUnit'
cast(OperationActivityCompUnion.MaterialComponentQuantity as mpe_consumed_qty_in_base_unit preserving type) as ResvnItmWithdrawnQtyInBaseUnit,
OperationActivityCompUnion.QuantityInEntryUnit,
OperationActivityCompUnion.EntryUnit,
cast( OperationActivityCompUnion.MatlCompIsMarkedForBackflush as boolean preserving type ) as MatlCompIsMarkedForBackflush,
OperationActivityCompUnion.IsBulkMaterialComponent,
OperationActivityCompUnion.GoodsMovementIsAllowed,
OperationActivityCompUnion.MaterialComponentIsMissing,
OperationActivityCompUnion.ReservationIsFinallyIssued,
OperationActivityCompUnion.MatlCompDiscontinuationType,
-- Variable-Size Item Fields
OperationActivityCompUnion.MaterialCompIsVariableSized,
OperationActivityCompUnion.VariableSizeItemUnit,
OperationActivityCompUnion.FormulaKey,
OperationActivityCompUnion.VariableSizeDimension1,
OperationActivityCompUnion.VariableSizeDimension2,
OperationActivityCompUnion.VariableSizeDimension3,
OperationActivityCompUnion.VariableSizeDimensionUnit,
OperationActivityCompUnion.VariableSizeComponentQuantity,
OperationActivityCompUnion.VariableSizeComponentUnit,
-- Related / Leading Reservations
OperationActivityCompUnion.RelatedReservation,
OperationActivityCompUnion.RelatedReservationItem,
OperationActivityCompUnion.RelatedRecordType,
OperationActivityCompUnion.RelatedOpActyNtwkInstance,
OperationActivityCompUnion.RelatedOpActyNtwkElement,
OperationActivityCompUnion.LeadingReservation,
OperationActivityCompUnion.LeadingReservationItem,
OperationActivityCompUnion.LeadingReservationRecordType,
OperationActivityCompUnion.LeadingOpActyNtwkInstance,
OperationActivityCompUnion.LeadingOpActyNtwkElement,
MfgOrderProductPlant.SerialNumberProfile,
MfgOrderProductPlant.SerialNumberIsRqdForAssembly,
MfgOrderProductPlant.StockCheckMessageType,
MfgOrderProductPlant.IsBatchManagementRequired,
cast(case
when OperationActivityCompUnion.MatlCompIsMarkedForBackflush = 'X' then 4
when OperationActivityCompUnion.IsBulkMaterialComponent = 'X' then 5
else MfgOrderProductPlant.MatlCompAssembleControl
end as mpe_comp_assemble_control preserving type ) as MatlCompAssembleControl,
-- Additional data needed for corresponding association
OperationActivityCompUnion.BillOfMaterialCategory,
OperationActivityCompUnion.BillOfMaterial,
cast( OperationActivityCompUnion.BillOfMaterialInternalID as mpe_exec_stnum preserving type ) as BillOfMaterialInternalID,
OperationActivityCompUnion.BillOfMaterialVariant,
OperationActivityCompUnion.BillOfMaterialVersion,
OperationActivityCompUnion.InheritedBOMItemNode,
OperationActivityCompUnion.BOMItemCategory,
OperationActivityCompUnion.BOMItem,
OperationActivityCompUnion.BOMItemInternalChangeCount,
OperationActivityCompUnion.BOOOpBOMItemInternalID,
OperationActivityCompUnion.LogicalComponent,
OperationActivityCompUnion.MfgRefStrucBOMLeafAssgmtUUID,
OperationActivityCompUnion.MfgRefStructureItemDetailUUID,
OperationActivityCompUnion.MfgRefStrucItmDetIsContextual,
OperationActivityCompUnion.MatlCompInstceAssyIsRequired,
_StorageLocation,
_MatlCompAssembleControl,
_BOMItemCategory,
_BOMItmMfgRefStrucItmAssgmt,
_MfgRefStrucItemWithDetails,
_MfgRefHierItemWithDetails
}